Xin giúp đỡ về cách tạo mã serial liên tục và có thể tuỳ chỉnh mã đầu tiên. (3 người xem)

[thanhems]

Chào mọi người
Công ty em sản xuất hàng với số lượng trung bình trên 1000 sản phẩm đối với một đơn hàng, mỗi sản phẩm cần dán 1 con tem serial có dạng: AAAAAXNNNNN trong đó A là mã đơn hàng còn X là từ 00000 cho đến 02000 (có thể hơn). Ví dụ cụ thể đơn hàng là V22033 và đặt 2000 cái ghế thì em phải làm tem từ
V22033X00001 cho đến V22033X02000
Em có tham khảo hàm trên GPE thì làm đc rồi, bằng cách sử dụng hàm
F1=mã đơn hàng
A1=$F$1&TEXT(ROW(A1),"00000")

Nhưng em không biết cách làm thế nào để tạo số serial với mã NNNNN bắt đầu bằng số thứ tự tùy thích.
Giả sử em muốn làm số serial từ
V22033X00150 đến V22033X02000 thì làm cách nào ạ
Xin mọi người giúp dùm, em có gửi file đính kèm.
Cám ơn mọi người

 

[viehoai]

Chào mọi người
Công ty em sản xuất hàng với số lượng trung bình trên 1000 sản phẩm đối với một đơn hàng, mỗi sản phẩm cần dán 1 con tem serial có dạng: AAAAAXNNNNN trong đó A là mã đơn hàng còn X là từ 00000 cho đến 02000 (có thể hơn). Ví dụ cụ thể đơn hàng là V22033 và đặt 2000 cái ghế thì em phải làm tem từ
V22033X00001 cho đến V22033X02000
Em có tham khảo hàm trên GPE thì làm đc rồi, bằng cách sử dụng hàm
F1=mã đơn hàng
A1=$F$1&TEXT(ROW(A1),"00000")

Nhưng em không biết cách làm thế nào để tạo số serial với mã NNNNN bắt đầu bằng số thứ tự tùy thích.
Giả sử em muốn làm số serial từ
V22033X00150 đến V22033X02000 thì làm cách nào ạ
Xin mọi người giúp dùm, em có gửi file đính kèm.
Cám ơn mọi người

Theo như ý bạn, giả sử ta nhập tại A1 V23033X20000 thì các giá trị A2, A3... là V23033X20001, V23033X20002... phải không?
Nếu vậy thì công thức A2 là: =LEFT(A1;LEN($A$1)-5)&ROW()+RIGHT($A$1;5)-1

 

[thanhems]

Cám ơn bác viehoai,
Bác có thể chỉnh dùm em công thức bác cho dãy số ra đủ 5 số không bác
Công thức bác em nhập A1=V22033X00150
A2=LEFT(A1,LEN($A$1)-5)&ROW()+RIGHT($A$1,5)-1
Thì A2 nó hiện là V22033X150, mà em muốn là V22033X00150 cơ
--------------
Em có thử cách này:
C1=22033 (ô C1 để nhập mã đơn hàng)
C2=00001 (ô C2 để nhập số thứ tự đầu tiên cần in, có thể là 00150 tùy ý)
A1=$C$2&TEXT($C$3,"00000")
A2=$C$2&TEXT($C$3+1,"00000")
A3=$C$2&TEXT($C$3+2,"00000")
......
nhưng làm vậy phải nhập số +1, +2.... rất vất vả, bác có cách nào nhanh hơn không bác.

Cám ơn bác nhiều, nhờ bác giúp dùm em cái

 

[viehoai]

Cám ơn bác viehoai,
Bác có thể chỉnh dùm em công thức bác cho dãy số ra đủ 5 số không bác
Công thức bác em nhập A1=V22033X00150
A2=LEFT(A1,LEN($A$1)-5)&ROW()+RIGHT($A$1,5)-1
Thì A2 nó hiện là V22033X150, mà em muốn là V22033X00150 cơ
--------------
Em có thử cách này:
C1=22033 (ô C1 để nhập mã đơn hàng)
C2=00001 (ô C2 để nhập số thứ tự đầu tiên cần in, có thể là 00150 tùy ý)
A1=$C$2&TEXT($C$3,"00000")
A2=$C$2&TEXT($C$3+1,"00000")
A3=$C$2&TEXT($C$3+2,"00000")
......
nhưng làm vậy phải nhập số +1, +2.... rất vất vả, bác có cách nào nhanh hơn không bác.

Cám ơn bác nhiều, nhờ bác giúp dùm em cái

Bạn xem file và cho ý kiến thêm nhé

 

[bebo021999]

