Tìm giá trị tăng giảm theo điều kiện (1 người xem)

[hngiatuong]

Em có 1 công thức tính giá trị tăng giảm, em đã tính được chiều tăng còn chiềugiảm thì chưa. Nhưng vấn đề là em muốn dùng công thức đang sử dụng. rất cảm ơn các anh chị quan tâm.

 

[nghiaphuc]

Em có 1 công thức tính giá trị tăng giảm, em đã tính được chiều tăng còn chiềugiảm thì chưa. Nhưng vấn đề là em muốn dùng công thức đang sử dụng. rất cảm ơn các anh chị quan tâm.

Chỗ điều kiện "B1<=-30 đến <-100" có lẽ phải sửa lại là -100<B1<=-30 chứ nhỉ? Tức là chỗ màu đỏ phải là > chứ?
Tôi nghĩ là bạn nên dùng hàm LOOKUP sẽ dễ hơn:

=LOOKUP(B1,{-99,-29,30,100,150,200,250},{-1,0,1,2,3,4,5})

 

[lenongree]

Thử CT này xem bạn!!!
=((B1>=30)+(B1>=100)+(B1>=150)+(B1>=200)+(B1>=250))-AND(B1<=-30,B1>-100)

 

[khuongvietphong]

nhân thêm cái này vào công thức của bạn:

*IF(B1>0,1,-1)

 

[lenongree]

Chỗ điều kiện "B1<=-30 đến <-100" có lẽ phải sửa lại là -100<B1<=-30 chứ nhỉ? Tức là chỗ màu đỏ phải là > chứ?
Tôi nghĩ là bạn nên dùng hàm LOOKUP sẽ dễ hơn:
Code:

=LOOKUP(B1,{-99,-29,30,100,150,200,250},{-1,0,1,2,3,4,5})

Hi, CT hay quá thầy!!!!

 

[nghiaphuc]

nhân thêm cái này vào công thức của bạn:

*IF(B1>0,1,-1)

Vụ này thì xài hàm SIGN nó "oai" hơn

 

[hngiatuong]

Ý của em là: bình thường là như điều kiện trên em đã làm, nhưng nếu điều kiện là bị âm và trong khoảng điều kiện tương tự thì giá trị sẽ bị đổi dấu. Em đã thử nhưng chưa chính xác ạ. Làm phiền các anh.

 

[hngiatuong]

Chỗ điều kiện "B1<=-30 đến <-100" có lẽ phải sửa lại là -100<B1<=-30 chứ nhỉ? Tức là chỗ màu đỏ phải là > chứ?
Tôi nghĩ là bạn nên dùng hàm LOOKUP sẽ dễ hơn:

=LOOKUP(B1,{-99,-29,30,100,150,200,250},{-1,0,1,2,3,4,5})

Dạ vâng ạ: nếu như -30>=B1<-100 ạ. Cảm ơn ac

 

[khuongvietphong]

Ý của em là: bình thường là như điều kiện trên em đã làm, nhưng nếu điều kiện là bị âm và trong khoảng điều kiện tương tự thì giá trị sẽ bị đổi dấu. Em đã thử nhưng chưa chính xác ạ. Làm phiền các anh.

Bạn lồng thêm hàm Abs() vào trước B1 là được

 

[khuongvietphong]

Dạ vâng ạ: nếu như -30>=B1<-100 ạ. Cảm ơn ac

Công thức thế này:

=((ABS(B1)>=30)+(ABS(B1)>=100)+(ABS(B1)>=150)+(ABS(B1)>=200)+(ABS(B1)>=250))*IF(B1>0,1,-1)

Hoặc theo ý của anh công nhân "đào mỏ" thì thế này:

=((ABS(B1)>=30)+(ABS(B1)>=100)+(ABS(B1)>=150)+(ABS(B1)>=200)+(ABS(B1)>=250))*SIGN(B1)

 

[nghiaphuc]

Dạ vâng ạ: nếu như -30>=B1<-100 ạ. Cảm ơn ac

Nếu tôi hiểu đúng thì phải là -100<B1<=-30 hay -30>=B1>-100 chứ đâu phải là -30>=B1<-100. Bạn làm tôi "bối rối" quá.
Thế tóm lại hàm LOOKUP trên đã ổn chưa vậy bạn?

 

