Group 2 đoạn thẳng

[N2NTrung]

Nhờ các bạn giúp mình Group 2 đoạn thẳng 1 & 2 lại với. Mình thử Group loạn lên mà chẳng làm được.

 

[BNTT]

File có đuôi là dvb là file gì vậy bạn ?

 

[N2NTrung]

à file đuôi dvb là marco của Acad, nhấn Alt + F8, vào VBA manager, chọn đường dẫn tới file và load. Nhấn Alt + F8 chọn Run là chạy mà.

 

[nvson]

Đây là đoạn code Group các đối tượng mình lấy từ help.

Sub Example_AppendItems()
    ' This example creates a group and several objects.
    ' It then appends the objects to the group.
    
    ' Create the new group
    Dim groupObj As AcadGroup
    Set groupObj = ThisDrawing.Groups.Add("TEST_GROUP")
            
    ' Create a Ray object in model space
    Dim rayObj As AcadRay
    Dim basePoint(0 To 2) As Double
    Dim SecondPoint(0 To 2) As Double
    basePoint(0) = 3#: basePoint(1) = 3#: basePoint(2) = 0#
    SecondPoint(0) = 1#: SecondPoint(1) = 3#: SecondPoint(2) = 0#
    Set rayObj = ThisDrawing.ModelSpace.AddRay(basePoint, SecondPoint)
    
    ' Create a polyline object in model space
    Dim plineObj As AcadLWPolyline
    Dim points(0 To 5) As Double
    points(0) = 3: points(1) = 7
    points(2) = 9: points(3) = 2
    points(4) = 3: points(5) = 5
    Set plineObj = ThisDrawing.ModelSpace.AddLightWeightPolyline(points)
    plineObj.Closed = True
    ' Create a line object in model space
    Dim lineObj As AcadLine
    Dim startPoint(0 To 2) As Double
    Dim endPoint(0 To 2) As Double
    startPoint(0) = 0: startPoint(1) = 0: startPoint(2) = 0
    endPoint(0) = 2: endPoint(1) = 2: endPoint(2) = 0
    Set lineObj = ThisDrawing.ModelSpace.AddLine(startPoint, endPoint)
    
    ' Create a circle object in model space
    Dim circObj As AcadCircle
    Dim centerPt(0 To 2) As Double
    Dim radius As Double
    centerPt(0) = 20: centerPt(1) = 30: centerPt(2) = 0
    radius = 3
    Set circObj = ThisDrawing.ModelSpace.AddCircle(centerPt, radius)
    ' Create an ellipse object in model space
    Dim ellObj As AcadEllipse
    Dim majAxis(0 To 2) As Double
    Dim center(0 To 2) As Double
    Dim radRatio As Double
    center(0) = 5#: center(1) = 5#: center(2) = 0#
    majAxis(0) = 10: majAxis(1) = 20#: majAxis(2) = 0#
    radRatio = 0.3
    Set ellObj = ThisDrawing.ModelSpace.AddEllipse(center, majAxis, radRatio)
    ZoomAll
    
    ' Iterate through the model space collection.
    ' Collect the objects found into an array of objects
    ' to be added to the group.
[COLOR=red]    ReDim appendObjs(0 To ThisDrawing.ModelSpace.Count - 1) As AcadEntity
    Dim I As Integer
    For I = 0 To ThisDrawing.ModelSpace.Count - 1
        Set appendObjs(I) = ThisDrawing.ModelSpace.Item(I)
    Next
    
    ' Add the array of objects to the group
    groupObj.AppendItems appendObjs
[/COLOR]    
    ThisDrawing.Regen acActiveViewport
    
End Sub

hãy chú ý đến những dòng lệnh mầu đỏ nhé!

@BNTT: file dvb được dùng để viết các lệnh cho AutoCAD

 

[tigertiger]

oh, Vào lại GPE thấy nvson giúp bạn, chắc là làm được rùi...
Đúng là chúng ta phải cho các obj vào mảng trước
từ sau dòng On Error Rếum Next , bạn lam như sau:

......
On Error Resume Next
    Set GroupLine = ThisDrawing.Groups.Add("tigertiger")
    Dim ag(1) As AcadEntity
    Set ag(0) = objLine1
    Set ag(1) = objLine2
    GroupLine.AppendItems ag
    GroupLine.Update
.......

thế là OK

 

[N2NTrung]

Cám ơn bạn nvson nhiều, bạn chỉ cho mình đường dẫn tới các VD ở helf với

 

[N2NTrung]

Cám ơn tigertiger nhé. Ý... mà mình xuất được Text từ Acad sang Excel rùi đấy

 

[tigertiger]

Cám ơn tigertiger nhé. Ý... mà mình xuất được Text từ Acad sang Excel rùi đấy

Uh, cứ từ từ sẽ còn nhiều điều hay, trong VBA -CAD, và -Excel lắm
chúc thành công

Cám ơn bạn nvson nhiều, bạn chỉ cho mình đường dẫn tới các VD ở helf với

Bạn viết thế này là spam bài đó - muốn cám ơn nvson bạn hãy bấm váo nút thanks

 

[nvson]

Cám ơn bạn nvson nhiều, bạn chỉ cho mình đường dẫn tới các VD ở helf với

Từ màn hình AutoCAD, nhấn F1 để vào Help.
Tiếp tục nhấn ActiveX Automation and VBA ở khung bên trái (tab Content).
Nhấn ActiveX and VBA Reference ở khung bên phải (nhấn Yes - nếu cần).
Nhấn tiếp vào Code Examples (khung bên phải).
Để xem danh mục các đoạn ví dụ, bạn nhấn đúp vào mục Code Examples ở khung bên trái nhé!
(Mình sử dụng AutoCAD 2008)