Bạn thử dùng công thức này xem:

Tại ô A1:

=$F$1&TEXT(150,"00000")

Tại ô A2:

=$F$1&TEXT(150+ROW(A1),"00000")

Kéo ô A2 xuống.

Bạn có thể thay số 150 bằng ô $F$2, và gõ số tùy thích vào ô $F$2

 

[ndu96081631]

Chào mọi người
Công ty em sản xuất hàng với số lượng trung bình trên 1000 sản phẩm đối với một đơn hàng, mỗi sản phẩm cần dán 1 con tem serial có dạng: AAAAAXNNNNN trong đó A là mã đơn hàng còn X là từ 00000 cho đến 02000 (có thể hơn). Ví dụ cụ thể đơn hàng là V22033 và đặt 2000 cái ghế thì em phải làm tem từ
V22033X00001 cho đến V22033X02000
Em có tham khảo hàm trên GPE thì làm đc rồi, bằng cách sử dụng hàm
F1=mã đơn hàng
A1=$F$1&TEXT(ROW(A1),"00000")

Nhưng em không biết cách làm thế nào để tạo số serial với mã NNNNN bắt đầu bằng số thứ tự tùy thích.
Giả sử em muốn làm số serial từ
V22033X00150 đến V22033X02000 thì làm cách nào ạ
Xin mọi người giúp dùm, em có gửi file đính kèm.
Cám ơn mọi người

Tôi thấy cách đơn giản nhất là gõ số đầu rồi kéo fill là được, cần gì công thức

 

[thanhems]

@ bác ndu96081631
Vì file em phải thể hiện khi in ra, 1 trang giấy phải có 2 số serial, nên em đặt số ở cột B sẽ bằng cột A, cột D sẽ bằng cột C. số serial cột A sẽ kết thúc cuối mỗi trang và bắt đầu qua cột C, nên một trang in sẽ như thế này
cột A________ cột B__________ cột C ______cột D
22033x00001| 22033x00001| 22033x00004| 22033x00004
22033x00002| 22033x00002| 22033x00005| 22033x00005
22033x00003| 22033x00002| 22033x00006| 22033x00006
sau đó qua trang 2 lại tiếp tục số seri ở cuối cột C.
số serial phải làm cặp như thế là 1 cái dán lên thùng, 1 cái dán vào sản phẩm, nếu ko làm 2 cột giống nhau như thế thì phải làm 2 tờ, mà làm 2 tờ thì công nhân dễ nhầm lẫn. dán nhầm là em khỏi ăn tết luôn.
Làm serial từng page riêng nhưng cũng phải liên tục số, lại làm trên 2000 con, nên dễ sai và mất thời gian lắm, bác nào giúp em với

 

[thanhems]

Bạn thử dùng công thức này xem:

Tại ô A1:

=$F$1&TEXT(150,"00000")

Tại ô A2:

=$F$1&TEXT(150+ROW(A1),"00000")

Kéo ô A2 xuống.

Bạn có thể thay số 150 bằng ô $F$2, và gõ số tùy thích vào ô $F$2

Oh cám ơn bebo nhiều lắm, ngon cơm rồi

 

[vodoi2x]

Cách khác tạo thành 4 cột như yêu cầu

Oh cám ơn bebo nhiều lắm, ngon cơm rồi

Oh, ngon gì nhỉ, thế bạn không làm 4 cột nữa ah,


nếu chỉ một cột như thế thì có thể công thức tại A1 như sau cho nhanh

=$F$1&TEXT(150+ROW($1:1)-1,"00000")

Hoặc tại F2 nhập 150 thì

=$F$1&TEXT($F$2+ROW($1:1)-1,"00000")

rồi copy xuống cho các A khác


TUY VẬY, cách khác tạo thành 4 cột như bạn mong muốn,

Vì các dòng cao bằng nhau--> số dòng trên trang bằng nhau, nên có thể số hàng nhập cố định số dòng này tại F2 như bebo đề xuất,

Ví như tại F2 nhập 23

thì tại A1 nhập công thức

=$F$1&TEXT((COLUMNS($A:A)>2)*$F$2+  INT((ROWS($1:1)-1)/$F$2)*2*$F$2+MOD(ROWS($1:1)-1,$F$2)+1,"00000")

Copy cho ô khác B11 rồi copy fill xuống đển bao nhiêu tuỳ thích

Thay đổi giá trị tại F2 cho phù hợp với phân trang , in ra là như mong muốn

 

[thanhems]

