Giúp em CT tìm chuỗi số tiến và AABBAA trong dãy số (1 người xem)

[ThuyTrang79]

Em chào anh chị !
Em có gởi file vd đính kèm, trong file có 2 vd,
Ở vd 1 nhờ anh chị giúp em CT tìm trong dãy số có chuỗi số tiến, nếu kết quả ở vị trí nào thì báo ở vị trí đó
Ở vd 2 trong file nhờ anh chị giúp em CT tìm trong dãy số có chuỗi AABBAA, nếu kết quả ở vị trí nào thì báo ở vị trí đó
Em cảm ởn anh chị nhiều ạ !

 

[excel_lv1.5]

Em chào anh chị !
Em có gởi file vd đính kèm, trong file có 2 vd,
Ở vd 1 nhờ anh chị giúp em CT tìm trong dãy số có chuỗi số tiến, nếu kết quả ở vị trí nào thì báo ở vị trí đó
Ở vd 2 trong file nhờ anh chị giúp em CT tìm trong dãy số có chuỗi AABBAA, nếu kết quả ở vị trí nào thì báo ở vị trí đó
Em cảm ởn anh chị nhiều ạ !

Bạn dùng các công thức sau:

B2=MIN(IFERROR(FIND(TEXT(MMULT(IFERROR(--(MID("0"&A2,ROW($1:$100),2)+{-1,0,1}),),10^{4;2;0}),"000000"),"0"&A2),""))
B18=MIN(IFERROR(FIND(TEXT(REPT(ROW($1:$10)-1,4),"00"&TRANSPOSE(REPT("\"&ROW($1:$10)-1,2)&"00")),A18),""))

Các công thức có thể cần bấm Ctrl+Shift+Enter!

 

[ThuyTrang79]

Bạn dùng các công thức sau:

B2=MIN(IFERROR(FIND(TEXT(MMULT(IFERROR(--(MID("0"&A2,ROW($1:$100),2)+{-1,0,1}),),10^{4;2;0}),"000000"),"0"&A2),""))
B18=MIN(IFERROR(FIND(TEXT(REPT(ROW($1:$10)-1,4),"00"&TRANSPOSE(REPT("\"&ROW($1:$10)-1,2)&"00")),A18),""))

Các công thức có thể cần bấm Ctrl+Shift+Enter!

Dạ CT chạy ra kết quả ok ạ, em muốn CT chạy ko cần Ctrl+Shift+Enter ạ, nếu có thể cho viết hộ em CT đơn giản dễ hiểu hơn ạ, em cảm ơn anh nhiều ạ !

 

[huuthang_bd]

Chắc cũng không dễ hiểu hơn

=MIN(IFERROR(FIND(TEXT(MID(0&A2,ROW($1:$9),2)*10101+102,"000000"),"0"&A2),""))

=MIN(IFERROR(FIND(REPLACE(REPT(MID(A18,ROW($1:$7),1),4),3,,REPT(MID(A18,ROW($3:$9),1),2)),A18),""))

 

[n0thing1988]

Em không hiểu bài này
Tại sao mà B5,B6 lại là vị trí số 3
Và tại sao ô B4, B11 lại là vị trí số 2 ạ?

 

[huuthang_bd]

B4, B5, B6 sao bạn?

 

[VetMini]

Bài toán này dùng để làm gì vậy?
Có liên quan gì đến Ông Huyện không?

 

[excel_lv1.5]

Chắc cũng không dễ hiểu hơn

=MIN(IFERROR(FIND(TEXT(MID(0&A2,ROW($1:$9),2)*10101+102,"000000"),"0"&A2),""))

=MIN(IFERROR(FIND(REPLACE(REPT(MID(A18,ROW($1:$7),1),4),3,,REPT(MID(A18,ROW($3:$9),1),2)),A18),""))

Khó hiểu hớn đấy bác ạ

 

[huuthang_bd]

Em không hiểu bài này
Tại sao mà B5,B6 lại là vị trí số 3
Và tại sao ô B4, B11 lại là vị trí số 2 ạ?

Mặc định thêm số 0 ở đầu mỗi số.

 

[befaint]

Bài toán này dùng để làm gì vậy?
Có liên quan gì đến Ông Huyện không?

Anh không nhớ rồi. Bạn chủ thớt chuyên về sim số điện thoại. Một 'số đẹp' no bụng vài năm.

------
Các công thức ở đây chỉ là phần nhỏ xíu, phần còn lại là code chạy công thức đó để ra số đẹp... nên cần công thức 'dễ hiểu', không được CSE vì vài ngàn dòng.

 

[ThuyTrang79]

Anh không nhớ rồi. Bạn chủ thớt chuyên về sim số điện thoại. Một 'số đẹp' no bụng vài năm.

------
Các công thức ở đây chỉ là phần nhỏ xíu, phần còn lại là code chạy công thức đó để ra số đẹp... nên cần công thức 'dễ hiểu', không được CSE vì vài ngàn dòng.

Dạ em làm cho nhà mạng, xếp giao việc phải làm, rồi đi bán từng cái sim để kiếm chỉ tiêu để có lương, anh có chiêu gì "bán 1 sim no bụng cả năm", về lấy nguồn hàng giá rẻ và cách bán cho khách hàng giá cực cao để có thể no bụng 1 tháng thôi ạ, nhờ anh inbox chỉ giúp em làm với ạ. cảm ơn anh rất nhiều !

Bài đã được tự động gộp: 19/8/20

Chắc cũng không dễ hiểu hơn

=MIN(IFERROR(FIND(TEXT(MID(0&A2,ROW($1:$9),2)*10101+102,"000000"),"0"&A2),""))

=MIN(IFERROR(FIND(REPLACE(REPT(MID(A18,ROW($1:$7),1),4),3,,REPT(MID(A18,ROW($3:$9),1),2)),A18),""))

Dạ CT chạy chưa ra hết kết quả nhờ anh giúp em thêm CT với ạ, cảm ơn anh !

 

[huuthang_bd]

Dạ CT chạy chưa ra hết kết quả nhờ anh giúp em thêm CT với ạ, cảm ơn anh !

Quên lưu ý bạn các công thức đó cũng là công thức mảng.

không được CSE vì vài ngàn dòng.

Đâu phải công thức mảng nào cũng "nặng".

 

[Phuocam]

Thử thay MIN() bằng AGGREGATE(15,6,....,1) để chỉ Enter.

 

[VetMini]

... không được CSE vì vài ngàn dòng.

CSE chỉ là để ép không cho mảng thâu về thành 1 giá trị thôi. Công thức nào cần phải duyệt hết cái mảng trong đó đều là "công thức mảng" tuốt.

 

[quick87]

Thử thay MIN() bằng AGGREGATE(15,6,....,1) để chỉ Enter.

Hình như là chỉ với Office 2019 trở lên mới dùng phím Enter thôi, phiên bản thấp hơn vẫn phải sử dụng 3 phím Ctrl Shift Enter thì phải thôi anh @phuocam

 

[huuthang_bd]

Hoa hết cả mắt các bác ạ.

=IFS(MID(A2,1,5)-MID(A2,1,1)*10101=102,1,MID(A2,1,6)-MID(A2,1,2)*10101=102,2,MID(A2,2,6)-MID(A2,2,2)*10101=102,3,MID(A2,3,6)-MID(A2,3,2)*10101=102,4,MID(A2,4,6)-MID(0&A2,4,2)*10101=102,5,1,0)

=IFS(MID(A18,1,1)*110011+MID(A18,3,1)*1100-MID(A18,1,6)=0,1,MID(A18,2,1)*110011+MID(A18,4,1)*1100-MID(A18,2,6)=0,2,MID(A18,3,1)*110011+MID(A18,5,1)*1100-MID(A18,3,6)=0,3,MID(A18,4,1)*110011+MID(A18,6,1)*1100-MID(A18,4,6)=0,4,1,0)

 

[ThuyTrang79]

View attachment 243498
Hoa hết cả mắt các bác ạ.

=IFS(MID(A2,1,5)-MID(A2,1,1)*10101=102,1,MID(A2,1,6)-MID(A2,1,2)*10101=102,2,MID(A2,2,6)-MID(A2,2,2)*10101=102,3,MID(A2,3,6)-MID(A2,3,2)*10101=102,4,MID(A2,4,6)-MID(0&A2,4,2)*10101=102,5,1,0)

=IFS(MID(A18,1,1)*110011+MID(A18,3,1)*1100-MID(A18,1,6)=0,1,MID(A18,2,1)*110011+MID(A18,4,1)*1100-MID(A18,2,6)=0,2,MID(A18,3,1)*110011+MID(A18,5,1)*1100-MID(A18,3,6)=0,3,MID(A18,4,1)*110011+MID(A18,6,1)*1100-MID(A18,4,6)=0,4,1,0)

Dạ em chạy thử chưa ra kết quả ạ đúng ạ .

 

[huuthang_bd]

Sai chỗ nào thì bạn đưa file lên chứ cứ chưa đúng chưa đúng ai biết đâu mà đỡ.

 

[Phuocam]

Số 0384.98.99.00 có được gọi là tiến lên không?

 

[ThuyTrang79]

Số 0384.98.99.00 có được gọi là tiến lên không?

Dạ ko anh, nếu tiến lên từ 00.01.02 tối đa là 979899 ạ

Sai chỗ nào thì bạn đưa file lên chứ cứ chưa đúng chưa đúng ai biết đâu mà đỡ.

Em chạy thử thấy nó cứ báo lỗi #NAME? ạ

 

[huuthang_bd]

Tôi chả hiểu sao bạn có thể phản hồi "chưa ra kết quả đúng" trong khi công thức trả về lỗi #Name.
Nguyên nhân: Bạn sử dụng Excel phiên bản cũ không có hàm IFS.
Khắc phục: Chuyển sang dùng các hàm IF lồng nhau.
Tạm biệt.

 

[ThuyTrang79]

Tôi chả hiểu sao bạn có thể phản hồi "chưa ra kết quả đúng" trong khi công thức trả về lỗi #Name.
Nguyên nhân: Bạn sử dụng Excel phiên bản cũ không có hàm IFS.
Khắc phục: Chuyển sang dùng các hàm IF lồng nhau.
Tạm biệt.

=IF(MID(A2,1,5)-MID(A2,1,1)*10101=102,1),IF(MID(A2,1,6)-MID(A2,1,2)*10101=102,2),IF(MID(A2,2,6)-MID(A2,2,2)*10101=102,3),IF(MID(A2,3,6)-MID(A2,3,2)*10101=102,4),IF(MID(A2,4,6)-MID(0&A2,4,2)*10101=102,5)
Dạ em lồng như thế này sai gì chạy không ra kết quả ạ, nhờ anh lồng hộ em với ạ, em cảm ơn anh !

 

[n0thing1988]

=IF(MID(A2,1,5)-MID(A2,1,1)*10101=102,1),IF(MID(A2,1,6)-MID(A2,1,2)*10101=102,2),IF(MID(A2,2,6)-MID(A2,2,2)*10101=102,3),IF(MID(A2,3,6)-MID(A2,3,2)*10101=102,4),IF(MID(A2,4,6)-MID(0&A2,4,2)*10101=102,5)
Dạ em lồng như thế này sai gì chạy không ra kết quả ạ, nhờ anh lồng hộ em với ạ, em cảm ơn anh !

Sao bạn lại viết hàm IF như thế này?

 

[Quang_Hải]

Em chào anh chị !
Em có gởi file vd đính kèm, trong file có 2 vd,
Ở vd 1 nhờ anh chị giúp em CT tìm trong dãy số có chuỗi số tiến, nếu kết quả ở vị trí nào thì báo ở vị trí đó
Ở vd 2 trong file nhờ anh chị giúp em CT tìm trong dãy số có chuỗi AABBAA, nếu kết quả ở vị trí nào thì báo ở vị trí đó
Em cảm ởn anh chị nhiều ạ !

Bài này nếu dùng VBA thì dễ mà sao không dùng hàm tự tạo cho khỏe.
Nếu dùng Sub thì có thể tô màu cho vị trí chuỗi số tiến

Đại loại như hình đính kèm. Có điều kết quả phần số gánh không khớp với kết quả của bạn

 

[ThuyTrang79]

Sao bạn lại viết hàm IF như thế này?

Dạ em sửa CT lại chạy OK rồi ạ, em cảm ơn anh @n0thing1988 @huuthang_bd ạ.

Bài này nếu dùng VBA thì dễ mà sao không dùng hàm tự tạo cho khỏe.
Nếu dùng Sub thì có thể tô màu cho vị trí chuỗi số tiến

Đại loại như hình đính kèm. Có điều kết quả phần số gánh không khớp với kết quả của bạn

View attachment 243595

Tại em ko rành về VBA nên muốn muốn dùng CT hơn ạ, em cảm ơn anh !