giúp mình đếm số trong cột chẵn cột lẻ . (1 người xem)

phuongdlt · 7/1/19

đây là mẫu mình cần .

mình cần dùng hàm chứ không dùng VBA .
mọi người xem giúp mình nhé .

tam888 · 7/1/19

phuongdlt đã viết:
đây là mẫu mình cần .

mình cần dùng hàm chứ không dùng VBA .
mọi người xem giúp mình nhé .

Mẫu cần là mẫu chi
Nếu B4 chứa số 4 thì công thức tại ô kết quả là

Mã:

=SUMPRODUCT((D4:N4=B4)*(MOD(COLUMN(D4:N4)-COLUMN(D4)+1,2)=0))

phuongdlt · 7/1/19

tam888 đã viết:
Mẫu cần là mẫu chi
Nếu B4 chứa số 4 thì công thức tại ô kết quả là

Mã:

=SUMPRODUCT((D4:N4=B4)*(MOD(COLUMN(D4:N4)-COLUMN(D4)+1,2)=0))

rất cảm ơn bạn .

.................

phuongdlt · 8/1/19

tam888 đã viết:
Mẫu cần là mẫu chi

bạn ơi . mình muốn tìm số cuối cùng của cột chẵn thì sửa hàm như nào bạn , nếu số cuối cùng vào cột lẻ thì bỏ qua . mình loay hoay với hàm mod mà chưa được . cảm ơn bạn nhiều :d

Phan Thế Hiệp · 8/1/19

phuongdlt đã viết:
mình muốn tìm số cuối cùng của cột chẵn thì sửa hàm như nào bạn , nếu số cuối cùng vào cột lẻ thì bỏ qua

Thử:

Mã:

=LOOKUP(100,D4:N4/MOD(COLUMN(A:Z)-1,2))

Thân

tam888 · 8/1/19

phuongdlt đã viết:
bạn ơi . mình muốn tìm số cuối cùng của cột chẵn thì sửa hàm như nào bạn , nếu số cuối cùng vào cột lẻ thì bỏ qua . mình loay hoay với hàm mod mà chưa được . cảm ơn bạn nhiều :d

Nên là

Mã:

=LOOKUP(2,1/(MOD(COLUMN(D4:N4)-COLUMN(D4)+1,2)=0),D4:N4)

phuongdlt · 8/1/19

Phan Thế Hiệp đã viết:
Thử:

Mã:

=LOOKUP(100,D4:N4/MOD(COLUMN(A:Z)-1,2))

Thân

bạn ơi mình chạy thì khi mình xóa số cuối thì bị thành 0 chứ không hiện số cuối bạn ah . bạn có thể sửa giúp mình được ko

tam888 · 8/1/19

phuongdlt đã viết:
bạn ơi mình chạy thì khi mình xóa số cuối thì bị thành 0 chứ không hiện số cuối bạn ah . bạn có thể sửa giúp mình được ko

Thì bằng 0 là chuẩn rùi, vì excel coi ô rỗng là bằng 0
vậy bạn muốn bằng bao nhiêu?

Và trong file kèm trên đang sử dụng công thức không phải của tôi

phuongdlt · 8/1/19

tam888 đã viết:
Nên là

Mã:

=LOOKUP(2,1/(MOD(COLUMN(D4:N4)-COLUMN(D4)+1,2)=0),D4:N4)

mình gửi file bạn xem giúp mình nhé . cảm ơn bạn trước nhé

tam888 · 8/1/19

phuongdlt đã viết:
mình gửi file bạn xem giúp mình nhé . cảm ơn bạn trước nhé

Thì bằng 0 là chuẩn rùi, vì excel coi ô rỗng là bằng 0 (do bạn quét dữ liệu đến tận cột Z?)
vậy bạn muốn bằng bao nhiêu?

Phan Thế Hiệp · 8/1/19

phuongdlt đã viết:
bạn ơi mình chạy thì khi mình xóa số cuối thì bị thành 0 chứ không hiện số cuối bạn ah . bạn có thể sửa giúp mình được ko

Vậy thì vầy:

Mã:

B4=LOOKUP(10^35,OFFSET($D4,,,,CEILING(COUNTIF($D4:$ZZ4,">0"),2))/MOD(COLUMN($A:$ZZ)-1,2))

Enter fill xuống
Kỹ tính hơn chút phải vầy:
Thay đoạn COUNTIF($D4:$ZZ4,">0") bằng LOOKUP(2,1/$D4:$ZZ4,COLUMN($A:$ZZ))
Như sau:

Mã:

