Hàm Tính Tổng Số Tuần Hoàn trong excel. (2 người xem)

[truongquangtrong]

Chào anh/chị.
Em đang học tập excel và có câu hỏi tham khảo ý kiến anh/chị.
Nhờ các anh/chị giúp em một vấn đề này:
- Ở ô A1 là ngày: 3/2/2016
- Ở ô A2 là ngày: 18/2/2016
- Ở ô A3 mình viết công thức: =weeknum(A2)-Weeknum(A1) thì kết quả trả về sẽ là: 2
Tuy nhiên trong khoảng thời gian nêu trên, chỉ có 1 tuần là đủ từ thứ 2 đến chủ nhật.
Như vật kết quả mong muốn của mình là tìm số tuần nguyên (là số tuần đủ các ngày từ thứ 2 đến chủ nhật) trong một khoảng thời gian bất kì
Cảm ơn tất cả.
Xem thêm>>> https://internetvietnam.net/

 

[Ba Tê]

Chào anh/chị.
Em đang học tập excel và có câu hỏi tham khảo ý kiến anh/chị.
Nhờ các anh/chị giúp em một vấn đề này:
- Ở ô A1 là ngày: 3/2/2016
- Ở ô A2 là ngày: 18/2/2016
- Ở ô A3 mình viết công thức: =weeknum(A2)-Weeknum(A1) thì kết quả trả về sẽ là: 2
Tuy nhiên trong khoảng thời gian nêu trên, chỉ có 1 tuần là đủ từ thứ 2 đến chủ nhật.
Như vật kết quả mong muốn của mình là tìm số tuần nguyên (là số tuần đủ các ngày từ thứ 2 đến chủ nhật) trong một khoảng thời gian bất kì
Cảm ơn tất cả.

Tôi chưa nghĩ ra công thức, dùng tạm hàm tự tạo nhé:

Public Function GPE(d1 As Long, d2 As Long) As Long
Dim I As Long, DK As Boolean
For I = d1 To d2
    If Weekday(I) = 2 Then DK = True
    If Weekday(I) = 1 And DK = True Then GPE = GPE + 1
Next I
End Function

A3=GPE(A1,A2)

 

[quocgiacan]

Chào anh/chị.
Em đang học tập excel và có câu hỏi tham khảo ý kiến anh/chị.
Nhờ các anh/chị giúp em một vấn đề này:
- Ở ô A1 là ngày: 3/2/2016
- Ở ô A2 là ngày: 18/2/2016
- Ở ô A3 mình viết công thức: =weeknum(A2)-Weeknum(A1) thì kết quả trả về sẽ là: 2
Tuy nhiên trong khoảng thời gian nêu trên, chỉ có 1 tuần là đủ từ thứ 2 đến chủ nhật.
Như vật kết quả mong muốn của mình là tìm số tuần nguyên (là số tuần đủ các ngày từ thứ 2 đến chủ nhật) trong một khoảng thời gian bất kì
Cảm ơn tất cả.

Tiếp nối anh Ba Tê bằng công thức mảng:

=COUNT(1/(FREQUENCY(WEEKNUM(ROW(INDIRECT(A1&":"&A2))),ROW($1:$53))=7))

Ctrl+Shift+Enter

Chúc bạn ngày vui.

 

[VetMini]

Có ít nhất 1 cách:

đem ngày đầu, tìm ngày thứ 2 gần nhất: =CEILING(A1-2,7)+2
trừ 2 ngày, cộng cho 1, chia cho 7, và bỏ số lẻ

 

[HieuCD]

có thể dùng công thức

=(A2-A1-WEEKDAY(A2)-MOD(8-WEEKDAY(A1,2),7)+2)/7

 

[quocgiacan]

có thể dùng công thức

=(A2-A1-WEEKDAY(A2)-MOD(8-WEEKDAY(A1,2),7)+2)/7

Cách của bạn hiền đơn giản hơn nhiều há!

Công thức bài số #3 của mình chưa chính xác nếu như tính qua nhiều năm, ví dụ: 01/01/2014 đến 25/01/2017 nó không ra chính xác, phải vầy mới đúng:

