Tạo bảng điểm động dựa vào điều kiện (2 người xem)

[huonglien1901]

Chào mọi người!

Em có vấn đề nhờ mọi người hỗ trợ.

Em có 2 bảng: bảng 1: bảng điểm động
bảng 2: bảng nhập vào
Bài toán có: có 5 phụ nữ và có 8 vòng đấu:, làm thế nào để phân bổ 5 phụ nữ vào 5 dòng, khi gõ số điểm vào thì nó tự phân bổ vào tên người phụ nữ đó.
Khi nhập vào bảng 2 thì bảng 1 tự phân bổ số điểm vào.

Em cảm ơn mọi người nhiều!

 

[Phuocam]

bảng 1: bảng điểm động
bảng 2: bảng nhập vào

Nếu số điểm luôn khác 0, có thể dùng:

=IFERROR(1/(1/VLOOKUP($C3,$C$11:$K$15,COLUMNS($C3:D3),0)),"")

 

[huonglien1901]

Nếu số điểm luôn khác 0, có thể dùng:

=IFERROR(1/(1/VLOOKUP($C3,$C$11:$K$15,COLUMNS($C3:D3),0)),"")

chưa đúng Anh ơi, làm thế nào phân bổ tên phụ nữ vào các dòng ở cột B.

 

[Ba Tê]

chưa đúng Anh ơi, làm thế nào phân bổ tên phụ nữ vào các dòng ở cột B.

Làm thí thí vầy đi:

Public Sub s_Gpe()
Dim Arr(), I As Long
Arr = Range("C11:LJ15").Value
For I = 1 To 5
    Arr(I, 10) = "=Sum(RC[-8]:RC[-1])"
Next I
Range("C3:L7") = Arr
Range("C3:L7").Sort Key1:=Range("L3"), Order1:=xlDescending
End Sub

 

[Phuocam]

chưa đúng Anh ơi, làm thế nào phân bổ tên phụ nữ vào các dòng ở cột B.

Bỗ sung thêm 2 công thức cột B và L.

 

[HieuCD]

chưa đúng Anh ơi, làm thế nào phân bổ tên phụ nữ vào các dòng ở cột B.

C3 =INDEX($C$11:$K$15,INDEX(MATCH(LARGE(MMULT($D$11:$K$15+0,--(ROW($1:$8)>0))+1/ROW($2:$6),$B3),MMULT($D$11:$K$15+0,--(ROW($1:$8)>0))+1/ROW($2:$6),0),),COLUMN(A1))

 

[huonglien1901]

C3 =INDEX($C$11:$K$15,INDEX(MATCH(LARGE(MMULT($D$11:$K$15+0,--(ROW($1:$8)>0))+1/ROW($2:$6),$B3),MMULT($D$11:$K$15+0,--(ROW($1:$8)>0))+1/ROW($2:$6),0),),COLUMN(A1))

Bỗ sung thêm 2 công thức cột B và L.

Em cảm ơn 2 Anh rất nhiều!
cùng là 01 bài toán nhưng 2 cách giải khác nhau.
Em gửi công thức của em, vận dụng hàm mmult để so sánh mảng
cách của em cũng tương tự với Anh Hiếu, giải thuật cũng tương tự nhau,

=INDEX($C$11:$K$15,MATCH(LARGE(MMULT(IF($D$11:$K$15<>"",$D$11:$K$15,0),{1;1;1;1;1;1;1;1}),ROWS($A$1:A1)),(COUNTIF($C$2:C2,$C$11:$C$15)=0)*MMULT(IF($D$11:$K$15<>"",$D$11:$K$15,0),{1;1;1;1;1;1;1;1}),0),COLUMNS($A$1:A1))

 

[Phan Thế Hiệp]

Chào mọi người!
Em có vấn đề nhờ mọi người hỗ trợ.
Em có 2 bảng: bảng 1: bảng điểm động
bảng 2: bảng nhập vào
Bài toán có: có 5 phụ nữ và có 8 vòng đấu:, làm thế nào để phân bổ 5 phụ nữ vào 5 dòng, khi gõ số điểm vào thì nó tự phân bổ vào tên người phụ nữ đó.
Khi nhập vào bảng 2 thì bảng 1 tự phân bổ số điểm vào.
Em cảm ơn mọi người nhiều!

Có đủ mặt anh em "bạn hiền", "hổng dô" uổng quá!

L3=LARGE(MMULT($D$11:$K$15*1,ROW($1:$8)^0),B3)
C3=OFFSET($C$10,MATCH(L3,INDEX(MMULT($D$11:$K$15*1,ROW($1:$8)^0)/(COUNTIF($C$2:C2,$C$11:$C$15)=0),),),)

Enter fill xuống

Nếu 1 công thức cho C3 thì ghép hai em ở trên vào thành:

C3=OFFSET($C$10,MATCH(LARGE(MMULT($D$11:$K$15*1,ROW($1:$8)^0),B3),INDEX(MMULT($D$11:$K$15*1,ROW($1:$8)^0)/(COUNTIF($C$2:C2,$C$11:$C$15)=0),),),)

Chỉ Enter, fill xuống.

Chúc anh em ngày vui.