Công thức tính ngày phép năm (5 người xem)

[ngatran08]

Cần chi tiết hơn nhé bạn:
* Một năm được 12 ngày phép đúng không?
* Dưới 1 năm có được phép không? Cách tính thế nào?
* Mốc thời gian đủ năm được tính như thế nào? VD: ngày vào 24/6/2017, ngày nghỉ 20/6/2018, có được phép không?
v.v...

Dạ, em có để thời gian bắt đầu vào làm việc. kết thúc thời gian thử việc là 2 tháng được tính
- Mốc thời gian từ ngày 24/6/2017 - kết thúc thử việc là 23/8/2017 kết thúc thử việc. Tính phép từ ngày 23/8/17-20/6/2018 sẽ được 10 ngày phép.
Em vừa mò đặt được phép đối với nhân viên làm 1 năm em nghĩ đã tạm thời ok, nhưng nhân viên trên 1 năm nó đang tính sai.
Anh xem file giúp em nhé.

 

[ngatran08]

Có thử 1 công thức nhưng không biết đúng không, vì tôi hơi kém về làm thời gian, lần sau bạn nên cho ra 1 ô kết quả sẵn để người làm tra theo xem có lệch chỗ nào không?

=IFERROR(DATEDIF(IF(G5<>"",G5,F5),IF(H5<>"",H5,TODAY()),"m")+INT(DATEDIF(IF(G5<>"",G5,F5),IF(H5<>"",H5,TODAY()),"m")/5),0)

Em đã điền tay số ngày phép, anh đặt công thức giúp em ạ

 

[bebo021999]

Dạ, em có để thời gian bắt đầu vào làm việc. kết thúc thời gian thử việc là 2 tháng được tính
- Mốc thời gian từ ngày 24/6/2017 - kết thúc thử việc là 23/8/2017 kết thúc thử việc. Tính phép từ ngày 23/8/17-20/6/2018 sẽ được 10 ngày phép.
Em vừa mò đặt được phép đối với nhân viên làm 1 năm em nghĩ đã tạm thời ok, nhưng nhân viên trên 1 năm nó đang tính sai.
Anh xem file giúp em nhé.

Thấy bạn chịu khó "mò" nên mình cũng có "hứng" hướng dẫn bạn chi tiết luôn.
* Vì cột TG chính thức có thể bằng TG làm việc+60 hay để trống, nên mình dùng TGLV+60 làm mốc luôn.
=F5+60
* TG nghỉ việc: Nếu trống thì cho bằng hôm nay
=IF(H5="",TODAY(),H5)
P/s: Nếu dùng hàm NOW sẽ có số lẻ của giờ và phút
1* Số tháng làm việc (thiếu 1 ngày coi như chưa đủ tháng)
=DATEDIF(F5+60,IF(H5="",TODAY(),H5),"m")
P/s: Cũng là số ngày phép theo quy định 1 tháng = 1 ngày phép.
2* Số ngày lẻ trên 15 ngày
=DATEDIF(F5+60,IF(H5="",TODAY(),H5),"md")>15
Trả về TRUE (=1), FALSE (=0)
3* Số ngày phép cộng thêm mỗi 5 năm:
=INT(DATEDIF(F5+60,IF(H5="",TODAY(),H5),"y")/5)
Cộng 3 cái này lại:
=DATEDIF(F5+60,IF(H5="",TODAY(),H5),"m")+(DATEDIF(F5+60,IF(H5="",TODAY(),H5),"md")>15)+INT(DATEDIF(F5+60,IF(H5="",TODAY(),H5),"y")/5)
Lồng IFERROR để loại những ngày chưa đủ tháng:

=IFERROR(DATEDIF(F5+60,IF(H5="",TODAY(),H5),"m")+(DATEDIF(F5+60,IF(H5="",TODAY(),H5),"md")>15)+INT(DATEDIF(F5+60,IF(H5="",TODAY(),H5),"y")/5),0)

 

[dazkangel]

Em đã điền tay số ngày phép, anh đặt công thức giúp em ạ

