[Giúp Đỡ] Tìm vị trí trong Excel. (7 người xem)

[fithui]

Dear Anh/Chị GPE.

Nhờ anh/chị hổ trợ giúp em trường hợp này với. Em có 2 bảng Excel: Bảng 1 chưa Data, Bảng 2 chứa giá trị.
Bây giờ em muốn lấy giá trị của Bảng 2 tìm trong Bảng 1 (như hàm vlookup), kết quả trả về là vị trí của giá trị đó theo định dạng: A1, B2, C3....
Bảng 1 của em chưa Data không có trùng nhau.

Em cám ơn anh chị.

 

[Nguyễn Hồng Quang]

Dear Anh/Chị GPE.

Nhờ anh/chị hổ trợ giúp em trường hợp này với. Em có 2 bảng Excel: Bảng 1 chưa Data, Bảng 2 chứa giá trị.
Bây giờ em muốn lấy giá trị của Bảng 2 tìm trong Bảng 1 (như hàm vlookup), kết quả trả về là vị trí của giá trị đó theo định dạng: A1, B2, C3....
Bảng 1 của em chưa Data không có trùng nhau.

Em cám ơn anh chị.

Ví dụ bạn đơn sơ quá, nên công thức gợi ý là
"B"&MATCH(F5;$B$1:$B$8;0)

 

[vanthinh3101]

Dear Anh/Chị GPE.

Nhờ anh/chị hổ trợ giúp em trường hợp này với. Em có 2 bảng Excel: Bảng 1 chưa Data, Bảng 2 chứa giá trị.
Bây giờ em muốn lấy giá trị của Bảng 2 tìm trong Bảng 1 (như hàm vlookup), kết quả trả về là vị trí của giá trị đó theo định dạng: A1, B2, C3....
Bảng 1 của em chưa Data không có trùng nhau.

Em cám ơn anh chị.

Bạn thử

G5=ADDRESS(MATCH(F5,$B$1:$B$8,0),2)

 

[Phan Thế Hiệp]

Dear Anh/Chị GPE.

Nhờ anh/chị hổ trợ giúp em trường hợp này với. Em có 2 bảng Excel: Bảng 1 chưa Data, Bảng 2 chứa giá trị.
Bây giờ em muốn lấy giá trị của Bảng 2 tìm trong Bảng 1 (như hàm vlookup), kết quả trả về là vị trí của giá trị đó theo định dạng: A1, B2, C3....
Bảng 1 của em chưa Data không có trùng nhau.

Em cám ơn anh chị.

Tiễn Phật tiễn về đến Tây thiên:

G5=HYPERLINK("#"&ADDRESS(MATCH(F5,$B$1:$B$100,),2,4),ADDRESS(MATCH(F5,$B$1:$B$100,),2,4))

Enter, fill xuống.
Click vào địa chỉ, con trỏ tự tìm đến ô đó.

Thân

 

[hml89]

Tiễn Phật tiễn về đến Tây thiên:

G5=HYPERLINK("#"&ADDRESS(MATCH(F5,$B$1:$B$100,),2,4),ADDRESS(MATCH(F5,$B$1:$B$100,),2,4))

Enter, fill xuống.
Click vào địa chỉ, con trỏ tự tìm đến ô đó.

Thân

Bạn cho tôi hỏi chút là nếu tìm trong 1khoảng (ví dụ A5:B10) thì làm như thế nào vậy?

 

[fithui]

Em xin cám ơn các anh, các chị.

 

[Phan Thế Hiệp]

Bạn cho tôi hỏi chút là nếu tìm trong 1khoảng (ví dụ A5:B10) thì làm như thế nào vậy?

Với các tên trái cây không được trùng lắp trong Vùng cần tìm.

=ADDRESS(MATCH(1,MMULT(N($A$1:$D$50=F5),{1;1;1;1}),),MATCH(1,COUNTIF(OFFSET($A$1:$A$50,,{0,1,2,3}),F5),),4)
Hoặc:
=ADDRESS(AGGREGATE(15,6,ROW($1:$50)/($A$1:$D$50=F5),1),AGGREGATE(15,6,COLUMN($A:$D)/($A$1:$D$50=F5),1),4)

Enter, fill xuống.

Thân

 

[Phi Hao]

Cho em hỏi nếu trong trường hợp để tim khác sheet thì sau khi tìm có ra địa chỉ ô và tên sheet không (em đã thử và nó không ra tên sheet chỉ ra địa chỉ ô)?

 

[Phan Thế Hiệp]

Cho em hỏi nếu trong trường hợp để tim khác sheet thì sau khi tìm có ra địa chỉ ô và tên sheet không (em đã thử và nó không ra tên sheet chỉ ra địa chỉ ô)?

