code mở phim wmv

[lephuonganh]

Em có đường dẫn tới phim wmv. Sau này các đường dẫn sẽ được lấy từ danh sách.
Trên sheet có hai nút. Nếu bấm nút play thì phim sẽ được chiếu. Ở đâu cũng được chỉ cần có phim để xem. Nếu bấm nút close thì phim sẽ được tắt.
Anh chị giúp em với nhé

 

[ndu96081631]

Em có đường dẫn tới phim wmv. Sau này các đường dẫn sẽ được lấy từ danh sách.
Trên sheet có hai nút. Nếu bấm nút play thì phim sẽ được chiếu. Ở đâu cũng được chỉ cần có phim để xem. Nếu bấm nút close thì phim sẽ được tắt.
Anh chị giúp em với nhé

Chèn Windows Media Player vào là chơi mát trời thôi!
Tham khảo bài này:
http://www.giaiphapexcel.com/forum/showthread.php?49503-Xem-nhạc-video-trong-file-Excel

 

[siwtom]

Em có đường dẫn tới phim wmv. Sau này các đường dẫn sẽ được lấy từ danh sách.
Trên sheet có hai nút. Nếu bấm nút play thì phim sẽ được chiếu. Ở đâu cũng được chỉ cần có phim để xem. Nếu bấm nút close thì phim sẽ được tắt.
Anh chị giúp em với nhé

Bạn có thể nhúng control có sẵn như bạn ndu hướng dẫn. Nếu bạn lập trình trong Delphi thì bạn có control TMediaPlayer, chỉ cần chọn trên thanh công cụ và "thả" xuống Form.
Nếu bạn muốn "phá cách" hoặc sợ bạn gái chê là chỉ biết dùng "đồ có sẵn" thì bạn thử làm như sau. Code tôi viết qua thôi. Hiện tôi mới cho các định dạng AVI, WMV, MPG, MP3, WAV, MID. Bạn thử các dạng khác xem. Tất nhiên đây không phải máy phát vạn năng, vì làm gì có chuyện kiếm tiền dễ và ít công sức như thế.
Code module mciSendCommand:

Public Const AliasName = "[COLOR=#ff0000]nang_tien_mong_minh_mat_nau[/COLOR]"

Private Declare Function mciSendString Lib "winmm.dll" Alias "mciSendStringA" _
    (ByVal lpstrCommand As String, ByVal lpstrReturnString As String, _
    ByVal uReturnLength As Long, ByVal hwndCallback As Long) As Long

Sub PlayMedia(FileName As String, windowWnd)
[COLOR=#0000ff]'    mở device. Ta gán cho device một cái tên để về sau dùng tên đó trong các thao tác như 
'     pause, close v...v thì system mới biết được ta định thao tác với device nào[/COLOR]
    mciSendString "open """ & FileName & """ alias " & AliasName, vbNullString, 0, 0
[COLOR=#0000ff]'    thiết lập "màn hình"[/COLOR]
    mciSendString "window " & AliasName & " handle " & CStr(windowWnd), vbNullString, 0, 0
[COLOR=#0000ff]'    cuộn lên đầu
[/COLOR]    mciSendString "seek " & AliasName & " to start", vbNullString, 0, 0
[COLOR=#0000ff]'    chiếu phim[/COLOR]
    mciSendString "play " & AliasName & " notify", vbNullString, 0, windowWnd
End Sub

Sub PauseMedia()
    mciSendString "pause " & AliasName, vbNullString, 0, 0
End Sub

Sub ResumeMedia()
    mciSendString "resume " & AliasName, vbNullString, 0, 0
End Sub

Sub StepMedia()
    mciSendString "step " & AliasName, vbNullString, 0, 0
End Sub

Sub StopMedia()
    mciSendString "stop " & AliasName, vbNullString, 0, 0
End Sub

Sub CloseMedia()
    If mciSendString("stop " & AliasName, vbNullString, 0, 0) = 0 Then
[COLOR=#0000ff]'       đóng device[/COLOR]
        mciSendString "close " & AliasName, vbNullString, 0, 0
    End If
End Sub

Code UserForm1:

Dim wnd As Long

Private Sub btnClose_Click()
    CloseMedia
End Sub

Private Sub btnCloseForm_Click()
    Unload Me
End Sub

Private Sub btnOpenFile_Click()
Dim fname
    fname = Application.GetOpenFilename("Video Files (*.avi; *.wmv;*.mpg),*.avi;*.wmv;*.mpg," & _
                    "Audio Files (*.mp3;*.wav;*.mid),*.mp3;*.wav;*.mid")
    If fname <> False Then
        Label1.Caption = fname
        CloseMedia
        btnPlay_Click
    End If
End Sub

Private Sub btnPause_Click()
    PauseMedia
End Sub

Private Sub btnPlay_Click()
    If Label1.Caption <> "" Then
        PlayMedia Label1.Caption, wnd
    End If
End Sub

Private Sub btnResume_Click()
    ResumeMedia
End Sub

Private Sub btnStep_Click()
    StepMedia
End Sub

Private Sub btnStop_Click()
    StopMedia
End Sub

Private Sub UserForm_Initialize()
    wnd = Application.Hwnd
End Sub

Private Sub UserForm_Terminate()
    CloseMedia
End Sub

Hiện tôi chiếu phim trực tiếp lên cửa sổ của Application. Tất nhiên có thể tạo cửa sổ và chiếu phim trong cửa sổ đó (thay Application.Hwnd bằng handle - "cán" của cửa sổ đó)

Có thể dùng mciSendString để thu audio (microphone) rồi ghi lại trên đĩa ở dạng WAV.