=SUM(IFERROR(INT(FREQUENCY(WEEKNUM(ROW(INDIRECT(A1&":"&A2))),ROW($1:$53))/7),""))

Ctrl+Shift+Enter.

Dù sao cũng rườm rà há, được cái là có cơ hội luyện để hiểu rõ FREQUENCY() và WEEKNUM(), hì hì.

Chúc bạn ngày vui.

 

[leoheocon]

Thêm 1 cách góp vui:

=INT((A2-6+WEEKDAY(A1-1,2)-A1)/7)

 

[leoheocon]

Cách của bạn hiền đơn giản hơn nhiều há!

Công thức bài số #3 của mình chưa chính xác nếu như tính qua nhiều năm, ví dụ: 01/01/2014 đến 25/01/2017 nó không ra chính xác, phải vầy mới đúng:

=SUM(IFERROR(INT(FREQUENCY(WEEKNUM(ROW(INDIRECT(A1&":"&A2))),ROW($1:$53))/7),""))

Ctrl+Shift+Enter.

Dù sao cũng rườm rà há, được cái là có cơ hội luyện để hiểu rõ FREQUENCY() và WEEKNUM(), hì hì.

Chúc bạn ngày vui.

CT này của anh hình chưa đúng với từ ngày 1/2/2016->28/2/2016 (4 tuần)!!!

 

[quocgiacan]

CT này của anh hình chưa đúng với từ ngày 1/2/2016->28/2/2016 (4 tuần)!!!

À!

Cảm ơn em trai Weeknum(....,21) mới đúng, hì hì.

Chúc em ngày thiệt vui.

 

[HieuCD]

Cách của bạn hiền đơn giản hơn nhiều há!

Công thức bài số #3 của mình chưa chính xác nếu như tính qua nhiều năm, ví dụ: 01/01/2014 đến 25/01/2017 nó không ra chính xác, phải vầy mới đúng:

=SUM(IFERROR(INT(FREQUENCY(WEEKNUM(ROW(INDIRECT(A1&":"&A2))),ROW($1:$53))/7),""))

Ctrl+Shift+Enter.

Dù sao cũng rườm rà há, được cái là có cơ hội luyện để hiểu rõ FREQUENCY() và WEEKNUM(), hì hì.

Chúc bạn ngày vui.

hàm mảng quá khó, nhiều lúc không hình dung được kết quả như thế nào, bạn kết hợp các hàm thứ dữ thật khâm phục
chúc bạn một ngày vui

 

[quocgiacan]

hàm mảng quá khó, nhiều lúc không hình dung được kết quả như thế nào, bạn kết hợp các hàm thứ dữ thật khâm phục
chúc bạn một ngày vui

Còn thua xa một "ông kẹ" em trai! nghe tên là toát mồ hôi với ổng

khà khà khà!

Chúc anh em mình có ngày thiệt vui.

 

[HieuCD]

Thêm 1 cách góp vui:

=INT((A2-6+WEEKDAY(A1-1,2)-A1)/7)

dùng hàm int gọn hơn, nhưng tìm các số -6,-1,2 hơi mệt óc
các hàm trên vẫn còn vướng số âm có lẽ phải thêm hàm max

=MAX(INT((A2-6+WEEKDAY(A1-1,2)-A1)/7),0)
=MAX(INT((A2-A1+2-WEEKDAY(A2-7))/7),0)
=MAX((A2-A1-WEEKDAY(A2)-MOD(8-WEEKDAY(A1,2),7)+2)/7,0)

 

[Ba Tê]

Theo gợi ý của VetMini bài #4 chắc công thức này:

=INT((A2-CEILING(A1-2;7))/7)

 

[HieuCD]

Theo gợi ý của VetMini bài #4 chắc công thức này:

=INT((A2-CEILING(A1-2;7))/7)

còn vài trường hợp chưa chuẩn như 3/1/16 đến 9/1/16
chỉnh lại 1 chút
=INT((A2-CEILING(A1-2,7)-1)/7)
hoặc đầy đủ hơn
=MAX(INT((A2-CEILING(A1-2,7)-1)/7),0)