Nhờ anh chị giúp tính tổng có điều kiện (1 người xem)

[chickenexcel]

Em nhờ các bác giúp đặt công thức tính tổng tiền của từng khách hàng
Em gửi file các bác xem giúp
Em có nghĩ đến hàm istext để xác định tên khách hàng (cột A) làm căn cứ nhưng chưa biết cách nào để ngắt từng đơn khách hàng để tính tổng mỗi đơn tự động cả, nhờ các bác tư vấn giúp ạ!
Thank cả nhà!

 

[dazkangel]

Em nhờ các bác giúp đặt công thức tính tổng tiền của từng khách hàng
Em gửi file các bác xem giúp
Em có nghĩ đến hàm istext để xác định tên khách hàng (cột A) làm căn cứ nhưng chưa biết cách nào để ngắt từng đơn khách hàng để tính tổng mỗi đơn tự động cả, nhờ các bác tư vấn giúp ạ!
Thank cả nhà!

bạn nên tạo 1 cột phụ để dò

 

[HieuCD]

Em nhờ các bác giúp đặt công thức tính tổng tiền của từng khách hàng
Em gửi file các bác xem giúp
Em có nghĩ đến hàm istext để xác định tên khách hàng (cột A) làm căn cứ nhưng chưa biết cách nào để ngắt từng đơn khách hàng để tính tổng mỗi đơn tự động cả, nhờ các bác tư vấn giúp ạ!
Thank cả nhà!

B2 =IF(A2="","",SUM(OFFSET(F2,,,INDEX(MATCH(TRUE,(C2:$C$16=""),0),)-1)))

copy xuống

 

[dazkangel]

B2 =IF(A2="","",SUM(OFFSET(F2,,,INDEX(MATCH(TRUE,(C2:$C$16=""),0),)-1)))

copy xuống

lại nhanh hơn kaka, em suy nghĩ cả tiếng mới ra

 

[concogia]

Công thức này hay nhưng ...hơi nguy hiểm, [C16] nằm ngoài bảng, nếu lỡ có dữ liệu thì ...
Bài dạng này thầy Ndu có viết công thức rất hay và ngắn
Thân

 

[dazkangel]

Công thức này hay nhưng ...hơi nguy hiểm, [C16] nằm ngoài bảng, nếu lỡ có dữ liệu thì ...
Bài dạng này thầy Ndu có viết công thức rất hay và ngắn
Thân

híc em ngồi mò cả tiếng, anh gửi em bài đó để tham khảo được không ạ.

 

[concogia]

híc em ngồi mò cả tiếng, anh gửi em bài đó để tham khảo được không ạ.

Hình như thế này:

=IF(A2="","",SUM(F2:$F$15)-SUM(B3:$B$15))

Thân

 

[dazkangel]

Hình như thế này:

Thân

cảm ơn ạ, để em mở máy xem thử ^^

 

[dazkangel]

Hình như thế này:

Thân

Hi cách của anh nếu ở dưới không có dữ liệu thì

 

[dazkangel]

B2 =IF(A2="","",SUM(OFFSET(F2,,,INDEX(MATCH(TRUE,(C2:$C$16=""),0),)-1)))

copy xuống

anh ơi sao công thức của em khúc dưới bị lỗi ạ
=IF(B2="","",SUM(INDIRECT("F"&ROW()&":F"&ROW()-1+MATCH(0,F2:$F$16,0))))

 

[HieuCD]

anh ơi sao công thức của em khúc dưới bị lỗi ạ
=IF(B2="","",SUM(INDIRECT("F"&ROW()&":F"&ROW()-1+MATCH(0,F2:$F$16,0))))

vì F16 là rổng không phải là số 0, Match trả về lỗi

 

[concogia]

Hi cách của anh nếu ở dưới không có dữ liệu thì

Hihi, mình nói công thức này của thầy Ndu, không phải của mình, khi viết thầy ấy cũng cảnh báo khi nhập xong dữ liệu rồi thì kéo công thức (cái này mình "wên", "xó- dì" bạn). HÍc
Thân

 

[dazkangel]

vì F16 là rổng không phải là số 0, Match trả về lỗi

dạ em cũng vừa tìm ra, em thắc mắc khi dùng giống anh thì nó lỗi toàn bộ, còn nhấn f9 thì được
=IF(B2="","",SUM(INDIRECT("F"&ROW()&":F"&ROW()-1+MATCH(1,($C$2:$C$16=""),0))))

 

[dazkangel]

Hihi, mình nói công thức này của thầy Ndu, không phải của mình, khi viết thầy ấy cũng cảnh báo khi nhập xong dữ liệu rồi thì kéo công thức (cái này mình "wên", "xó- dì" bạn). HÍc
Thân