B4=LOOKUP(10^35,OFFSET($D4,,,,CEILING(LOOKUP(2,1/$D4:$ZZ4,COLUMN($A:$ZZ)),2))/MOD(COLUMN($A:$ZZ)-1,2))

Thân

phuongdlt · 8/1/19

Phan Thế Hiệp đã viết:
Vậy thì vầy:

Mã:

B4=LOOKUP(10^35,OFFSET($D4,,,,CEILING(COUNTIF($D4:$ZZ4,">0"),2))/MOD(COLUMN($A:$ZZ)-1,2))

Enter fill xuống
Kỹ tính hơn chút phải vầy:
Thay đoạn COUNTIF($D4:$ZZ4,">0") bằng LOOKUP(2,1/$D4:$ZZ4,COLUMN($A:$ZZ))
Như sau:

Mã:

B4=LOOKUP(10^35,OFFSET($D4,,,,CEILING(LOOKUP(2,1/$D4:$ZZ4,COLUMN($A:$ZZ)),2))/MOD(COLUMN($A:$ZZ)-1,2))

Thân

bạn ơi mình muốn sửa theo cột mình muốn : VD từ cột A mình muốn chuyển sang Cột D nhưng khi mình chuyển thế thì gây ra lỗi bạn à .
B4=LOOKUP(10^35,OFFSET($D4,,,,CEILING(LOOKUP(2,1/$D4:$ZZ4,COLUMN($A -> D:$ZZ)),2))/MOD(COLUMN($A ->D:$ZZ)-1,2)) nhưng bị lỗi thì mình cần sửa gì thêm nữa bạn . cảm ơn nhiều

tam888 · 8/1/19

phuongdlt đã viết:
bạn ơi mình muốn sửa theo cột mình muốn : VD từ cột A mình muốn chuyển sang Cột D nhưng khi mình chuyển thế thì gây ra lỗi bạn à .
B4=LOOKUP(10^35,OFFSET($D4,,,,CEILING(LOOKUP(2,1/$D4:$ZZ4,COLUMN($A -> D:$ZZ)),2))/MOD(COLUMN($A ->D:$ZZ)-1,2)) nhưng bị lỗi thì mình cần sửa gì thêm nữa bạn . cảm ơn nhiều

Bạn kiệm lời quá, kết quả bằng bao nhiêu với các ví dụ (tôi hỏi bạn trên 2 post rồi)
Nên giả lập file nhiều trường hợp để người xem biết là bạn muốn sao

Phan Thế Hiệp · 8/1/19

phuongdlt đã viết:
bạn ơi mình muốn sửa theo cột mình muốn : VD từ cột A mình muốn chuyển sang Cột D nhưng khi mình chuyển thế thì gây ra lỗi bạn à .
B4=LOOKUP(10^35,OFFSET($D4,,,,CEILING(LOOKUP(2,1/$D4:$ZZ4,COLUMN($A -> D:$ZZ)),2))/MOD(COLUMN($A ->D:$ZZ)-1,2)) nhưng bị lỗi thì mình cần sửa gì thêm nữa bạn . cảm ơn nhiều

Công thức MOD(COLUMN($A:$ZZ)-1,2) nhằm tạo 1 mảng hàng ngang: từ {1,2,3,4,....} thành mảng {0,1,0,1,0,1....} ứng với việc phân cột: {lẻ,chẳn,lẻ,chẳn,...}.

Nên nó không liên can cột chứa dữ liệu của bạn, thì không nên thay đổi.

Thân

tam888 · 8/1/19

Phan Thế Hiệp đã viết:
Công thức MOD(COLUMN($A:$ZZ)-1,2) nhằm tạo 1 mảng hàng ngang: từ {1,2,3,4,....} thành mảng {0,1,0,1,0,1....} ứng với việc phân cột: {lẻ,chẳn,lẻ,chẳn,...}.

Nên nó không liên can cột chứa dữ liệu của bạn, thì không nên thay đổi.

Thân

Cái này hay, nhưng có 1 điểm khuyết là : Sai lệch khi chèn cột A của bảng tính
Nên sử dụng thì cần cân nhắc Không chèn cột A

phuongdlt · 8/1/19

Phan Thế Hiệp đã viết:
Công thức MOD(COLUMN($A:$ZZ)-1,2) nhằm tạo 1 mảng hàng ngang: từ {1,2,3,4,....} thành mảng {0,1,0,1,0,1....} ứng với việc phân cột: {lẻ,chẳn,lẻ,chẳn,...}.

Nên nó không liên can cột chứa dữ liệu của bạn, thì không nên thay đổi.

Thân

vì mình muốn chủ động trong việc chọn cột , các bẳng tính của mình cột đối chiếu không sắp xếp giống nhau nên mình cần tùy biến cột đó , thanks bạn