Rút kinh nghiệm cho lần sau bạn muốn hỏi thành viên nào trong chủ đề, thì nhấn nút "Trả lời" bên phải dưới của bài.
Nếu 2 bảng nằm tại hai sheet khác nhau thì phải điều chỉnh bổ sung thêm tên sheet cho công thức:

=ADDRESS(MATCH(1,MMULT(N(Data!$A$1:$D$50=A2),{1;1;1;1}),),MATCH(1,COUNTIF(OFFSET(Data!$A$1:$A$50,,{0,1,2,3}),A2),),4,,MID(CELL("filename",Data!$A$1),FIND("]",CELL("filename",Data!$A$1))+1,100) )​

Thân

 

[Phi Hao]

Rút kinh nghiệm cho lần sau bạn muốn hỏi thành viên nào trong chủ đề, thì nhấn nút "Trả lời" bên phải dưới của bài.
Nếu 2 bảng nằm tại hai sheet khác nhau thì phải điều chỉnh bổ sung thêm tên sheet cho công thức:

=ADDRESS(MATCH(1,MMULT(N(Data!$A$1:$D$50=A2),{1;1;1;1}),),MATCH(1,COUNTIF(OFFSET(Data!$A$1:$A$50,,{0,1,2,3}),A2),),4,,MID(CELL("filename",Data!$A$1),FIND("]",CELL("filename",Data!$A$1))+1,100) )​

Thân

Cám ơn anh

 

[hml89]

Rút kinh nghiệm cho lần sau bạn muốn hỏi thành viên nào trong chủ đề, thì nhấn nút "Trả lời" bên phải dưới của bài.
Nếu 2 bảng nằm tại hai sheet khác nhau thì phải điều chỉnh bổ sung thêm tên sheet cho công thức:

=ADDRESS(MATCH(1,MMULT(N(Data!$A$1:$D$50=A2),{1;1;1;1}),),MATCH(1,COUNTIF(OFFSET(Data!$A$1:$A$50,,{0,1,2,3}),A2),),4,,MID(CELL("filename",Data!$A$1),FIND("]",CELL("filename",Data!$A$1))+1,100) )​

Thân

Hữu ích quá , cám ơn @Phan Thế Hiệp

 

[Vu_Ha_HN]

Rút kinh nghiệm cho lần sau bạn muốn hỏi thành viên nào trong chủ đề, thì nhấn nút "Trả lời" bên phải dưới của bài.
Nếu 2 bảng nằm tại hai sheet khác nhau thì phải điều chỉnh bổ sung thêm tên sheet cho công thức:

=ADDRESS(MATCH(1,MMULT(N(Data!$A$1:$D$50=A2),{1;1;1;1}),),MATCH(1,COUNTIF(OFFSET(Data!$A$1:$A$50,,{0,1,2,3}),A2),),4,,MID(CELL("filename",Data!$A$1),FIND("]",CELL("filename",Data!$A$1))+1,100) )​

Thân

Chào bạn Hiệp!
Mình có bị vướng trong mục này.
Mình có bảng theo dõi sản phẩm bán ra theo từng cửa hàng rồi theo từng ngày trong tháng của cửa hàng đó trong sheet "theo doi hang ngay", giờ mình muốn tổng hợp tên những sản phẩm bán theo ngàycủa từng cửa hàng trong sheet "tong hop ngay", thì mình dùng công thức nào để gộp tên của các sản phẩm bán trong cùng 1 ngày của 1 cửa hàng (theo mẫu làm thủ công trong sheet "tong hop ngay").
Cảm ơn bạn.

 

[Phan Thế Hiệp]

Chào bạn Hiệp!
Mình có bị vướng trong mục này.
Mình có bảng theo dõi sản phẩm bán ra theo từng cửa hàng rồi theo từng ngày trong tháng của cửa hàng đó trong sheet "theo doi hang ngay", giờ mình muốn tổng hợp tên những sản phẩm bán theo ngàycủa từng cửa hàng trong sheet "tong hop ngay", thì mình dùng công thức nào để gộp tên của các sản phẩm bán trong cùng 1 ngày của 1 cửa hàng (theo mẫu làm thủ công trong sheet "tong hop ngay").
Cảm ơn bạn.

Yêu cầu của bạn khác với chủ đề này.
Bạn nên mở chủ đề mới bên box: "Lập trình với Excel" với tiêu đề "Lập danh sách đã loại trùng và theo điều kiện"

Thân.

 

[Vu_Ha_HN]

Yêu cầu của bạn khác với chủ đề này.
Bạn nên mở chủ đề mới bên box: "Lập trình với Excel" với tiêu đề "Lập danh sách đã loại trùng và theo điều kiện"

Thân.

Cảm ơn Hiệp đã trả lời.
Vì mình cũng đã tìm được đoạn sau để gộp dữ liệu, tuy nhiên mình chưa tìm được cách để định vị ô dữ liệu.
Ví dụ: (cột A) (cột B)
(hàng 3) Ngày 1/04 tổ 1
...
(hàng 33) Ngày 30/04 tổ 1