dạ cách này nhanh gọn nếu có dữ liệu thì được ạ, mọi cách đều giúp đầu óc nhạy hơn ^^

 

[dazkangel]

vì F16 là rổng không phải là số 0, Match trả về lỗi

a em tìm ra rồi haizz đầu óc không linh hoạt gì cả

 

[HieuCD]

dạ em cũng vừa tìm ra, em thắc mắc khi dùng giống anh thì nó lỗi toàn bộ, còn nhấn f9 thì được
=IF(B2="","",SUM(INDIRECT("F"&ROW()&":F"&ROW()-1+MATCH(1,($C$2:$C$16=""),0))))

($C$2:$C$16="") là biểu thức luận lý trả về true và false, nên Match(1,....) sẽ bị lỗi, cần phải qui về cùng 1 dạng là true hết hay là số 1, hàm Match cho mảng nên phải Ctrl+Shif+Enter, hoặc dùng thêm hàm Index

 

[dazkangel]

($C$2:$C$16="") là biểu thức luận lý trả về true và false, nên Match(1,....) sẽ bị lỗi, cần phải qui về cùng 1 dạng là true hết hay là số 1, hàm Match cho mảng nên phải Ctrl+Shif+Enter, hoặc dùng thêm hàm Index

hi vậy mới nói đầu óc chưa linh hoạt ^^

 

[HieuCD]

hi vậy mới nói đầu óc chưa linh hoạt ^^

làm nhiều dần dần sẽ quen và sẽ thấy nhiều vấn đề thú vị

 

[dazkangel]

làm nhiều dần dần sẽ quen và sẽ thấy nhiều vấn đề thú vị

chắc cần thời gian em hơi hấp tấp nhưng cũng tăng cường tự giải

 

[bebo021999]

Hình như thế này:

Thân

Loại này thường người ta hay copy ngược từ dưới lên:
Ô B13:

=IF(A13="","",SUM(F13:$F$15)-SUM(B14:$B$15))

