Tìm số lớn nhất trong chuỗi số

[mythuat4p]

Anh em xem giúp mình có thể tìm được số lớn nhất trong chuỗi số không ?

Ví dụ : 435799726288. Tìm ra số lớn nhất là số 9
ahghsk42985hsgt54635. tìm ra số lớn nhất là số 9.

Công thức thì càng tốt. Nếu không thì VBA.

Thank

 

[befaint]

CT1:

=AGGREGATE(14,6,--MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1),1)
'Enter

CT2:

=MAX(IFERROR(--MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1),""))
'Ctrl + shift + enter

CT3:
...

 

[phulien1902]

CT1:

=AGGREGATE(14,6,--MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1),1)
'Enter

CT2:

=MAX(IFERROR(--MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1),""))
'Ctrl + shift + enter

CT3:
...

Công thức CT3 chưa đúng?

 

[Phan Thế Hiệp]

CT1:

=AGGREGATE(14,6,--MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1),1)
'Enter

CT2:

=MAX(IFERROR(--MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1),""))
'Ctrl + shift + enter

CT3:
...

Điền vào chỗ trống:
CT3:

=LOOKUP(10,ROW($1:$9)/SIGN(FIND(ROW($1:$9),A1)))
Hoặc:
=LOOKUP(10,ROW($1:$9)/(FIND(ROW($1:$9),A1)>0))

Chúc anh em ngày vui.

 

[batman1]

=10-MATCH(FALSE,ISERR(FIND({9,8,7,6,5,4,3,2,1,0},A1)),0)

 

[batman1]

CT2:

=MAX(IFERROR(--MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1),""))
'Ctrl + shift + enter

Nếu A1 không chứa chữ số thì nên trả về lỗi để nhận biết là dữ liệu có vấn đề. Không nên trả về 0 vì sẽ không ý thức được là chuỗi có vấn đề. Nếu dữ liệu nhiều thì khó nhận ra bằng mắt, dễ bỏ qua

 

[ndu96081631]

Góp thêm (chỉ hàm FIND thôi được rồi)

=LOOKUP(10^10,FIND(ROW($1:$9),A1),ROW($1:$9))

 

[befaint]

Thử dùng Min() nhưng sao dài vậy... Híc

=MID(A1,MATCH(MIN(IFERROR(1/(MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1)+1),"")),IFERROR(1/(MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1)+1),""),0),1)
'cse

 

[befaint]

ROW($1:$9)

Còn số 0 anh ơi.

 

[batman1]

Rõ ràng 0 cũng là chữ số, hay nói theo cách diễn đạt của thớt thì là số. Nếu A1 chứa vd. a0 thì kết quả phải là 0 chứ không thể là lỗi được. Tức các công thức LOOKUP đã đưa ra là chưa chuẩn.

Tất nhiên có trường hớp ở trên không thì thớt không nói, không miêu tả dữ liệu.

 

[ndu96081631]

Còn số 0 anh ơi.

thì kệ đi. Tui thấy nhưng mà tui thích vậy đó

 

[mythuat4p]

CT1:

=AGGREGATE(14,6,--MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1),1)
'Enter

CT2:

=MAX(IFERROR(--MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1),""))
'Ctrl + shift + enter

CT3:
...

Cám ơn bạn nhiều

 

[mythuat4p]

Điền vào chỗ trống:
CT3:

=LOOKUP(10,ROW($1:$9)/SIGN(FIND(ROW($1:$9),A1)))
Hoặc:
=LOOKUP(10,ROW($1:$9)/(FIND(ROW($1:$9),A1)>0))

Chúc anh em ngày vui.

Cám ơn bạn nhé