Cách sử dụng hàm find trong excel (1 người xem)

[truongquangtrong]

Chào các anh/chị em đang thắc mắc về vấn đề sử dụng hàm find trong excel mong được sự chỉ bảo của các cao nhân.


Em muốn tìm vị trí của một kí tự trong chuỗi, nhưng khi kí tự đó không có thì xuất hiện lỗi #value, em muốn sửa thành 0 thì làm thế nào.
Tiện thể mình hỏi thêm là nếu có 2 kí tự giống nhau nhưng dùng hàm find bình thường chỉ cho ra vị trí của kí tự đầu tiên mình muốn cho ra vị trí của cả hai thì làm thế nào?
Cảm ơn anh/chị.
Xem thêm>>> https://internetvietnam.net/

 

[nghiaphuc]

Chào các anh/chị em đang thắc mắc về vấn đề sử dụng hàm find trong excel mong được sự chỉ bảo của các cao nhân.


Em muốn tìm vị trí của một kí tự trong chuỗi, nhưng khi kí tự đó không có thì xuất hiện lỗi #value, em muốn sửa thành 0 thì làm thế nào.
Tiện thể mình hỏi thêm là nếu có 2 kí tự giống nhau nhưng dùng hàm find bình thường chỉ cho ra vị trí của kí tự đầu tiên mình muốn cho ra vị trí của cả hai thì làm thế nào?
Cảm ơn anh/chị.

Câu hỏi 1: Bạn lồng thêm hàm IFERROR ở ngoài hàm FIND, kiểu thế này: =IFERROR(FIND(...),0) (công thức này chỉ dùng cho Excel từ 2007 trở lên) hoặc =IF(ISERR(FIND(...)),0,FIND(...)) (cho mọi phiên bản Excel)
Câu hỏi 2: Bạn có thể lồng 2 hàm FIND vào nhau, hàm FIND bên trong là tham số thứ 3 của hàm FIND bên ngoài, kiểu thế này: =FIND(S1,S2,FIND(S1,S2))

 

[befaint]

#value thành 0:

=IFERROR(FIND("kytu",A1),0)

nếu có 2 kí tự giống nhau, tìm vị trị ký tự thứ hai:

=IFERROR(FIND("kytu",A1,FIND("kytu",A1)+FIND("kytu",A1)>1),0)

 

[Nguyễn Hồng Quang]

Công thức của bác befaint ẩu quá
Người ta viết là tìm vị trí của cả 2 kí tự mà

Ví dụ A1 có chuỗi sau: sdfsadfa
Tìm vị trí các chữ a trong chuỗi: =IFERROR(FIND("a";A1)&";"&IFERROR(FIND("a";A1;FIND("a";A1)+1);" ");0)
Còn nếu có n kí tự giống nhau thì hàm sẽ phức tạp hơn (có khi còn phải dùng tới VBA )

 

[quocgiacan]

Công thức của bác befaint ẩu quá
Người ta viết là tìm vị trí của cả 2 kí tự mà

Ví dụ A1 có chuỗi sau: sdfsadfa
Tìm vị trí các chữ a trong chuỗi: =IFERROR(FIND("a";A1)&";"&IFERROR(FIND("a";A1;FIND("a";A1)+1);" ");0)
Còn nếu có n kí tự giống nhau thì hàm sẽ phức tạp hơn (có khi còn phải dùng tới VBA )

Tại "bác" befaint chưa trổ tài thiệt ra chứ không như bạn hiểu lầm vậy đâu!

Cái công thức dưới đây là tôi học mót của bác ấy nè bạn.
Giả sử: B2 chứa ký tự cần tìm (vd: "a"), C2 là ký tự thứ mấy mà bạn muốn tìm số vị trí (vd: 2), bạn dùng công thức mảng sau:

=IFERROR(SMALL(IF(MID(A3,ROW($1:$100),1)=B2,FIND(B2,A3,ROW($1:$100))),C2),"không có")

Ctrl+Shift+Enter

Thêm một công thức của bác ấy nữa nè, đơn giản hơn:

=FIND("#",SUBSTITUTE(A3,B2,"#",C2))

Enter
Còn muốn biết có bao nhiêu ký tự cần tìm thì dùng:

=LEN(A3)-LEN(SUBSTITUTE(A3,B2,""))

Enter

Bạn có thể xem file đính kèm.

Chúc bạn ngày vui.
p/s: chưa nói đến nếu bạn ấy xuất chiêu VBA, khà khà khà! còn ác nữa.

 

[befaint]

Anh quocgiacan,

Cảm ơn anh

Chúc anh tối vui!

(Em đang dùng điện thoại)