Dùng tham chiếu 3D (1 người xem)

[thangbithu]

Nhờ anh chị em giúp đỡ:

Mình có số liệu từng tháng trong 6 sheet VTHT0115 - VTHT0615, mình muốn tổng hợp số liệu 6 tháng tương ứng với từng sản phẩm (dòng) và loại vật tư (cột) tại sheet KQ01. Mình đính kèm file, mình muốn mọi người chỉ giúp:

1/ Công thức tại KQ01!D7 sai chỗ nào? mình chép công thức ra đây luôn
KQ01!D7= SUM(INDIRECT("VTHT0115:VTHT0615!"&ADDRESS(MATCH($B7;$B$1:$B$312;0)-1;MATCH(D$5;$A$3:$HT$3;0)+1)))

2/ Có công cụ nào khác (không dùng hàm) để xử lý việc này không?

3/ Nếu dùng code thì như thế nào?

Cảm ơn Anh Chị Em trước

 

[ndu96081631]

Nhờ anh chị em giúp đỡ:

Mình có số liệu từng tháng trong 6 sheet VTHT0115 - VTHT0615, mình muốn tổng hợp số liệu 6 tháng tương ứng với từng sản phẩm (dòng) và loại vật tư (cột) tại sheet KQ01. Mình đính kèm file, mình muốn mọi người chỉ giúp:

1/ Công thức tại KQ01!D7 sai chỗ nào? mình chép công thức ra đây luôn
KQ01!D7= SUM(INDIRECT("VTHT0115:VTHT0615!"&ADDRESS(MATCH($B7;$B$1:$B$312;0)-1;MATCH(D$5;$A$3:$HT$3;0)+1)))

2/ Có công cụ nào khác (không dùng hàm) để xử lý việc này không?

3/ Nếu dùng code thì như thế nào?

Cảm ơn Anh Chị Em trước

SUMIF nhiều sheet vậy không đúng rồi
KQ01!D7 phải có công thức:

=SUMPRODUCT(SUMIF(INDIRECT("'"&"VTHT0"&ROW($1:$6)&"15'!B6:B312"),$B7,INDIRECT("'"&"VTHT0"&ROW($1:$6)&"15'![COLOR=#ff0000]D6:D312[/COLOR]")))

Cái chỗ màu đỏ là vùng Sum_Range, nếu kéo fill sang phải thì sửa lại hoặc làm sao đó cho đúng
--------------------
Tuy nhiên, nhận thấy 6 sheet con có cấu trúc giống nhau, vậy tại sao không đơn giản hóa vấn đề bằng công thức này:

=SUM(VTHT0115:VTHT0615!D6)

 

[thangbithu]

Dạ, vấn đề là muốn công thức chạy tự động theo tiêu đề cột, chứ không thì phải sửa địa chỉ trong công thức rất nhiều

 

[ndu96081631]

Dạ, vấn đề là muốn công thức chạy tự động theo tiêu đề cột, chứ không thì phải sửa địa chỉ trong công thức rất nhiều

Bởi vậy tôi mới tô đỏ đó! Chỗ đó để Thắng tự suy nghĩ sao cho nó "tự động" đấy
Riêng công thức thứ 2 thì quá tự động rồi còn gì (chỉ có yêu cầu là 6 sheet con phải có cấu trúc y chang nhau)
--------------------------
Ngoài lề: File của Thắng còn nặng lắm nha! Dữ liệu có bao nhiêu đâu mà lên đến 4 MB. Nếu kéo "quét dọn", chỉ còn khoảng 1MB mà thôi

 

[thangbithu]

Bởi vậy tôi mới tô đỏ đó! Chỗ đó để Thắng tự suy nghĩ sao cho nó "tự động" đấy
Riêng công thức thứ 2 thì quá tự động rồi còn gì (chỉ có yêu cầu là 6 sheet con phải có cấu trúc y chang nhau)
--------------------------
Ngoài lề: File của Thắng còn nặng lắm nha! Dữ liệu có bao nhiêu đâu mà lên đến 4 MB. Nếu kéo "quét dọn", chỉ còn khoảng 1MB mà thôi

Dạ, em cảm ơn Anh ndu, em cho nó chạy theo cột được rồi, công thức dưới đây:
SUMPRODUCT(SUMIF(INDIRECT("'VTHT0"&ROW($1:$6)&"15'!B6:B312");$B7;INDIRECT("'VTHT0"&ROW($1:$6)&"15'!"&ADDRESS(6;MATCH(D$3;VTHT0615!$A$3:$HT$3;0))&":"&ADDRESS(312;MATCH(D$3;VTHT0615!$A$3:$HT$3;0)))))

Em có chỉnh một chút trong công thức của anh, đoạn này:
INDIRECT("'"&"VTHT0"&... thành INDIRECT("'VTHT0"&..., em thấy nó chạy bình thường
Hình như anh muốn kiểm tra em phải không? em cảm ơn anh nhiều nha
Còn file nặng thì em chịu, không biết tại sao, anh chỉ giúp em với : làm sao cho nó nhẹ bowst đi. Hi hi

 

[ndu96081631]

Còn file nặng thì em chịu, không biết tại sao, anh chỉ giúp em với : làm sao cho nó nhẹ bowst đi. Hi hi

Cách nhanh gọn nhất là: Save As file theo định dạng XLSB ---> Thử xem để thấy sự khác biệt