Thời gian thử việc bên bạn là đúng 60 ngày hay chỉ tính tròn 2 tháng ?
Nếu tính 60 ngày thì cột đầu tiên 30/4 đến hôm nay mới 23/06 thì sao được 2 ngày phép ?

 

[ngatran08]

Thấy bạn chịu khó "mò" nên mình cũng có "hứng" hướng dẫn bạn chi tiết luôn.
* Vì cột TG chính thức có thể bằng TG làm việc+60 hay để trống, nên mình dùng TGLV+60 làm mốc luôn.
=F5+60
* TG nghỉ việc: Nếu trống thì cho bằng hôm nay
=IF(H5="",TODAY(),H5)
P/s: Nếu dùng hàm NOW sẽ có số lẻ của giờ và phút
1* Số tháng làm việc (thiếu 1 ngày coi như chưa đủ tháng)
=DATEDIF(F5+60,IF(H5="",TODAY(),H5),"m")
P/s: Cũng là số ngày phép theo quy định 1 tháng = 1 ngày phép.
2* Số ngày lẻ trên 15 ngày
=DATEDIF(F5+60,IF(H5="",TODAY(),H5),"md")>15
Trả về TRUE (=1), FALSE (=0)
3* Số ngày phép cộng thêm mỗi 5 năm:
=INT(DATEDIF(F5+60,IF(H5="",TODAY(),H5),"y")/5)
Cộng 3 cái này lại:
=DATEDIF(F5+60,IF(H5="",TODAY(),H5),"m")+(DATEDIF(F5+60,IF(H5="",TODAY(),H5),"md")>15)+INT(DATEDIF(F5+60,IF(H5="",TODAY(),H5),"y")/5)
Lồng IFERROR để loại những ngày chưa đủ tháng:

=IFERROR(DATEDIF(F5+60,IF(H5="",TODAY(),H5),"m")+(DATEDIF(F5+60,IF(H5="",TODAY(),H5),"md")>15)+INT(DATEDIF(F5+60,IF(H5="",TODAY(),H5),"y")/5),0)

Em vừa copy công thức của anh vào nó gần được rồi, anh xem giúp em các nhân viên làm việc từ 5 năm trở lên họ chạy chưa đúng
Ví dụ Mã NV049 - họ sẽ được 14 ngày phép mà nó chạy ra nhiều hơn anh ạ

Bài đã được tự động gộp: 23/6/18

Thời gian thử việc bên bạn là đúng 60 ngày hay chỉ tính tròn 2 tháng ?
Nếu tính 60 ngày thì cột đầu tiên 30/4 đến hôm nay mới 23/06 thì sao được 2 ngày phép ?

Anh ơi! Cứ làm việc đến hết ngày 15 hàng tháng thì anh làm tròn cho em thành 2 ngày luôn nhé.

 

[dazkangel]

Em vừa copy công thức của anh vào nó gần được rồi, anh xem giúp em các nhân viên làm việc từ 5 năm trở lên họ chạy chưa đúng
Ví dụ Mã NV049 - họ sẽ được 14 ngày phép mà nó chạy ra nhiều hơn anh ạ

Bài đã được tự động gộp: 23/6/18

Anh ơi! Cứ làm việc đến hết ngày 15 hàng tháng thì anh làm tròn cho em thành 2 ngày luôn nhé.

Công thức tương tự anh bebo ngắn hơn tí
Những người làm trên 5 năm 10 năm phép nhiều là phải trừ khi có giới hạn cho từng năm hay tối đa ?

=IFERROR(SUMPRODUCT(INT(DATEDIF(F5+60,MIN(TODAY(),H5),{"m","y","md"})/{1,5,16})),0)

 

[Mr. Duck]

Bạn thử xem cái này có đúng không. Nếu thời gian tính từ ngày bắt đầu làm việc thì sửa cột G thành cột F.

 

[hdcftu]

=IF(TODAY()-C2>=1826,12+ROUNDDOWN((TODAY()-C2)/1826,0),IF(TODAY()-C2>=365,12,ROUNDDOWN((TODAY()-C2)*12/365,0)))
Có đúng với yêu cầu của bạn không.