, mình loay hoay mãi mà vẫn chưa thể tùy biến theo ý mình được ,
B4=LOOKUP(10^35,OFFSET($D4,,,,CEILING(LOOKUP(2,1/$D4:$ZZ4,COLUMN($A -> D:$ZZ)),2))/MOD(COLUMN($A ->D:$ZZ)-1,2)) nhưng bị lỗi thì mình cần sửa gì thêm

Bài đã được tự động gộp: 8/1/19

tam888 đã viết:
Cái này hay, nhưng có 1 điểm khuyết là : Sai lệch khi chèn cột A của bảng tính
Nên sử dụng thì cần cân nhắc Không chèn cột A

ý mình là tính từ cột cần tính mà không lấy mốc là cột A đó

tam888 · 8/1/19

phuongdlt đã viết:
vì mình muốn chủ động trong việc chọn cột , các bẳng tính của mình cột đối chiếu không sắp xếp giống nhau nên mình cần tùy biến cột đó , Cảm ơn bạn , mình loay hoay mãi mà vẫn chưa thể tùy biến theo ý mình được ,
B4=LOOKUP(10^35,OFFSET($D4,,,,CEILING(LOOKUP(2,1/$D4:$ZZ4,COLUMN($A -> D:$ZZ)),2))/MOD(COLUMN($A ->D:$ZZ)-1,2)) nhưng bị lỗi thì mình cần sửa gì thêm

Bài đã được tự động gộp: 8/1/19

ý mình là tính từ cột cần tính mà không lấy mốc là cột A đó

Vẫn kiệm lợi
Kết quả lấy sao?

Gia cát Dự (nickname Đoán Toàn Sai): Có phải bạn muốn lấy giá trị cuối cùng (có số) của dòng, nếu giá trị cuối cùng đó nằm ở cột Lẻ thì lấy =0, cột chẵn thì lấy giá trị ô đó

phuongdlt · 8/1/19

tam888 đã viết:
Vẫn kiệm lợi
Kết quả lấy sao?

Gia cát Dự (nickname Đoán Toàn Sai): Có phải bạn muốn lấy giá trị cuối cùng (có số) của dòng, nếu giá trị cuối cùng đó nằm ở cột Lẻ thì lấy =0, cột chẵn thì lấy giá trị ô đó

