Giúp đỡ về các option trong Userform (1 người xem)

[chua123]

Dear Các Pác,

Nhờ các Pác hỗ trợ giùm em, em có 1 userform dạng multi page, ở mỗi page em có các hạng mục (text box), ứng với mỗi text box có các option box đánh số từ 0 tới 3, khi option nào dược chọn thì trong text bx tương ứng sẽ hiện lên số của option (0, 1, 2, 3).
Sau khi chọn xong, nhấn nhập data, thì giá trị các text box ở các page được paste vào sheet2. cụ thể trong file đính kèm. các pác giúp với.

 

[chua123]

Sao không ai giúp hết vậy? Huhu

 

[phucbugis]

Dear Các Pác,
Nhờ các Pác hỗ trợ giùm em, em có 1 userform dạng multi page, ở mỗi page em có các hạng mục (text box), ứng với mỗi text box có các option box đánh số từ 0 tới 3, khi option nào dược chọn thì trong text bx tương ứng sẽ hiện lên số của option (0, 1, 2, 3).
...

mình làm vấn đề 1 trước nhé:
b1: đặt các OptionButton (Opt) vào trong Frame để có thể dùng riêng cho từng hạng mục.
b2: khai báo sự kiện Click cho các Opt tại Class Modules ---> code mới gọn được.
'-------
các Textbox, opt của page khác bạn làm tương tự (để ý cách đặt tên các Controls mình đã tạo ở Page1)
'-------
hehe, bác HTN làm từ A->Z kiểu này etc etc...

 

[Hoàng Trọng Nghĩa]

Dear Các Pác,

Nhờ các Pác hỗ trợ giùm em, em có 1 userform dạng multi page, ở mỗi page em có các hạng mục (text box), ứng với mỗi text box có các option box đánh số từ 0 tới 3, khi option nào dược chọn thì trong text bx tương ứng sẽ hiện lên số của option (0, 1, 2, 3).
Sau khi chọn xong, nhấn nhập data, thì giá trị các text box ở các page được paste vào sheet2. cụ thể trong file đính kèm. các pác giúp với.

Trong Class Module:

Option Explicit
Public WithEvents clsOpt As MSForms.OptionButton

Private Sub clsOpt_Change()
    If clsOpt Then
        UserForm1("tbx" & Mid(clsOpt.Name, 4, 2)) = clsOpt.Caption
    End If
End Sub

Trong UserForm:

Option Explicit
Private pri_OptBttn(1 To 60) As New EventClass


Private Sub UserForm_Initialize()
    Dim opt
    Dim n As Byte
    For Each opt In Me.Controls
        If TypeName(opt) = "OptionButton" Then
            n = n + 1
            Set pri_OptBttn(n).clsOpt = opt
        End If
    Next
    MultiPage1.Value = 0
End Sub


Private Sub cmdXoa_Click()
    Dim OptOrTbx
    For Each OptOrTbx In Me.Controls
        If TypeName(OptOrTbx) = "OptionButton" Then
            OptOrTbx.Value = False
        ElseIf TypeName(OptOrTbx) = "TextBox" Then
            OptOrTbx.Text = ""
        End If
    Next
    MultiPage1.Value = 0
    tbx11.SetFocus
End Sub


Private Sub cmdNhap_Click()
    Dim c As Byte, r As Byte
    Dim Rng As Range
    For r = 1 To 5
        Set Rng = Sheets("Sheet2").Range("A" & Rows.Count).End(xlUp).Offset(1)
        Rng = "Page " & r
        For c = 1 To 4
            Rng.Offset(, c) = Me("tbx" & r & c).Value
        Next
    Next
End Sub


Private Sub cmdNhapXoa_Click()
    cmdNhap_Click
    cmdXoa_Click
End Sub

 

[chua123]

Em cám ơn các Pác nhiều lắm lắm.