Tạo công thức if cho nhiều điều kiện? (1 người xem)

[PIT]

Các bác ơi làm ơn cho em xin công thức của điều kiện này được k?, em lập mãi k được
DK1: Nếu Cột A= 24 hoặc cột B=12 thì cột C =1
hoặc nếu Cột A=12 và cột B=6 thì cột C=1
DK2: Nếu Cột A=12+Cột B=12 thì cột C=2
hoặc nếu Cột A=24+cột B=6 thì cột C=2
hoặc nếu Cột A=6+cột B=15 thì cột C=2
hoặc nếu cột A =36 hoặc cột B= 18 thì cột C=2.

Giúp em với em đang cần rất gấp ah.

 

[boyxin]

Các bác ơi làm ơn cho em xin công thức của điều kiện này được k?, em lập mãi k được
DK1: Nếu Cột A= 24 hoặc cột B=12 thì cột C =1
hoặc nếu Cột A=12 và cột B=6 thì cột C=1
DK2: Nếu Cột A=12+Cột B=12 thì cột C=2
hoặc nếu Cột A=24+cột B=6 thì cột C=2
hoặc nếu Cột A=6+cột B=15 thì cột C=2
hoặc nếu cột A =36 hoặc cột B= 18 thì cột C=2.

Giúp em với em đang cần rất gấp ah.

KIỂM TRA LẠI XEM ĐÚNG Ý CHƯA?

C1=IF(OR(A1=24,B1=12,AND(A1=12,B1=12)),1,IF(OR(AND(A1=12,B1=12),AND(A1=24,B1=6),AND(A1=6,B1=15),A1=36,B1=18),2,"???"))

 

[PIT]

Úi cha tuyệt vời quá, em cám ơn bác nhé.

Bác giúp em nốt 2 công thức này nha
- Nếu A=1 thì cột C=ok, Nếu B=2 Thì cột C="notok"
- Nếu Số lượng cột A*2 hoặc Số lượng của cột B*4 >= 10 thì kết quả ra =1

 

[ThuNghi]

Nếu A=1 thì cột C=ok, Nếu B=2 Thì cột C="notok"

Nhưng mà nếu A=1 và B=2 thì lấy cái gì? Hay là A=1 and B<>2, C="OK"

 

[boyxin]

Nhưng mà nếu A=1 và B=2 thì lấy cái gì? Hay là A=1 and B<>2, C="OK"

hi
Khi cột A = 1 thì không cần biết cột B thế nào (có nói đến đâu mà để ý)
tương tự cột B = 2 thì không cần để ý đến cột A
công thức tại cột C

C1 =IF(A1=1,"ok",IF(B1=2,"notok","???"))

 

[PIT]

Mình lấy Nếu cột A=1 rồi thì loại trừ cột B=2, nếu cột B=2 rồi thì loại trừ cột A=1

hi
Khi cột A = 1 thì không cần biết cột B thế nào (có nói đến đâu mà để ý)
tương tự cột B = 2 thì không cần để ý đến cột A
công thức tại cột C

C1 =IF(A1=1,"ok",IF(B1=2,"notok","???"))

Bác này siêu quá, cho em xin nốt công thức này nha, phiền bác nhiều
Nếu Số lượng cột A*2 hoặc Số lượng của cột B*4 >= 10 thì kết quả ra =1

 

[boyxin]

Úi cha tuyệt vời quá, em cám ơn bác nhé.

Bác giúp em nốt 2 công thức này nha
- Nếu A=1 thì cột C=ok, Nếu B=2 Thì cột C="notok"
- Nếu Số lượng cột A*2 hoặc Số lượng của cột B*4 >= 10 thì kết quả ra =1

LÀM GIÚP BẠN THÌ CŨNG NHANH THÔI

- Nếu A=1 thì cột C=ok, Nếu B=2 Thì cột C="notok"
C1 =IF(A1=1,"ok",IF(B1=2,"notok","???"))

- Nếu Số lượng cột A*2 hoặc Số lượng của cột B*4 >= 10 thì kết quả ra =1
C1 =IF(OR(A1*2>=10,B1*4>=10),1,"???")

