Giúp em CT tìm dữ liệu với ạ ! (3 người xem)

[ThuyTrang79]

Em chào anh chị !
Em có gởi file vd cần giúp ạ, Trong file cột A là DL, cột D là các đuôi số cần tìm sang cột A, các đuôi số có thể là có thể là 2,3,4,5,... kí tự ạ
Trong bài này em cần tìm các đuôi số với dữ liệu cho sẵn ạ
Nhờ anh chị viết dùm em công thức với ạ, cảm ơn anh chị nhiều !

 

[hocexcel_1991]

Em chào anh chị !
Em có gởi file vd cần giúp ạ, Trong file cột A là DL, cột D là các đuôi số cần tìm sang cột A, các đuôi số có thể là có thể là 2,3,4,5,... kí tự ạ
Trong bài này em cần tìm các đuôi số với dữ liệu cho sẵn ạ
Nhờ anh chị viết dùm em công thức với ạ, cảm ơn anh chị nhiều !

Thử công thức này

B2=SIGN(SUM(INDEX(N($D$2:$D$9=--MID(A2,COLUMN($A$1:$I$1),9)),)))=>Enter

 

[befaint]

b2=SUMPRODUCT(--(--RIGHT(A2,LEN($D$2:$D$9))=$D$2:$D$9))

 

[ThuyTrang79]

Thử công thức này

B2=SIGN(SUM(INDEX(N($D$2:$D$9=--MID(A2,COLUMN($A$1:$I$1),9)),)))=>Enter

b2=SUMPRODUCT(--(--RIGHT(A2,LEN($D$2:$D$9))=$D$2:$D$9))

Dạ em cảm ơn ạ, Em muốn trong CT mở rộng vùng lấy dữ liệu sẵn D2 đến D100 (hoặc hơn), khi cần tìm gì đó gõ đuôi cần tìm vào cột D ra KQ luôn ạ

 

[hocexcel_1991]

Dạ em cảm ơn ạ, Em muốn trong CT mở rộng vùng lấy dữ liệu sẵn D2 đến D100 (hoặc hơn), khi cần tìm gì đó gõ đuôi cần tìm vào cột D ra KQ luôn ạ

Nhấn Ctrl+Shirt+Enter

=SIGN(SUM(N(IF($D$2:$D$100<>"",$D$2:$D$100)=--MID(A2,COLUMN($A$1:$I$1),9))))

 

[ThuyTrang79]

Nhấn Ctrl+Shirt+Enter

=SIGN(SUM(N(IF($D$2:$D$100<>"",$D$2:$D$100)=--MID(A2,COLUMN($A$1:$I$1),9))))

Dạ ok rùi ạ, bỏ dc chức năng ctrl shift enter ko anh nhỉ, tại em lấy CT nhanh ạ .

 

[bebo021999]

Dùng cái này tại B2 rồi kéo xuống:

=1-ISERROR(MATCH(TRUE,INDEX(SEARCH($D$2:$D$100&"|",A2&"|")<=LEN(A2),),0))

Enter bình thường nhé.

 

[batman1]

B2

=SIGN(SUMPRODUCT((MOD(A2,10^LEN(D$2:D$20))=D$2:D$20)*(D$2:D$20<>"")))

 

[ThuyTrang79]

Dùng cái này tại B2 rồi kéo xuống:

=1-ISERROR(MATCH(TRUE,INDEX(SEARCH($D$2:$D$100&"|",A2&"|")<=LEN(A2),),0))

Enter bình thường nhé.

B2

=SIGN(SUMPRODUCT((MOD(A2,10^LEN(D$2:D$20))=D$2:D$20)*(D$2:D$20<>"")))

Dạ CT chạy OK rùi em cảm ơn anh chị nhiều ạ !
Cũng bài tìm này, nếu gõ liệt kê các đuôi số cần tìm đó vào trong CT mà ko sử dụng cột phụ D được ko ạ ?

 

[bebo021999]

Dạ CT chạy OK rùi em cảm ơn anh chị nhiều ạ !
Cũng bài tìm này, nếu gõ liệt kê các đuôi số cần tìm đó vào trong CT mà ko sử dụng cột phụ D được ko ạ ?