Cám ơn bác vodoi2x nhiều lắm.
Cách của bác làm sao nối tiếp được bác, ý em là nối tiếp thế này:
Trang 1:
cột A________ cột B__________ cột C ______cột D
22033x00001| 22033x00001| 22033x00004| 22033x00004
22033x00002| 22033x00002| 22033x00005| 22033x00005
22033x00003| 22033x00002| 22033x00006| 22033x00006
Trang 2:
cột A________ cột B__________ cột C ______cột D
22033x00007| 22033x00007| 22033x00010| 22033x00010
22033x00008| 22033x00008| 22033x00011| 22033x00011
22033x00009| 22033x00009| 22033x00012| 22033x00012
....
chạy cho đến 2000

Công thức bác đưa, nếu em nhập F2 là 2000 thì nó chạy số từ 1 đến 2000 xong nó chạy tiếp từ 4001 đến 60001, hix, mất khoảng giữa kìa bác

 

[bebo021999]

Quên mất chuyện làm 2 cột trên 1 trang.
Làn thế này nhé:
Thay đổi STT khởi đầu : ô F2
Số dòng mỗi trang dự định in: ô F3 (hiện tại là 23 dòng. Tuy nhiên, giả sử sau này bạn in chữ lớn hơn hoặc nhỏ đi thì số seri sẽ nhảy trang. Khi đó bạn sẽ điều chỉnh số dòng in tại ô F3 cho phù hợp với trang in thực tế của bạn).

A1:

=$F$1&TEXT($F$2,"00000")

A2:

=$F$1&TEXT(IF(MOD(RIGHT(A1,5)-$F$2+1,$F$3)=0,RIGHT(C1,5),RIGHT(A1,5))+1,"00000")

Kéo A2 xuống.

C1:

=$F$1&TEXT(RIGHT(A1,5)+$F$3,"00000")

Kéo C1 xuống

 

[huuthang_bd]

Cám ơn bác vodoi2x nhiều lắm.
Cách của bác làm sao nối tiếp được bác, ý em là nối tiếp thế này:
Trang 1:
cột A________ cột B__________ cột C ______cột D
22033x00001| 22033x00001| 22033x00004| 22033x00004
22033x00002| 22033x00002| 22033x00005| 22033x00005
22033x00003| 22033x00002| 22033x00006| 22033x00006
Trang 2:
cột A________ cột B__________ cột C ______cột D
22033x00007| 22033x00007| 22033x00010| 22033x00010
22033x00008| 22033x00008| 22033x00011| 22033x00011
22033x00009| 22033x00009| 22033x00012| 22033x00012
....
chạy cho đến 2000

Công thức bác đưa, nếu em nhập F2 là 2000 thì nó chạy số từ 1 đến 2000 xong nó chạy tiếp từ 4001 đến 60001, hix, mất khoảng giữa kìa bác

Bạn xem file này thử xem.
Công thức tại A1:

=TEXT($F$2+ROW(A1)-1+(INT((ROW(A1)-1)/$F$4)+(COLUMN(A1)>2))*$F$4,"[<="&$F$3&"]"""&$F$1&"""00000;")

Với:
F1: PO#
F2: Số bắt đầu
F3: Số kết thúc
F4: Số dòng trong một trang

 

[thanhems]

Cám ơn bebo nhiều lắm, cám ơn huuthang_bd nhiều,
Bác huuthang có thêm cả số PO, số bắt đầu, số kết thúc, số dòng một trang nữa, thật tiện cho em
Xin cám ơn mọi người

 

[vodoi2x]

không đọc kỹ hướng dẫn khi sử dụng

Cám ơn bác vodoi2x nhiều lắm.
Cách của bác làm sao nối tiếp được bác, ý em là nối tiếp thế này:
Trang 1:
cột A________ cột B__________ cột C ______cột D
22033x00001| 22033x00001| 22033x00004| 22033x00004
22033x00002| 22033x00002| 22033x00005| 22033x00005
22033x00003| 22033x00002| 22033x00006| 22033x00006
Trang 2:
cột A________ cột B__________ cột C ______cột D
22033x00007| 22033x00007| 22033x00010| 22033x00010
22033x00008| 22033x00008| 22033x00011| 22033x00011
22033x00009| 22033x00009| 22033x00012| 22033x00012
....
chạy cho đến 2000

Công thức bác đưa, nếu em nhập F2 là 2000 thì nó chạy số từ 1 đến 2000 xong nó chạy tiếp từ 4001 đến 60001, hix, mất khoảng giữa kìa bác

Ui, bạn không đọc kỹ hướng dẫn khi sử dụng rồi,

F2=23 là số dòng trên 1 trang - không phải là số kết thúc nhé,

giờ thì bạn nên sd công thức của huuthangbd cho phù hợp