[hngiatuong]

Nếu B1 >=+-30 đến <+-100 thì +-1điểm
từ >=+-100 đến <+-150 thì +-2 điểm
từ >=+-150 đến <+-200 thì +-3 điểm
từ >=+-200 đến <+-250 thì +-4 điểm
từ >=+-250 thì +-5 điểm
Rất xin lỗi vì em muốn dùng công thức này

 

[nghiaphuc]

Nếu B1 >=+-30 đến <+-100 cộng +-1điểm
từ >=+-100 đến <+-150 cộng +-2 điểm
từ >=+-150 đến <+-200 cộng +-3 điểm
từ >=+-200 đến <+-250 cộng +-4 điểm
từ >=+-250 cộng +-5 điểm
Rất xin lỗi vì em muốn dùng công thức này

Vậy thì công thức ở bài #11 đáp ứng đúng yêu cầu của bạn rồi đấy.

 

[hngiatuong]

Nếu tôi hiểu đúng thì phải là -100<B1<=-30 hay -30>=B1>-100 chứ đâu phải là -30>=B1<-100. Bạn làm tôi "bối rối" quá.
Thế tóm lại hàm LOOKUP trên đã ổn chưa vậy bạn?

Vâng như anh nói ạ. Vội quá hóa lúng túng. Xin lỗi anh ạ.

 

[hngiatuong]

Công thức thế này:

=((ABS(B1)>=30)+(ABS(B1)>=100)+(ABS(B1)>=150)+(ABS(B1)>=200)+(ABS(B1)>=250))*IF(B1>0,1,-1)

Hoặc theo ý của anh công nhân "đào mỏ" thì thế này:

=((ABS(B1)>=30)+(ABS(B1)>=100)+(ABS(B1)>=150)+(ABS(B1)>=200)+(ABS(B1)>=250))*SIGN(B1)

Dạ xin cảm ơn anh nghĩa phúc đã chỉ, cảm ơn Việt Khương - công thức chuẩn rồi. Xin được cảm ơn tất cả mọi người ạ. Chúc buổi tối vui vẻ

 

[nghiaphuc]

Nếu B1 >=+-30 đến <+-100 thì +-1điểm
từ >=+-100 đến <+-150 thì +-2 điểm
từ >=+-150 đến <+-200 thì +-3 điểm
từ >=+-200 đến <+-250 thì +-4 điểm
từ >=+-250 thì +-5 điểm
Rất xin lỗi vì em muốn dùng công thức này

Dù sao thì bạn cũng nên tham khảo thêm một cách không "dùng công thức này", biết đâu bạn lại suy nghĩ lại nhỉ (lỡ mang tiếng "đào mỏ" rồi nên "khai quật" thêm lần nữa luôn ):

=SIGN(B1)*(MATCH(ABS(B1),{0,30,100,150,200,250},1)-1)

 

[hngiatuong]

Dù sao thì bạn cũng nên tham khảo thêm một cách không "dùng công thức này", biết đâu bạn lại suy nghĩ lại nhỉ (lỡ mang tiếng "đào mỏ" rồi nên "khai quật" thêm lần nữa luôn ):

=SIGN(B1)*(MATCH(ABS(B1),{0,30,100,150,200,250},1)-1)

Dạ. Xin cảm ơn anh đã giúp. Thực ra em đang cố hiểu thêm về cách không vận dùng hàm trực tiếp. Em rất thích kiểu dạng như vậy, rất mong anh thông cảm.

 

[nghiaphuc]

Dạ. Xin cảm ơn anh đã giúp. Thực ra em đang cố hiểu thêm về cách không vận dùng hàm trực tiếp. Em rất thích kiểu dạng như vậy, rất mong anh thông cảm.

Hóa ra ý tưởng của bạn là như vậy. Vậy thì xài công thức này, chẳng có một hàm nào cả:

=((B1>=30)+(B1>=100)+(B1>=150)+(B1>=200)+(B1>=250))-((B1<=-30)+(B1<=-100)+(B1<=-150)+(B1<=-200)+(B1<=-250))

 

[bebo021999]

Tại sao dùng hàm gọn hơn rất nhiều mà k thích nhỉ? Góp thêm một hàm:

=SUMPRODUCT(SIGN(B1)*(ABS(B1)>={30,100,150,200,250}))