Công thức tổng có điều kiện (1 người xem)

[hatnguyenap]

em chào cả nhà, em muốn cộng thời gian đi muộn của bảng chấm công tương ứng với các ký hiệu trên bảng chấm công:
VD: M1= đi muộn 1 tiếng, M2= đi muộn 2tiếng, M3= đi muộn 3 tiếng...
có ai biết giúp em với , dạng công thức trả về đuôi của nó rồi cộng tổng(file đính kèm)

 

[thanhsangnguyen1982]

Cong thuc BM4=SUM(IF($F$4:$BK$4="M1",1,0))+SUM(IF($F$4:$BK$4="M2",2,0))+SUM(IF($F$4:$BK$4="M3",3,0))
Vi la cong thuc mang nen ket thuc cong thuc nhan Ctrl Shift Enter

 

[Xuân hiếu]

Tại BM4 =COUNTIF(F4:BK4,"m1")+2*COUNTIF(F4:BK4,"m2")+3*COUNTIF(F4:BK4,"m3") thử xem có thỏa được điều kiện đưa ra không.
Bạn có thể xem file đính kèm

em chào cả nhà, em muốn cộng thời gian đi muộn của bảng chấm công tương ứng với các ký hiệu trên bảng chấm công:
VD: M1= đi muộn 1 tiếng, M2= đi muộn 2tiếng, M3= đi muộn 3 tiếng...
có ai biết giúp em với , dạng công thức trả về đuôi của nó rồi cộng tổng(file đính kèm)

 

[concogia]

em chào cả nhà, em muốn cộng thời gian đi muộn của bảng chấm công tương ứng với các ký hiệu trên bảng chấm công:
VD: M1= đi muộn 1 tiếng, M2= đi muộn 2tiếng, M3= đi muộn 3 tiếng...
có ai biết giúp em với , dạng công thức trả về đuôi của nó rồi cộng tổng(file đính kèm)

Thêm một công thức cho bạn
Có khi nào M lên đến M4, M5 hoặc M6 không nhỉ ???

=SUM(IF(LEFT(F4:BK4)="M",--RIGHT(F4:BK4),""))

Kết thúc bằng Ctrl + Shift + Enter
Híc

 

[ndu96081631]

Tại BM4 =COUNTIF(F4:BK4,"m1")+2*COUNTIF(F4:BK4,"m2")+3*COUNTIF(F4:BK4,"m3") thử xem có thỏa được điều kiện đưa ra không.
Bạn có thể xem file đính kèm

Công thức này khá hay vì nó đơn giản... Tuy nhiên nó hơi dài
Sửa thành vầy:

=SUMPRODUCT(COUNTIF(F4:BK4,"m"&ROW($1:$[COLOR=#ff0000]8[/COLOR]))*ROW($1:$[COLOR=#ff0000]8[/COLOR]))

Sửa số 8 màu đỏ ở trên thành bi nhiêu tùy ý (nếu như có cái vụ đi trễ > 8 tiếng)
Nhưng giả định có vụ đi trể 1.5 tiếng thì sao ta?
Ẹc... Ẹc...

 

[concogia]

Công thức này khá hay vì nó đơn giản... Tuy nhiên nó hơi dài
Sửa thành vầy:

=SUMPRODUCT(COUNTIF(F4:BK4,"m"&ROW($1:$[COLOR=#ff0000]8[/COLOR]))*ROW($1:$[COLOR=#ff0000]8[/COLOR]))

Sửa số 8 màu đỏ ở trên thành bi nhiêu tùy ý (nếu như có cái vụ đi trễ > 8 tiếng)
Nhưng giả định có vụ đi trể 1.5 tiếng thì sao ta?
Ẹc... Ẹc...

Nếu có trường hợp này cũng có thể xài tạm cái ni, thấy cũng ổn

=SUM(IF(LEFT(F4:BK4)<>"M","",--SUBSTITUTE(F4:BK4,"M","")))

Híc