(hàng 35) Ngày 1/04 tổ 2
...
(hàng 68) Ngày 1/04 tổ 2

Giờ mình muốn xác định hàng thứ bao nhiêu chứa cả 2 thông tin Ngày 5/04 và tổ 2, và công thức tương tự với những tổ phía dưới. Mà ở đây không làm thêm cột phụ.

Mong bạn trả lời giúp mình. Thanks,

 

[Phan Thế Hiệp]

Cảm ơn Hiệp đã trả lời.
Vì mình cũng đã tìm được đoạn sau để gộp dữ liệu, tuy nhiên mình chưa tìm được cách để định vị ô dữ liệu.
Ví dụ: (cột A) (cột B)
(hàng 3) Ngày 1/04 tổ 1
...
(hàng 33) Ngày 30/04 tổ 1

(hàng 35) Ngày 1/04 tổ 2
...
(hàng 68) Ngày 1/04 tổ 2

Giờ mình muốn xác định hàng thứ bao nhiêu chứa cả 2 thông tin Ngày 5/04 và tổ 2, và công thức tương tự với những tổ phía dưới. Mà ở đây không làm thêm cột phụ.

Mong bạn trả lời giúp mình. Cảm ơn,

Thử:

D3=IF(N(A3)>0,HYPERLINK("#"&ADDRESS(LOOKUP(2,1/(A3='theo doi hang ngay'!$A$3:$A$100)/(B3='theo doi hang ngay'!$B$3:$B$100),ROW($A$3:$A$100)),1,4,,"theo doi hang ngay")),"")

Enter, fill xuống.

Thân

 

[Vu_Ha_HN]

Thử:

D3=IF(N(A3)>0,HYPERLINK("#"&ADDRESS(LOOKUP(2,1/(A3='theo doi hang ngay'!$A$3:$A$100)/(B3='theo doi hang ngay'!$B$3:$B$100),ROW($A$3:$A$100)),1,4,,"theo doi hang ngay")),"")

Enter, fill xuống.

Thân

Cảm ơn bạn,
Ý mình là muốn biết dữ liệu (ngày&tổ) ở hàng số bao nhiêu, vì số này sẽ được mình dùng trong hàm index để lấy dữ liệu ở 1 cột đã xác định khác (lấy dữ liệu tại hàng được xác định ở trên).
Giúp mình với. Thanks.

 

[Phan Thế Hiệp]

Cảm ơn bạn,
Ý mình là muốn biết dữ liệu (ngày&tổ) ở hàng số bao nhiêu, vì số này sẽ được mình dùng trong hàm index để lấy dữ liệu ở 1 cột đã xác định khác (lấy dữ liệu tại hàng được xác định ở trên).
Giúp mình với. Cảm ơn.

Thử:

D3=IF(N($A3)>0,AGGREGATE(15,6,ROW($1:$100)/($A3='theo doi hang ngay'!$A$1:$A$100)/($B3='theo doi hang ngay'!$B$1:$B$100),1),"")

Enter, fill xuống.

Thân

 

[Vu_Ha_HN]

Thử:

D3=IF(N($A3)>0,AGGREGATE(15,6,ROW($1:$100)/($A3='theo doi hang ngay'!$A$1:$A$100)/($B3='theo doi hang ngay'!$B$1:$B$100),1),"")

Enter, fill xuống.

Thân

Cảm ơn bạn. Tớ đang nghiên cứu công thức của bạn.

 

[Phan Thế Hiệp]

Cảm ơn bạn. Tớ đang nghiên cứu công thức của bạn.

Vậy bạn nghiên cứu công thức này tương đối dễ hiểu hơn:

E3=IF(N($A3)>0,MATCH(A3,INDEX('theo doi hang ngay'!$A$1:$A$100/(B3='theo doi hang ngay'!$B$1:$B$100),),),"")

Enter, fill xuống.

Thân

 

[Phi Hao]

Vậy bạn nghiên cứu công thức này tương đối dễ hiểu hơn:

E3=IF(N($A3)>0,MATCH(A3,INDEX('theo doi hang ngay'!$A$1:$A$100/(B3='theo doi hang ngay'!$B$1:$B$100),),),"")

Enter, fill xuống.

Thân

Anh Phan Thế Hiệp ơi, anh có tài liệu học VBA không (sách, phim hướng dẫn từ cơ bản đến nâng cao, liên tục các bài không ngắt quãng) cho em với để em tự học vì em không có thời gian đi học, em tự lên Youtube học có các bài giảng nhưng không có liên tục được nên khó hiểu, nếu anh có biết kênh nào hay thì chỉ giúp, cảm ơn anh.