Ngoài ra, một công thức khác không dùng OFFSET mà dùng INDEX(CELL1:INDEX(...) để tham chiếu vùng động:

=IF(A2="","",SUM(INDEX(F2:INDEX(F2:$F$15,MATCH(TRUE,INDEX(C2:$C$15="",),0)-1,),)))

 

[HieuCD]

Loại này thường người ta hay copy ngược từ dưới lên:
Ô B13:

=IF(A13="","",SUM(F13:$F$15)-SUM(B14:$B$15))

Ngoài ra, một công thức khác không dùng OFFSET mà dùng INDEX(CELL1:INDEX(...) để tham chiếu vùng động:

=IF(A2="","",SUM(INDEX(F2:INDEX(F2:$F$15,MATCH(TRUE,INDEX(C2:$C$15="",),0)-1,),)))

tham chiếu vùng động có nhiều cách, dùng INDEX(CELL1:INDEX(...)) thì hàm INDEX bên trái không cần thiết, chỉ cần (CELL1:CELL2) là đủ, CELL1 và CELL2 tùy trường hợp có thể dùng hàng loạt hàm khác nhau để tùy biến vùng tham chiếu

 

[chickenexcel]

Em xin cảm ơn cả nhà đã nhiệt tình giúp đỡ, mỗi bác lại có 1 công thức # nhau, mỗi cái đều có ưu và nhược riêng, có một số hàm như Offset hay index em chưa học được nên sẽ ngâm cứu từng công thức của mỗi bác, từ đó lựa chọn cho 1 mình công thức phù hợp với công việc.
Chúc các bác ngày mới vui vẻ cùng GPE ạ!

 

[chickenexcel]

Được thể "có voi đòi tiên" cho em hỏi VD với công thức của anh HieuCD ở #3, nếu như em nhập dữ liệu liền, có nghĩa là không có dòng trống giữa các đơn hàng (dòng 6, dòng 12) thì có cách nào tính được không ạ

 

[quocgiacan]

Được thể "có voi đòi tiên" cho em hỏi VD với công thức của anh HieuCD ở #3, nếu như em nhập dữ liệu liền, có nghĩa là không có dòng trống giữa các đơn hàng (dòng 6, dòng 12) thì có cách nào tính được không ạ

Cái này là có "voi đòi Hai Bà Trưng" nè!

Nghỉ ngơi ăn trưa rồi tiếp.

 

[dazkangel]

Được thể "có voi đòi tiên" cho em hỏi VD với công thức của anh HieuCD ở #3, nếu như em nhập dữ liệu liền, có nghĩa là không có dòng trống giữa các đơn hàng (dòng 6, dòng 12) thì có cách nào tính được không ạ

có lẽ là được, mình nghĩ tới istext khà khà

 

[dazkangel]

tham chiếu vùng động có nhiều cách, dùng INDEX(CELL1:INDEX(...)) thì hàm INDEX bên trái không cần thiết, chỉ cần (CELL1:CELL2) là đủ, CELL1 và CELL2 tùy trường hợp có thể dùng hàng loạt hàm khác nhau để tùy biến vùng tham chiếu

anh rảnh chỉ em hàm index rồi cell tác dụng thế nào ạ

 

[quocgiacan]

Được thể "có voi đòi tiên" cho em hỏi VD với công thức của anh HieuCD ở #3, nếu như em nhập dữ liệu liền, có nghĩa là không có dòng trống giữa các đơn hàng (dòng 6, dòng 12) thì có cách nào tính được không ạ

Vậy thì chơi vầy:

B2=IF(A2="","",SUMPRODUCT((COUNTIF(OFFSET($A$2,,,ROW($1:$14)),"<>")=COUNTIF($A$2:A2,"<>"))*$F$2:$F$15))

Enter fill xuống.

Hoặc không thì theo đúng bài của bạn hiền HieuCD, thay đổi chút:

B2=IF(A2="","",SUM(OFFSET(F2,,,IFERROR(MATCH(TRUE,INDEX(A3:$A$16<>"",),),LOOKUP(2,1/(C3:$C$16=""),ROW(2:$15)-ROW()+1)))))

Enter fill xuống.

Chúc anh em ngày vui.

 

[chickenexcel]

thực sự hàm bác ảo diệu thật, em xem mà ... chẳng hiều gì , file test em up lên thì ok nhưng file em làm áp dụng vào bị lỗi value , nhờ bác xem giúp em sai chỗ nào với ạ (cột F)

 

[quocgiacan]

thực sự hàm bác ảo diệu thật, em xem mà ... chẳng hiều gì , file test em up lên thì ok nhưng file em làm áp dụng vào bị lỗi value , nhờ bác xem giúp em sai chỗ nào với ạ (cột F)

Bạn chỉnh công thức cột N: N8=IFERROR((K8*M8),0) Fill xuống

F8=IF(E8="","",SUMPRODUCT((COUNTIF(OFFSET($E$8,,,ROW($1:$792)),"<>")=COUNTIF($E$8:E8,"<>"))*$N$8:$N$799)) Enter fill xuống

(Phải có sự tương xứng số dòng: 8:799 = 1:792)

Chúc bạn ngày vui.

 

[chickenexcel]

Quá hay ạ!

 

[quocgiacan]

Quá hay ạ!

Tham khảo cho vui với dòng dữ liệu không nhiều quá.

Bạn nên nghiên cứu công thức của anh concogia đưa ra nó thực dụng hơn công thức của tôi.

Hình như thế này: =IF(A2="","",SUM(F2:$F$15)-SUM(B3:$B$15))

Chúc bạn ngày vui.

 

[chickenexcel]

Dạ công thức của anh concogia cũng rất hay nhưng nó chỉ áp dụng khi bảng tính được hoàn thiện thôi ạ,do em phải tạo from cho người không biết gì về Excel (chỉ nhập liệu ) nên phải cân nhắc các công thức để tránh họ làm nhầm lẫn, hỏng số liệu
Một lần nữa chân thành cảm ơn cả nhà!

 

[HieuCD]

Được thể "có voi đòi tiên" cho em hỏi VD với công thức của anh HieuCD ở #3, nếu như em nhập dữ liệu liền, có nghĩa là không có dòng trống giữa các đơn hàng (dòng 6, dòng 12) thì có cách nào tính được không ạ

anh rảnh chỉ em hàm index rồi cell tác dụng thế nào ạ

nếu dùng cấu trúc (cell1,cell2)

F8 =IF(E8="","",SUM((N8:INDEX(N8:$N$796,IFERROR(MATCH("*",E9:$E$796,0),ROWS(E9:$E$796)),))))

trong đó cell1 là N8, còn cell2 là index(...) dĩ nhiên thay index bằng offset cũng được

nếu dùng Offset thì gọn hơn

F8=IF(E8="","",SUM(OFFSET(N8,,,IFERROR(MATCH("*",E9:$E$796,0),ROWS(E9:$E$796)),)))

 

[dazkangel]

nếu dùng cấu trúc (cell1,cell2)

F8 =IF(E8="","",SUM((N8:INDEX(N8:$N$796,IFERROR(MATCH("*",E9:$E$796,0),ROWS(E9:$E$796)),))))

trong đó cell1 là N8, còn cell2 là index(...) dĩ nhiên thay index bằng offset cũng được

nếu dùng Offset thì gọn hơn

F8=IF(E8="","",SUM(OFFSET(N8,,,IFERROR(MATCH("*",E9:$E$796,0),ROWS(E9:$E$796)),)))

em đang làm cái validation tí mò cái này