Tìm ngày bắt đầu có khoảng trắng nhiều phía sau

[hoangexcell]

Xin xem file đính kèm và trợ giúp mình nhé!
Xin cảm ơn!

 

[Quang_Hải]

Xin xem file đính kèm và trợ giúp mình nhé!
Xin cảm ơn!

Cái này dùng hàm tự tạo thì không khó, công thức thì chắc khó

 

[mhung12005]

Xin xem file đính kèm và trợ giúp mình nhé!
Xin cảm ơn!

Bạn dùng công thức mảng sau:

=INDEX($B$4:$AB$4,,MATCH(TRUE,B5:AB5<>"")+1)

Ctrl + Shift + Enter.


Nếu dùng cái này Enter bình thường:

=INDEX($B$4:$AB$4,,LOOKUP(2,1/(B5:AB5<>""),COLUMN(B5:AB5)))

 

[ndu96081631]

Nếu dùng cái này Enter bình thường:

=INDEX($B$4:$AB$4,,LOOKUP(2,1/(B5:AB5<>""),COLUMN(B5:AB5)))

Nếu LOOKUP thì tôi làm vầy:

=LOOKUP(2,1/(A5:AA5<>""),$B$4:$AB$4)

 

[hoangexcell]

Thích cái vụ 1/ của Thầy ndu96081631 quá. Quả là hay. Xưa nay ít nhớ tới hàm lookup...

Nếu được Thầy giải thích thêm cái vụ 1/ . Em cảm ơn!

 

[siwtom]

Thích cái vụ 1/ của Thầy ndu96081631 quá. Quả là hay. Xưa nay ít nhớ tới hàm lookup...

Nếu được Thầy giải thích thêm cái vụ 1/ . Em cảm ơn!

Không được mời ăn cỗ nên hơi vô duyên.

Cơ sở lập luận, hay cái gọi là triết lý của cấu trúc LOOKUP(2; 1 / (...) theo tôi dựa trên nền tảng 2 điểm chính:

1. Hàm LOOKUP không bị lỗi khi trong vùng dò có những giá trị lỗi và những giá trị không cùng kiểu với giá trị cần tìm. VD. ta tìm giá trị 2 mà trong vùng tìm có giá trị #DIV/0!, #VALUE, "hichic" thì hàm LOOKUP lờ chúng đi, coi như không nhìn thấy chúng, coi như chúng không có hay coi chúng là không khí. Hàm SUM lờ các giá trị không là số, vd. "hichic" nhưng sẽ bị lỗi nếu vùng có giá trị lỗi, tức vd. #DIV/0!, #VALUE

Bạn thử code dưới đây thì sẽ rõ:

a. A1 = 0, A2 = 1 / A1, A3 = "hichic", A4 = 3, A5 = A3*1, A6 = 5

b. code

công thức cho C1 =LOOKUP(4;A1:A6)
công thức cho D1 =SUM(A1:A6)
công thức cho E1 =SUM(A3:A4)

Trong D1 có #DIV/0! do dữ liệu có lỗi, trong E1 có 3 do "hichic" bị SUM lờ đi, còn trong C1 có 3 do các lỗi #DIV/0!, #VALUE và giá trị khác kiểu với giá trị cần tìm, tức "hichic", đều bị LOOKUP "lờ" đi.

2. 1 / (...) ta dùng khi (...) trả về các giá trị TRUE / FALSE hoặc 1 / 0.
Lúc đó 1 / (...) trả về 1 (khi (...) trả về TRUE / 1) hoặc #DIV/0! (khi (...) trả về FALSE / 0). Tức lúc này vùng tìm kiếm chỉ chứa các giá trị 1 hoặc #DIV/0!. Do ta tìm 2 mà các giá trị #DIV/0! bị LOOKUP lờ đi, tức coi như vùng tìm chỉ có toàn giá trị 1, nên rõ ràng giá trị 2 không được tìm thấy. Vậy LOOKUP trả về giá trị 1 cuối cùng hoặc nếu có result_vector thì trả về giá trị tương ứng với 1 cuối cùng

Nếu bạn đọc kỹ và hiểu thì thấy là ta cố tình tìm giá trị mà dứt khoát là sẽ không tìm thấy trong vùng chỉ có toàn 1, và ta muốn trả về 1 cuối cùng nên giá trị đó phải > 1. Đó là "thuộc tính" duy nhất của giá trị tìm. Vậy thay cho 2 ta có thể tìm bất cứ giá trị nào > 1. Vd. LOOKUP(12345; 1 / (...)
--------------
Trên GPE đã có nhiều giải thích nhưng tất nhiên bạn không chịu tìm kiếm. Ngoài ra không chỉ GPE dùng cấu trúc LOOKUP(2; 1 / (...). Nếu bạn biết dùng google thì bạn thấy đầy. Cả giải thích cũng có.

 

[hoangexcell]

Không được mời ăn cỗ nên hơi vô duyên.

...

--------------
Trên GPE đã có nhiều giải thích nhưng tất nhiên bạn không chịu tìm kiếm. Ngoài ra không chỉ GPE dùng cấu trúc LOOKUP(2; 1 / (...). Nếu bạn biết dùng google thì bạn thấy đầy. Cả giải thích cũng có.

Cám ơn nhé! thật ra cũng hay tìm kiếm nhiều thứ lắm chứ. Vì quên thôi, do đang xem bài thích quá viết câu hỏi luôn. Mấy tháng trước có đọc 1 bài nào đó Thầy ndu cũng có 1/ trong hàm lookup và cũng chưa hiểu lắm. Nay với giải thích của Bạn đã hiểu gốc rễ rùi.
Vì bài viết cũng khá là nhiều nên đôi khi chưa tìm thấy đúng bài mà có giải thích làm mình hiểu .

Cuối tuần vui vẻ & hạnh phúc!