Thì ai cấm gõ đâu: {123,52,126,...}
Hoặc nhanh nhất là trên thanh công thức, bôi đen vùng D, nhấn F9, sau đó enter.

 

[ThuyTrang79]

Thì ai cấm gõ đâu: {123,52,126,...}
Hoặc nhanh nhất là trên thanh công thức, bôi đen vùng D, nhấn F9, sau đó enter.

Dạ Ok rùi, cảm ơn anh !

 

[ThuyTrang79]

Thì ai cấm gõ đâu: {123,52,126,...}
Hoặc nhanh nhất là trên thanh công thức, bôi đen vùng D, nhấn F9, sau đó enter.

Nhờ anh giúp em thêm vdb2 với ạ,
Trong bài này tìm kết hợp 3 số giữa và và 3 số cuối với DL cho sẵn ở cột D và E,
Kết quả em cần, nếu đúng cả 2 giữ liệu cho sẵn D và E là lấy
Dữ liệu D và E có lúc em nhập hơi nhiều, nên viết dùm em CT tránh bị báo quá 255 kí tự ạ
Em cảm ơn ạ !

 

[HieuCD]

Dạ CT chạy OK rùi em cảm ơn anh chị nhiều ạ !
Cũng bài tìm này, nếu gõ liệt kê các đuôi số cần tìm đó vào trong CT mà ko sử dụng cột phụ D được ko ạ ?

=SUMPRODUCT(--ISNUMBER(FIND($D$2:$D$9&"|",A2&"|")))
Gõ trực tiếp
=SUM(--ISNUMBER(FIND({2271;7718;15534;115213;99308;685;52;98}&"|",A2&"|")))

 

[ThuyTrang79]

=SUMPRODUCT(--ISNUMBER(FIND($D$2:$D$9&"|",A2&"|")))
Gõ trực tiếp
=SUM(--ISNUMBER(FIND({2271;7718;15534;115213;99308;685;52;98}&"|",A2&"|")))

Dạ CT này em làm OK rùi ạ,
Ở #12 là bài khác em có up lên đó là vdb2 ạ
Nhờ anh chị giúp em #12 vdb2 với ạ.

 

[HieuCD]

Dạ CT này em làm OK rùi ạ,
Ở #12 là bài khác em có up lên đó là vdb2 ạ
Nhờ anh chị giúp em #12 vdb2 với ạ.

=SIGN(AND(OR({282;"015";134;106;"097";"028"}&""=MID(A2,4,3)),OR({810;562;870;417;534;271;660;213}&""=MID(A2,7,3))))

 

[ThuyTrang79]

=SIGN(AND(OR({282;"015";134;106;"097";"028"}&""=MID(A2,4,3)),OR({810;562;870;417;534;271;660;213}&""=MID(A2,7,3))))

Dạ CT vdb2 OK rùi anh ạ, em cảm ơn anh !

 

[ThuyTrang79]

Thì ai cấm gõ đâu: {123,52,126,...}
Hoặc nhanh nhất là trên thanh công thức, bôi đen vùng D, nhấn F9, sau đó enter.

Cho em hỏi nếu đang filter, lấy riêng vùng đang filter thì làm thế nào ạ, tại em làm nó lấy hết cả ạ.

 

[ThuyTrang79]

Em bôi đen trong CT rùi chọn vùng lấy dữ liệu khi đang Filter rồi bấm F9, nó lấy hết vùng đó, nó ko lấy vùng chỉ đang Filter
Nhờ anh chị chỉ em cách lấy vùng đang Filter với ạ.

 

[be_09]

Cho em hỏi nếu đang filter, lấy riêng vùng đang filter thì làm thế nào ạ, tại em làm nó lấy hết cả ạ.

Thử thế này:
Chọn vùng cần lấy dữ liệu, nhấn Ctrl+G nhấn nút Special chọn Visible cells only rồi nhấn nút OK.
Tiếp theo Ctrl+C và Paste > Value nơi bạn cần.

 

[ThuyTrang79]

Thử thế này:
Chọn vùng cần lấy dữ liệu, nhấn Ctrl+G nhấn nút Special chọn Visible cells only rồi nhấn nút OK.
Tiếp theo Ctrl+C và Paste > Value nơi bạn cần.

Em chưa hiểu cách làm lắm ạ, có phím tắt nào làm nhanh ko ạ.