hàm ở trên là ok rồi bạn , chỉ là mình muốn tùy biến cho cột A
VD
COLUMN($A -> D:$ZZ)),2))/MOD(COLUMN($A ->D:$ZZ)
cột mình cần tính là cột H , sheet khác lại cần tính từ cột O , nhưng khi mỗi lần mình thay cột theo ý mình thì lại lỗi và mình chưa biết sửa chỗ nào cho đúng .

tam888 · 8/1/19

phuongdlt đã viết:
hàm ở trên là ok rồi bạn , chỉ là mình muốn tùy biến cho cột A
VD
COLUMN($A -> D:$ZZ)),2))/MOD(COLUMN($A ->D:$ZZ)
cột mình cần tính là cột H , sheet khác lại cần tính từ cột O , nhưng khi mỗi lần mình thay cột theo ý mình thì lại lỗi và mình chưa biết sửa chỗ nào cho đúng .

Vậy GiaCatDu trên có đúng hay không hay bạn muốn khác?
Vì nếu nickname DoanToanSai là đúng thì có công thức khác

phuongdlt · 8/1/19

tam888 đã viết:
Vậy GiaCatDu trên có đúng hay không hay bạn muốn khác?
Vì nếu nickname DoanToanSai là đúng thì có công thức khác

hàm trên là đúng nhưng mình muốn tùy biến cho cột bắt đầu không phải là cột A
bạn có thể giúp mình theo cách của bạn chứ

tam888 · 8/1/19

phuongdlt đã viết:
hàm trên là đúng nhưng mình muốn tùy biến cho cột bắt đầu không phải là cột A
bạn có thể giúp mình theo cách của bạn chứ

Tôi hỏi về GiaCatDu và DoanToanSai, thì bạn trả lời 1 nẻo: hàm ... hàm đó có phải của tôi đâu

Thôi
Thử phương án này

Mã:

=IF(MOD(LOOKUP(2,1/D4:Z4,COLUMN(D4:Z4)-COLUMN(D4)+1),2),0,LOOKUP(2,1/D4:Z4,D4:Z4))

batman1 · 8/1/19

phuongdlt đã viết:
hàm trên là đúng nhưng mình muốn tùy biến cho cột bắt đầu không phải là cột A
bạn có thể giúp mình theo cách của bạn chứ

Bạn nên mô tả rõ ràng yêu cầu của bạn. Đừng nên lấy một hướng nào đó, công thức nào đó để làm tiêu chí rồi bắt người khác phải theo khuôn đó. Người khác có thể có ý tưởng khác dựa trên yêu cầu của bạn. Câu hỏi của bạn tam888 rất rõ ràng

Có phải bạn muốn lấy giá trị cuối cùng (có số) của dòng, nếu giá trị cuối cùng đó nằm ở cột Lẻ thì lấy =0, cột chẵn thì lấy giá trị ô đó

Chỉ là trả lời: "Đúng thế", "Không phải thế". Tại sao bạn lại không trả lời?

Nếu câu trả lời cho bạn tam888 là "Đúng thế", và tôi hiểu được việc thay vùng thì ...

Xin nhớ là nếu vùng bắt đầu từ cột nào - cột mốc - thì cột đó tính là lẻ. Tức nếu bắt đầu từ D thì cột D tính là lẻ. Nếu bắt đầu từ cột O thì cột O tính là lẻ, nếu cột mốc là H thì cột H tính là lẻ v...v

Mã:

=LOOKUP(10^99;$D4:$ZZ4)*MOD(LOOKUP(10^99;(COLUMN($A4:$ZZ4)-1)/($D4:$ZZ4<>""));2)

Khi thay đổi cột mốc thành O hay H thì đổi D thành O hay H, mọi chỗ khác không đổi. Tức

Mã:

=LOOKUP(10^99;$O4:$ZZ4)*MOD(LOOKUP(10^99;(COLUMN($A4:$ZZ4)-1)/($O4:$ZZ4<>""));2)

hoặc

=LOOKUP(10^99;$H4:$ZZ4)*MOD(LOOKUP(10^99;(COLUMN($A4:$ZZ4)-1)/($H4:$ZZ4<>""));2)

phuongdlt · 9/1/19

tam888 đã viết:
Tôi hỏi về GiaCatDu và DoanToanSai, thì bạn trả lời 1 nẻo: hàm ... hàm đó có phải của tôi đâu

Thôi
Thử phương án này

Mã:

=IF(MOD(LOOKUP(2,1/D4:Z4,COLUMN(D4:Z4)-COLUMN(D4)+1),2),0,LOOKUP(2,1/D4:Z4,D4:Z4))

good................................ thanks you .......................!!!

Phan Thế Hiệp · 9/1/19

phuongdlt đã viết:
bạn ơi mình muốn sửa theo cột mình muốn : VD từ cột A mình muốn chuyển sang Cột D nhưng khi mình chuyển thế thì gây ra lỗi bạn à .
B4=LOOKUP(10^35,OFFSET($D4,,,,CEILING(LOOKUP(2,1/$D4:$ZZ4,COLUMN($A -> D:$ZZ)),2))/MOD(COLUMN($A ->D:$ZZ)-1,2)) nhưng bị lỗi thì mình cần sửa gì thêm nữa bạn . cảm ơn nhiều

Vậy bạn chịu khó đem file chứa khoảng 3 sheet có Vùng khác nhau lên đi, nhìn thực tế file mới biết bạn đang gặp khó ở chỗ nào, lúc đó mới có công thức phù hợp cho trường hợp của bạn.

Cũng đưa ra thêm 1 hướng theo dõi cho bạn tham khảo, như file đính kèm dưới đây, chỉ cần bạn xác định duy nhất Vùng chứa dữ liệu, thì công thức sẽ tự xem xét và phân chia cột chẳn và lẻ tùy theo thứ tự của số phát sinh đầu tiên (lúc nào cũng tính là 1 lẻ). Giả sử:

Vùng số liệu là D4: ZZ4, số liệu phát sinh đầu tiên tại cột D4, thì nó sẽ tính D là cột 1 (lẻ). (Xem stt tại D3: Z3)
Vùng số liệu là D5: ZZ5, số liệu phát sinh đầu tiên tại cột G5, thì nó sẽ tính G là cột 1 (lẻ). (Xem stt tại D6: Z6)

Công thức sau chỉ cần xác định Vùng 1 lần lúc lập, và không cần phải chỉnh đi chỉnh lại là: cột A, hay cột D, hay cột O, cột H... cột nào là đầu tiên, nó không quan tâm nữa. Cụ thể:

Mã:

B4=IF(MOD(SUM(AGGREGATE({14,15},6,COLUMN($D4:$ZZ4)/($D4:$ZZ4>0),1)*{1,-1}),2),1/LOOKUP(2,1/$D4:$ZZ4),)

Enter fill xuống.

Bạn cứ tự nhiên trình bày những khó khăn của mình, đừng ngại bất kỳ điều gì.

Chúc bạn học tập vui với GPE
Thân

phuongdlt · 9/1/19

batman1 đã viết:
Bạn nên mô tả rõ ràng yêu cầu của bạn. Đừng nên lấy một hướng nào đó, công thức nào đó để làm tiêu chí rồi bắt người khác phải theo khuôn đó. Người khác có thể có ý tưởng khác dựa trên yêu cầu của bạn. Câu hỏi của bạn tam888 rất rõ ràng

Chỉ là trả lời: "Đúng thế", "Không phải thế". Tại sao bạn lại không trả lời?

Nếu câu trả lời cho bạn tam888 là "Đúng thế", và tôi hiểu được việc thay vùng thì ...

Xin nhớ là nếu vùng bắt đầu từ cột nào - cột mốc - thì cột đó tính là lẻ. Tức nếu bắt đầu từ D thì cột D tính là lẻ. Nếu bắt đầu từ cột O thì cột O tính là lẻ, nếu cột mốc là H thì cột H tính là lẻ v...v

Mã:

=LOOKUP(10^99;$D4:$ZZ4)*MOD(LOOKUP(10^99;(COLUMN($A4:$ZZ4)-1)/($D4:$ZZ4<>""));2)

Khi thay đổi cột mốc thành O hay H thì đổi D thành O hay H, mọi chỗ khác không đổi. Tức

Mã:

=LOOKUP(10^99;$O4:$ZZ4)*MOD(LOOKUP(10^99;(COLUMN($A4:$ZZ4)-1)/($O4:$ZZ4<>""));2) hoặc =LOOKUP(10^99;$H4:$ZZ4)*MOD(LOOKUP(10^99;(COLUMN($A4:$ZZ4)-1)/($H4:$ZZ4<>""));2)

cảm ơn bạn

................. bạn tam888 đã giúp đúng như mình muốn

Bài đã được tự động gộp: 9/1/19

Phan Thế Hiệp đã viết:
Vậy bạn chịu khó đem file chứa khoảng 3 sheet có Vùng khác nhau lên đi, nhìn thực tế file mới biết bạn đang gặp khó ở chỗ nào, lúc đó mới có công thức phù hợp cho trường hợp của bạn.

Cũng đưa ra thêm 1 hướng theo dõi cho bạn tham khảo, như file đính kèm dưới đây, chỉ cần bạn xác định duy nhất Vùng chứa dữ liệu, thì công thức sẽ tự xem xét và phân chia cột chẳn và lẻ tùy theo thứ tự của số phát sinh đầu tiên (lúc nào cũng tính là 1 lẻ). Giả sử:

Vùng số liệu là D4: ZZ4, số liệu phát sinh đầu tiên tại cột D4, thì nó sẽ tính D là cột 1 (lẻ). (Xem stt tại D3: Z3)

Vùng số liệu là D5: ZZ5, số liệu phát sinh đầu tiên tại cột G5, thì nó sẽ tính G là cột 1 (lẻ). (Xem stt tại D6: Z6)

Công thức sau chỉ cần xác định Vùng 1 lần lúc lập, và không cần phải chỉnh đi chỉnh lại là: cột A, hay cột D, hay cột O, cột H... cột nào là đầu tiên, nó không quan tâm nữa. Cụ thể:

Mã:

B4=IF(MOD(SUM(AGGREGATE({14,15},6,COLUMN($D4:$ZZ4)/($D4:$ZZ4>0),1)*{1,-1}),2),1/LOOKUP(2,1/$D4:$ZZ4),)

Enter fill xuống.

Bạn cứ tự nhiên trình bày những khó khăn của mình, đừng ngại bất kỳ điều gì.

Chúc bạn học tập vui với GPE
Thân

good.........................thanks you.....................................!!!

giúp mình đếm số trong cột chẵn cột lẻ . (1 người xem)

Người dùng đang xem chủ đề này

Thành viên mới

File đính kèm

Thành viên tích cực

Thành viên mới

Thành viên mới

-⍟-

Thành viên tích cực

Thành viên mới

File đính kèm

Thành viên tích cực

Thành viên mới

File đính kèm

Thành viên tích cực

-⍟-

File đính kèm

Thành viên mới

Thành viên tích cực

-⍟-

Thành viên tích cực

Thành viên mới

Thành viên tích cực

Thành viên mới

Thành viên tích cực

Thành viên mới

Thành viên tích cực

Thành viên gạo cội

Thành viên mới

-⍟-

File đính kèm

Thành viên mới

Thời gian đếm ngược.