TỐT NHẤT BẠN NÊN TÌM HIỂU KỸ VỀ HÀM IF TẠI ĐÂY (BÁC BNTT VIẾT RẤT CHI TIẾT)
IF(logical_test, value_if_true, value_if_false) : Dùng để kiểm tra điều kiện theo giá trị và công thức
AND(logical1, logical2, ...) : Trả về TRUE nếu tất cả các đối số là TRUE, trả về FALSE nếu một hay nhiều đối số là FALSE
OR(logical1, logical2, ...) : Trả về TRUE nếu một hay nhiều đối số là TRUE, trả về FALSE nếu tất cả các đối số là FALSE

 

[PIT]

LÀM GIÚP BẠN THÌ CŨNG NHANH THÔI

- Nếu A=1 thì cột C=ok, Nếu B=2 Thì cột C="notok"
C1 =IF(A1=1,"ok",IF(B1=2,"notok","???"))

- Nếu Số lượng cột A*2 hoặc Số lượng của cột B*4 >= 10 thì kết quả ra =1
C1 =IF(OR(A1*2>=10,B1*4>=10),1,"???")

Bác ơi, em nghiên cứu mãi mà chưa thủng, mà em thì đang cần làm báo cáo, bác giúp em vụ này nhé. Em làm công thức như vậy mà k ra được
Nếu Số lượng cột A*2 hoặc Số lượng của cột B*4 >= 10 thì kết quả ra =1
hoặc cột A*2 và cột B*4 - cả hai cột này cộng vào >=10 thì cột C ra kết quả là 1
C1 =IF(OR(A1*2>=10,B1*4>=10,AND(A1*2,B1*4)>=10),1,"???")
Bác xem chỉnh hộ em tý nhé.
Cám ơn bác nhiều

 

[BNTT]

Sửa cái mệnh đề của bạn lại một tí nhé:

Nếu Số lượng cột A*2 hoặc Số lượng của cột B*4 >= 10 thì kết quả ra =1
hoặc cột A*2 và cột B*4 - cả hai cột này cộng vào >=10 thì cột C ra kết quả là 1
C1 =IF(OR(A1*2>=10,B1*4>=10,AND(A1*2,B1*4)>=10),1,"?? ?")

Nếu Số lượng cột A*2 hoặc Số lượng của cột B*4 >= 10 hoặc cột A*2 và cột B*4 (cả hai cột này cộng vào) >=10 thì cột C ra kết quả là 1

Hàm OR() chấp nhận hoặc... hoặc... đến 30 cái (với Excel 2007 thì 255 cái!), do đó bạn nên gom hết 3 cái hoặc của bạn vào chung (gom được vì chúng đều trả về kết quả là 1)

Công thức của bạn sai ở chỗ tôi bôi màu đỏ. Sửa lại như sau:

C1 = IF(OR(A1*2>=10, B1*4>=10, (A1*2 + B1*4)>=10), 1, "???")​

 

[ndu96081631]

Nếu bạn có thể gữi dử liệu lên thì tôi nghĩ có thể khỏi IF được đấy (nếu may mắn)
Khi gữi file bạn có thể mô tả sơ qua về dử liệu, chẳng hạn 12 hoặc 12+ là cái gì!
(chứ IF thế có mà chết---> Không hiệu quả)

 

[Hien tron]

tiện đây cho mình hỏi các bạn về hàm if với:
Hàm if chỉ có 9 vòng lặp nếu mình cần dùng nhiều hơn thì nên dùng hàm gì nhỉ?
có bạn nào biệt giúp mình với

 

[cadafi]

tiện đây cho mình hỏi các bạn về hàm if với:
Hàm if chỉ có 9 vòng lặp nếu mình cần dùng nhiều hơn thì nên dùng hàm gì nhỉ?
có bạn nào biệt giúp mình với

Tùy từng trường hợp cụ thể mới nói được bạn ơi!. Bạn đưa ví dụ của bạn lên với nhiều hơn 9 điều kiện xem. Sẽ có nhiều phương án lựa chọn khác nhau.

 

[thuytinh69]

