Công thức tham chiếu đến dòng cuối cùng có dữ liệu (1 người xem)

[790312]

Nhờ các bác giúp giùm e.Nội dung e ghi trong file đính kèm.Thanks.

 

[vu_tuan_manh_linh]

Công thức của bạn đây
F53=INDIRECT("I"&COUNTA(D1852)+17)+INDIRECT("D"&COUNTA(D1852)+17)/2*INDIRECT("H"&COUNTA(D1852)+17)
Giải thích công thức: Mấu chốt trong công thức của bạn là chỉ số dòng tương ứng với dòng dữ liệu cuối của cột D. Công thức COUNTA(D1852)+17 sẽ cho ra kết quả đó. Hàm indirect() giúp nối chỉ số cột với chỉ số dòng thành địa chỉ tham chiếu có nghĩa.

 

[ndu96081631]

Nhờ các bác giúp giùm e.Nội dung e ghi trong file đính kèm.Thanks.

Vầy chắc là được:

=LOOKUP(10^15,I18:I52)+LOOKUP(10^15,D18:D52)/2*LOOKUP(10^15,H18:H52)

Và còn hàng đống cách khác nữa

 

[siwtom]

Nhờ các bác giúp giùm e.Nội dung e ghi trong file đính kèm.Thanks.

Ý của bạn là: giả sử dòng cuối cùng có dữ liệu trong cột D là 23, trong cột H và I là 32 thì F53 = I23 + D23/2 * H23???

Nếu thế thì một trong các cách

=INDEX(I18:I52+D18:D52/2*H18:H52;LOOKUP(2;1/ISNUMBER(D18:D52);ROW(1:35)))

Công thức trên có những tính toán không cần thiết khi tạo mảng tạm thời - tính cho tất cả các dòng.

Công thức tốt hơn là

=INDEX(I18:I52;LOOKUP(2;1/ISNUMBER(D18:D52);ROW(1:35)))+INDEX(D18:D52;LOOKUP(2;1/ISNUMBER(D18:D52);ROW(1:35)))/2*INDEX(H18:H52;LOOKUP(2;1/ISNUMBER(D18:D52);ROW(1:35)))

Nhưng khi tính công thức thì LOOKUP(2;1/ISNUMBER(D1852);ROW(1:35)) được tính 3 lần.
Để đơn giản công thức và chỉ tính 1 lần LOOKUP(2;1/ISNUMBER(D1852);ROW(1:35)) thì đặt name pos

=LOOKUP(2;1/ISNUMBER($D$18:$D$52);ROW($1:$35))

Và công thức cho F53

=INDEX(I18:I52;pos)+INDEX(D18:D52;pos)/2*INDEX(H18:H52;pos)

 

[790312]

Vầy chắc là được:

=LOOKUP(10^15,I18:I52)+LOOKUP(10^15,D18:D52)/2*LOOKUP(10^15,H18:H52)

Và còn hàng đống cách khác nữa

Khi sử dụng công thức của bác nếu D32 trống thì kết quả là 27.254 còn e tính lại theo e là 25.2 bác ah.Mong bác xem lại giúp e.Thanks.

 

[Phuocam]

Khi sử dụng công thức của bác nếu D32 trống thì kết quả là 27.254 còn e tính lại theo e là 25.2 bác ah.Mong bác xem lại giúp e.Thanks.

Xem thử công thức này đúng ý bạn không?
=LOOKUP(10^15,D1852,I18:I52)+LOOKUP(10^15,D1852)/2*LOOKUP(10^15,D1852,H18:H52)

 

[790312]

Cảm ơn các bác đã giúp đỡ.

 

[Tóc gió thôi bay]

khi sử dụng công thức của bác nếu d32 trống thì kết quả là 27.254 còn e tính lại theo e là 25.2 bác ah.mong bác xem lại giúp e.thanks.

=lookup(1,1/(d18:d52<>""),i18:i52+d18:d52/2*h18:h52)

ok?

 

[790312]

Cũng trong bài toán này,cách thức hơi khác tí,mong các bác giúp e.Yêu cầu e gửi trong file đính kèm.

 

[ndu96081631]

Cũng trong bài toán này,cách thức hơi khác tí,mong các bác giúp e.Yêu cầu e gửi trong file đính kèm.

Thử công thức này xem:

=MIN(N(OFFSET(D18,MATCH(10^15,D18:D52)-1,{1,3})))