Tôi đang làm bài tập này, các bác giúp tôi với nhá
Cũng là hàm if thôi, nhưng tôi làm không ra, các bác kiểm tra xem tôi sai chỗ nào:
If(I1<=100,"I1*550",if(100<I1<=150,"550000+(I1-100)*900,ì(150<I1<=200,"100000+(I1-150)*1210")))
Nhưng tại ô đó chỉ ra KQ là I1*550

 

[anhtuan1066]

Tôi đang làm bài tập này, các bác giúp tôi với nhá
Cũng là hàm if thôi, nhưng tôi làm không ra, các bác kiểm tra xem tôi sai chỗ nào:
If(I1<=100,"I1*550",if(100<I1<=150,"550000+(I1-100)*900,ì(150<I1<=200,"100000+(I1-150)*1210")))
Nhưng tại ô đó chỉ ra KQ là I1*550

Lý ra phải vầy:

=IF(I1<=100,I1*550,IF(AND(I1>100,I1<=150),550000+(I1-100)*900,IF(AND(I1>150,I1<=200),100000+(I1-150)*1210)))

Tự dưng lại đặt mấy dấu "" vào trong công thức làm gì cơ chứ --- Lại sai luôn cú pháp
Hỏng có vụ if(100<I1<=150 ... đâu nha
Còn nữa, trong công thức không nói gì về trường hợp >200
???

 

[BNTT]

Tôi đang làm bài tập này, các bác giúp tôi với nhá
Cũng là hàm if thôi, nhưng tôi làm không ra, các bác kiểm tra xem tôi sai chỗ nào:
If(I1<=100,"I1*550",if(100<I1<=150,"550000+(I1-100)*900,ì(150<I1<=200,"100000+(I1-150)*1210")))
Nhưng tại ô đó chỉ ra KQ là I1*550

Ý bạn muốn như thế nào?
Nếu I1<=100 thì hiện ra nội dung là "I1*550" hay sẽ hiện ra kết quả là giá trị trong I1 nhân với 550 ?

Nếu bạn muốn kết quả là một giá trị, thì bạn đừng có dùng mấy cái dấu nháy kép! Và xem tiếp:

Nếu như dãy số bạn cần xét (trong cột I) không có số nào lớn hơn 200, thì bạn dùng cái này:

=IF(I1<=100, I1*550, IF(I1<=150, 550000+(I1-100)*900, 100000+(I1-150)*1210))​

Còn nếu như dãy số bạn cần xét (trong cột I) có những giá trị lớn hơn 200, thì bạn cho biết thêm phải xử những giá trị lớn hơn 200 này như thế nào, tạm thời tôi cho nó = XXX, và bạn dùng công thức này:

=IF(I1<=100, I1*550, IF(I1<=150, 550000+(I1-100)*900, IF(I1<=200, 100000+(I1-150)*1210, XXX)))
​

(Bạn thay cái XXX bằng điều kiện sẽ áp dụng cho những giá trị > 200)

----------------------------------------

Nói thêm, ở cái IF thứ nhất, bạn đã xét trường hợp những số <=100, do đó, ở cái IF thứ hai, không cần nói đến những số <=100 nữa, chỉ cần xét những số <=150 mà thôi. Tương tự cho trường hợp thứ ba: <=200

Thêm nữa, Excel không chấp nhận kiểu viết 100<I1<=150
Nếu muốn phải lớn hơn 100 và nhỏ hơn hoặc bằng 150, bạn dùng hàm AND:

AND(I1>100, I1<=150)​

 

[BNTT]

Gửi bạn Thuytinh69:

Sau khi được sư nương ngocmaipretty tư vấn, và xem lại bài của bạn, thì hình như đây là bài toán tính tiền điện?

Vậy có phải đề bài là như vầy:

Nếu sử dụng trong định mức (100KW) thì tiền điện là 550 đồng / 1 KW
Nếu sử dụng vượt định mức, thì từ KW 101 đến KW 150, giá là 900 đồng / 1KW
và tiền điện cho số KW 151 trở đi là 1210 đồng / 1KW ?

Nếu đúng như vậy, thì bạn dùng công thức này:

IF(I1>150, 100000+(I1-150)*1210, IF(I1>100, 55000+(I1-100)*900, I1*550))​

 

[thuytinh69]

Xin cảm ơn các bác ah, nguyên văn bài tập là thế này:
Tính tiền điện nếu:
1. Số điện nhỏ hơn or bằng 100 thì đơn giá là 550
2. Số điện lớn hơn 100 và nhỏ hơn or bằng 150 thì:55000+(Sđiện-100)*900
3. Số điện từ 150 đến nhỏ hơn or bằng 200 thì:100+(Sđiện-150)*1210
4. Số điện từ 200 đến nhỏ hơn or bằng 300: 160500+(Sđiện-200)*1340
5. Số điện lớn hơn 300 thì:294500+(Sđiện-300)*1400
Tui làm thử rùi vẫn không được,các bác giúp tui nốt lần này nữa nha, thanks các bác nhìu nhìu

 

[ngocmaipretty]

Bạn xem lại cách tính (hoặc cách hiểu đề bài) của bạn nhé!
Theo tôi hiểu và giải thích cho BNTT thì thế này:
- 100 KWh đầu tiên: giá 550 x 50 = 55.000 (không phải 550.000 như bài #1)
- 50 KWh kế tiếp giá 900 x 50 = 45.000
Vậy 150 KWh đầu tiên sẽ phải trả 55.000 + 45.000 = 100.000 (không phải 100 như bài #17)
- Tương tự 50 KWh kế giá 1.210 x 50 = 60.500, lũy kế là 160.500
- 100 KWh tiếp theo giá 1.340 x 100 = 134.000, lũy kế là 294.500

Công thức cuối cùng là:

If(I1>300, 294500+ (I1- 300)*1400, If(I1>200, 160500+ (I1-200)*1340, If(I1>150, 100000+ (I1-150)* 1210, If(I1>100, (I1-100)* 900, I1* 550))))

To đệ tử BNTT: KWh chứ không phải KW nhe!

 

[thuytinh69]

Cảm ơn bạn nhưng...

Bạn đã thử đặt công thức mà bạn tính giùm tui vào trong exel chưa? tui đặt nguyên văn như vậy đâu có ra chứ?

 

[BNTT]

Bạn xem lại cách tính (hoặc cách hiểu đề bài) của bạn nhé!
Theo tôi hiểu và giải thích cho BNTT thì thế này:
- 100 KWh đầu tiên: giá 550 x 50 = 55.000 (không phải 550.000 như bài #1)
- 50 KWh kế tiếp giá 900 x 50 = 45.000
Vậy 150 KWh đầu tiên sẽ phải trả 55.000 + 45.000 = 100.000 (không phải 100 như bài #17)
- Tương tự 50 KWh kế giá 1.210 x 50 = 60.500, lũy kế là 160.500
- 100 KWh tiếp theo giá 1.340 x 100 = 134.000, lũy kế là 294.500

Công thức cuối cùng là:

If(I1>300, 294500+ (I1- 300)*1400, If(I1>200, 160500+ (I1-200)*1340, If(I1>150, 100000+ (I1-150)* 1210, If(I1>100, (I1-100)* 900, I1* 550))))

To đệ tử BNTT: KWh chứ không phải KW nhe!

Công thức của Sư tỷ Ngocmaipretty đã đưa ra ở trên, có sai một tí xíu, là quên cộng 55000 vào trường hợp kWh >100 (cái IF thứ tư). Chính xác thì phải như sau:

=IF(I1>300, 294500 + (I1- 300)*1400, IF(I1>200, 160500 + (I1-200)*1340, IF(I1>150, 100000 + (I1-150)* 1210, IF(I1>100, 55000 + (I1-100)* 900, I1* 550))))
​

Xin giới thiệu với bạn thêm một cách, dùng VLOOKUP để cho công thức ngắn hơn.

Với cái đề bài của bạn (xin phép sửa một chút cho chính xác hơn):

Tính tiền điện nếu:
1. Số điện nhỏ hơn hoặc bằng 100 thì đơn giá là 550
2. Số điện lớn hơn 100 và nhỏ hơn hoặc bằng 150 thì = 55000+ (Sđiện-100)*900
3. Số điện từ 150 đến nhỏ hơn hoặc bằng 200 thì = 100000 + (Sđiện-150)*1210
4. Số điện từ 200 đến nhỏ hơn hoặc bằng 300= 160500 + (Sđiện-200)*1340
5. Số điện lớn hơn 300 thì = 294500 + (Sđiện-300)*1400

Bạn vẽ một cái bảng như sau:

|

A​

​

|

B​

​

|

C​

​

|

1​

​

|

Số KWh tiêu thụ​

​

|

Đơn giá​

​

|

Lũy kế​

​

|

2​

​

|

0​

|

550​

|

0​

|

3​

​

|

100​

|

900​

|

55,000​

|

4​

​

|

150​

|

1,210​

|

100,000​

|

5​

​

|

200​

|

1,340​

|

160,500​

|

6​

​

|

300​

|

1,400​

|

294,500​

|

Bảng này, như trong hình, có địa chỉ là $A$1:$C$6. Ta có thể đặt tên (Define Name) cho nó là GIADIEN.

Giả sử ô G1 là ô chứa số điện tiêu thụ trong tháng, bạn dùng công thức sau:

=(G1 - VLOOKUP(G1, $A$1:$C$6, 1)) * VLOOKUP(G1, $A$1:$C$6, 2) + VLOOKUP(G1, $A$1:$C$6, 3)​

Hoặc:

=(G1 - VLOOKUP(G1, GIADIEN, 1)) * VLOOKUP(G1, GIADIEN, 2) + VLOOKUP(G1, GIADIEN, 3)​

 

[npv]

Hoặc:
LOOKUP(G1,$A$2:$A$6,$B$2:$B$6)*(G1-LOOKUP(G1,$A$2:$A$6))+LOOKUP(G1,$A$2:$A$6,$C$2:$C$6)
Cái này là theo cách của anh ndu96081631

 

[be heo 68]

Mình muốn hỏi làm thế nào có thể dò tìm được tháng làm việc của nhân viên như bảng sau :

[TABLE="width: 223"]
[TR]
[TD]Loại Thâm Niên[/TD]
[TD]Số tháng[/TD]
[/TR]
[TR]
[TD]0[/TD]
[TD]< 8[/TD]
[/TR]
[TR]
[TD]1[/TD]
[TD]< 14[/TD]
[/TR]
[TR]
[TD]2[/TD]
[TD]< 26[/TD]
[/TR]
[TR]
[TD]3[/TD]
[TD]< 38[/TD]
[/TR]
[TR]
[TD]4[/TD]
[TD]< 50[/TD]
[/TR]
[TR]
[TD]5[/TD]
[TD]< 62[/TD]
[/TR]
[TR]
[TD]6[/TD]
[TD]< 74[/TD]
[/TR]
[TR]
[TD]7[/TD]
[TD]< 86[/TD]
[/TR]
[TR]
[TD]8[/TD]
[TD]< 98[/TD]
[/TR]
[TR]
[TD]9[/TD]
[TD]< 110[/TD]
[/TR]
[TR]
[TD]10[/TD]
[TD]> 110
[/TD]
[/TR]
[/TABLE]
Mình làm nhưng chỉ được tới loại 8 với công thức sau :

=IF(E147<8;0;IF(E147<14;1;IF(E147<26;2;IF(E147<38;3;IF(E147<50;4;IF(E147<62;5;IF(E147<74;6;IF(E147<86;7;8))))))))
Các bạn có thể giúp mình với công thức này có thể lọc ra các loại thâm niên 8,9,10 ko?
Đại chỉ mail của mình là anhthutran3110@yahoo.com.vn
Chân thành cảm ơn các bạn đã giúp.

 

[be heo 68]

Mình muốn hỏi làm thế nào có thể dò tìm được tháng làm việc của nhân viên như bảng sau :
Loại thâm niên Số tháng làm việc
0 < 8
1 < 14
2 < 26
3 < 38
4 < 50
5 < 62
6 < 74
7 < 86
8 < 98
9 < 110
10 > 110
Mình làm nhưng chỉ được tới loại 8 với công thức sau :

=IF(E147<8;0;IF(E147<14;1;IF(E147<26;2;IF(E147<38; 3;IF(E147<50;4;IF(E147<62;5;IF(E147<74;6;IF(E147<8 6;7;8))))))))
Các bạn có thể giúp mình với công thức này có thể lọc ra các loại thâm niên 8,9,10 ko?
Đại chỉ mail của mình là anhthutran3110@yahoo.com.vn
Chân thành cảm ơn các bạn đã giúp.

 

[be heo 68]

Mình muốn hỏi làm thế nào có thể dò tìm được tháng làm việc của nhân viên như bảng sau :
Loại thâm niên - Số tháng làm việc
0 < 8
1 < 14
2 < 26
3 < 38
4 < 50
5 < 62
6 < 74
7 < 86
8 < 98
9 < 110
10 > 110
file View attachment loai tham nien.xls
Mình làm nhưng chỉ được tới loại 8 với công thức sau :

=IF(E147<8;0;IF(E147<14;1;IF(E147<26;2;IF(E147<38; 3;IF(E147<50;4;IF(E147<62;5;IF(E147<74;6;IF(E147<8 6;7;8))))))))
Các bạn có thể giúp mình với công thức này có thể lọc ra các loại thâm niên 8,9,10 ko?
Đại chỉ mail của mình là anhthutran3110@yahoo.com.vn
Chân thành cảm ơn các bạn đã giúp.

 

[Ba Tê]

Mình muốn hỏi làm thế nào có thể dò tìm được tháng làm việc của nhân viên như bảng sau :
Loại thâm niên - Số tháng làm việc
0 < 8
1 < 14
2 < 26
3 < 38
4 < 50
5 < 62
6 < 74
7 < 86
8 < 98
9 < 110
10 > 110
file View attachment 88247
Mình làm nhưng chỉ được tới loại 8 với công thức sau :

=IF(E147<8;0;IF(E147<14;1;IF(E147<26;2;IF(E147<38; 3;IF(E147<50;4;IF(E147<62;5;IF(E147<74;6;IF(E147<8 6;7;8))))))))
Các bạn có thể giúp mình với công thức này có thể lọc ra các loại thâm niên 8,9,10 ko?
Đại chỉ mail của mình là anhthutran3110@yahoo.com.vn
Chân thành cảm ơn các bạn đã giúp.

Bạn nên tạo một Bảng dò tìm ở đâu đó rồi dùng Vlookup()

|

A​

|

B​

|

1​

|

0​

|

0​

|

2​

|

8​

|

1​

|

3​

|

14​

|

2​

|

4​

|

26​

|

3​

|

5​

|

38​

|

4​

|

6​

|

50​

|

5​

|

7​

|

62​

|

6​

|

8​

|

74​

|

7​

|

9​

|

86​

|

8​

|

10​

|

98​

|

9​

|

11​

|

110​

|

10​

|

Công thức ô E6:

=VLOOKUP(D6;Bang;2)

 

[leonguyenz]

Mình muốn hỏi làm thế nào có thể dò tìm được tháng làm việc của nhân viên như bảng sau :
Loại thâm niên - Số tháng làm việc
0 < 8
1 < 14
2 < 26
3 < 38
4 < 50
5 < 62
6 < 74
7 < 86
8 < 98
9 < 110
10 > 110
file View attachment 88247
Mình làm nhưng chỉ được tới loại 8 với công thức sau :

=IF(E147<8;0;IF(E147<14;1;IF(E147<26;2;IF(E147<38; 3;IF(E147<50;4;IF(E147<62;5;IF(E147<74;6;IF(E147<8 6;7;8))))))))
Các bạn có thể giúp mình với công thức này có thể lọc ra các loại thâm niên 8,9,10 ko?
Đại chỉ mail của mình là anhthutran3110@yahoo.com.vn
Chân thành cảm ơn các bạn đã giúp.

Bạn sửa lại bảng điều kiện và dùng Vlookup: =VLOOKUP(D6,$G$6:$H$16,2)

 

[exciter1889]

Cho e ké xiu nge bác, e muốn lập công thức cho ví dụ sau thì làm sao ạh
Nếu ô A1<=20 thì B1 = Rất Thấp
Nếu ô A1<=30 thì B1 = Thấp
Nếu ô A1<=50 thì B1 = Vừa
Nếu ô A1>60 thì B1 = Cao
Các bác chỉ giáo giúp e với

 

[thanhsangnguyen1982]

Công thức tại ô B1=If(A1<=20,"Rất Thấp",if(A1<=30,"Thấp",If(A1<=50,"Vừa",if(A1<60,"Vừa Vừa","Cao"))))

 

[ChanhTQ@]

Mình muốn hỏi làm thế nào có thể dò tìm được tháng làm việc của nhân viên như bảng sau :
Loại thâm niên Số tháng làm việc
0 < 8
1 < 14
2 < 26
3 < 38
4 < 50
5 < 62
6 < 74
7 < 86
8 < 98
9 < 110
10 > 110
Chân thành cảm ơn các bạn đã giúp.

Hai IF() là đủ & bạn kiểm tra thử nha:

Công thức tại ô [E6] như sau:

=IF(D6<8,0,IF(D6>=110,10,INT((D6-2)/12)+1))​

 

[exciter1889]

Công thức tại ô B1=If(A1<=20,"Rất Thấp",if(A1<=30,"Thấp",If(A1<=50,"Vừa",if(A1<60,"Vừa Vừa","Cao"))))

Cảm ơn bác nhưng sao e làm như vậy vẫn không được,hic

 

[thanhsangnguyen1982]

Nó báo như thế nào. bạn thử thay chỗ nào dấu , thành dấu ; xem

 

[exciter1889]

Nó báo như thế nào. bạn thử thay chỗ nào dấu , thành dấu ; xem

Được rồi bác ah, đổi dấu , thành dấu ; là ok,hehe
Chân thành cảm ơn bác, chúc bác nhiều sức khỏe nhé