Cách chấm công theo điều kiện
- Thread starter Tandattb
- Ngày gửi
Phan Thế Hiệp
-⍟-
- Tham gia
- 10/10/17
- Bài viết
- 3,380
- Được thích
- 11,240
- Giới tính
- Nam
Tiêu đề "mọi người giúp em tìm hàm phù hợp với ạ" quá chung chung nên vi phạm Nội Quy Diễn đàn.
Bạn có thể điều chỉnh lại theo tiêu đề như sau "Tính công theo điều kiện"
Thân.
Tandattb
Thành viên mới
- Tham gia
- 9/10/18
- Bài viết
- 45
- Được thích
- 9
- Donate (Momo)
- Giới tính
- Nam
ồ. em mới tham gia diễn đàn nên chưa hiểu lắm. Cám ơn anh.
Lê Hồng Minh83
Thành viên tiêu biểu
- Tham gia
- 29/9/17
- Bài viết
- 587
- Được thích
- 649
- Giới tính
- Nam
Đôi lời góp ý cho bạn:
1, Tại sao không sử dụng trực tiếp giờ công là 8, 12, 16 cho sheet đầu luôn mà phải chuyển qua công dạng 1.5n, 2n gì để phức tạp tình hình thêm
2, Nếu bạn bị ép buộc sử dụng kiểu chấm công như thế này thì trường hợp người ta làm có 4 giờ hoặc 6 giờ trong ngày vì có việc riêng thì chấm công kiểu gì (0.5n, 0.75n?)
Nếu bạn đi theo hướng 1 thì chắc quá dễ cho bạn rồi, còn nếu bạn vẫn đi theo hướng của bạn thì ta tính tiếp
Tandattb
Thành viên mới
- Tham gia
- 9/10/18
- Bài viết
- 45
- Được thích
- 9
- Donate (Momo)
- Giới tính
- Nam
hi anh Minh.
Bên em không thể áp dụng chấm công là 8,12,16h được anh ạ, vì bên em có nhiều ký hiệu thể hiện các công việc khác nhau, công "n" chỉ thể hiện1 loại công việc thôi. Và chỉ công "n" (như trong bảng chấm công của em) khi người lao động làm thêm giờ mới được cộng thêm 4h hoặc 8h.
Anh có thể giúp em công thức thực hiện yêu cầu trên không ạ.
Lê Hồng Minh83
Thành viên tiêu biểu
- Tham gia
- 29/9/17
- Bài viết
- 587
- Được thích
- 649
- Giới tính
- Nam
Vậy thì làm theo cách của bạn (nhưng vẫn thắc mắc là tại sao không đi theo hướng 1
, thay vì chữ n mới được tính tăng ca kiểu này thì cho nó thêm 1 cột ký hiệu riêng, nếu có chữ n trên dòng đó thì người đó được tính tăng ca kiểu này)
Mã:
C4=IFERROR(SUBSTITUTE('công SX T10'!C4,"n","")*8-8,"")Tandattb
Thành viên mới
- Tham gia
- 9/10/18
- Bài viết
- 45
- Được thích
- 9
- Donate (Momo)
- Giới tính
- Nam
Vậy thì làm theo cách của bạn (nhưng vẫn thắc mắc là tại sao không đi theo hướng 1
Bạn tham khảo fileMã:C4=IFERROR(SUBSTITUTE('công SX T10'!C4,"n","")*8-8,"")
oh. Em cám ơn anh Minh nhé.
anh ơi. Em hỏi chút nữa ạ.
Giờ sếp em lại bảo thêm 1 loại công nữa cũng tính thêm giờ như vậy, nhưng không được để ký hiệu "n" mà để ký hiệu là "v". để cuối tháng bình xét 2 loại công.
E tính tách thành 2 bảng công rồi dùng công thức của anh, nhưng sếp không muốn tách 2 bảng công mà chỉ dùng 1 bảng. Vậy công thức trên phải sửa lại như thế nào để chấm 2 loại công này vẫn ra được thêm giờ như vậy ạ
Bài đã được tự động gộp:
Vậy thì làm theo cách của bạn (nhưng vẫn thắc mắc là tại sao không đi theo hướng 1
anh nói cách này, nhưng em chưa hình dung ra được anh ạ. Hi
Lê Hồng Minh83
Thành viên tiêu biểu
- Tham gia
- 29/9/17
- Bài viết
- 587
- Được thích
- 649
- Giới tính
- Nam
Nếu cách tính cho công loại n và v giống nhau thì
Mã:
C4=IFERROR(IFERROR(SUBSTITUTE('công SX T10'!C4,"n","")*8-8,SUBSTITUTE('công SX T10'!C4,"v","")*8-8),"")Tandattb
Thành viên mới
- Tham gia
- 9/10/18
- Bài viết
- 45
- Được thích
- 9
- Donate (Momo)
- Giới tính
- Nam
em cám ơn anh Minh nhiều ạ.
Em mới làm về mảng này, nên tính toán trên cel còn chậm và chưa hiểu lắm. Chỉ biết các công thức đơn giản. các hàm kết hợp cũng không hiểu nhiều.
Thực tế là công thức anh cho, em cũng không hiểu gì, chỉ áp dụng máy móc thôi, nhưng vậy cũng đỡ mệt hơn nhiều rồi
Em cám ơn!
Lần chỉnh sửa cuối:
Lê Hồng Minh83
Thành viên tiêu biểu
- Tham gia
- 29/9/17
- Bài viết
- 587
- Được thích
- 649
- Giới tính
- Nam
Có gì đâu khó hiểu. Hàm SUBSTITUTE làm nhiệm vụ thay thế những chữ n, v nếu xuất hiện bằng tập hợp rỗng, chỉ còn lại con số để thực hiện phép tính nhân chia cộng trừ thôi. Và đương nhiên những ô không có chữ n, v sẽ bị lỗi và hàm IFERROR làm nhiệm vụ bẫy lỗi thôiem cám ơn anh Minh nhiều ạ.
Em mới làm về mảng này, nên tính toán trên cel còn chậm và chưa hiểu lắm. Chỉ biết các công thức đơn giản. các hàm kết hợp cũng không hiểu nhiều.
Thực tế là công thức anh cho, em cũng không hiểu gì, chỉ áp dụng máy móc thôi, nhưng vậy cũng đỡ mệt hơn nhiều rồi
Em cám ơn!
Tandattb
Thành viên mới
- Tham gia
- 9/10/18
- Bài viết
- 45
- Được thích
- 9
- Donate (Momo)
- Giới tính
- Nam
Có gì đâu khó hiểu. Hàm SUBSTITUTE làm nhiệm vụ thay thế những chữ n, v nếu xuất hiện bằng tập hợp rỗng, chỉ còn lại con số để thực hiện phép tính nhân chia cộng trừ thôi. Và đương nhiên những ô không có chữ n, v sẽ bị lỗi và hàm IFERROR làm nhiệm vụ bẫy lỗi thôi
ah, em hiểu rồi anh, hóa ra loại n,v còn lại 1,5 hoặc 2 sau đó *8-8, là ra kết quả mong muốn.
hi. E cám ơn anh nhé
Phuocam
Thành viên mới
- Tham gia
- 16/5/13
- Bài viết
- 4,537
- Được thích
- 7,309
1. Có thể dùng công thức này trong C4 sheets 12H:
=IFERROR(SUBSTITUTE(SUBSTITUTE('công SX T10'!C4,"n",""),"v","")*8-8,"")
2. Có thể dùng công thức mảng này trong AH4 sheets Công SX T10:
=COUNTIF(C4:AG4,"n")+COUNTIF(C4:AG4,"v")+SUM(IFERROR(--SUBSTITUTE(SUBSTITUTE(C4:AG4,"n",""),"v",""),0))
Công thức thứ 2 nhớ kết thúc bằng Ctrl+Shift+Enter.
Tandattb
Thành viên mới
- Tham gia
- 9/10/18
- Bài viết
- 45
- Được thích
- 9
- Donate (Momo)
- Giới tính
- Nam
oh, Em cám ơn, nhưng trong bảng công SX T10 của em có thêm các ký hiệu công khác ví dụ như x, 2x, x/2, 1.5x, sc, sc/2, 1.5sc, 2sc thì phải làm thế nào hả anh. vì em cần tự động thêm giờ cho sheet 12h nên em rút gọn bảng cho đỡ rối mắt, chỉ đển công ký hiệu v hoặc n thôi.
Nói chung công bên công ty em khá phứctạp. hi.
Phuocam
Thành viên mới
- Tham gia
- 16/5/13
- Bài viết
- 4,537
- Được thích
- 7,309
1. Dùng tìm và thay thế x/2 về dạng 0.5x , sc/2 về 0.5sc mới sử lý được
2. Dùng hàm SUBSTITUTE thay thế, ưu tiên những ký tự có chiều dài chuỗi lớn trước , nhỏ sau như:
SUBSTITUTE(SUBSTITUTE('công SX T10'!C4,"sc",""),"s","")
Tandattb
Thành viên mới
- Tham gia
- 9/10/18
- Bài viết
- 45
- Được thích
- 9
- Donate (Momo)
- Giới tính
- Nam
Bảng công đầy đủ công ty em nó như file đính kèm dưới đây anh ạ.
Phức tạp quá, em chỉ biết dùng hàm COUNIF nên hơi dài, mà mỗi lần thêm 1 loại công là lại phải +thêm CounIf
Phan Thế Hiệp
-⍟-
- Tham gia
- 10/10/17
- Bài viết
- 3,380
- Được thích
- 11,240
- Giới tính
- Nam
Góp sức với bạn hiền tôi, và làm gọn công thức cho bạn:
Sheet "Cong SX T9":
Mã:
AI6=SUM(COUNTIF(D6:AH6,{"x/2*","x","x;*","1.5x","2x"})*{0.5,1,1,1.5,2})Bạn tìm hiểu công thức trên rồi áp dụng cho các cột AK; AL
Thân
Tandattb
Thành viên mới
- Tham gia
- 9/10/18
- Bài viết
- 45
- Được thích
- 9
- Donate (Momo)
- Giới tính
- Nam
Wow. Rất hay. Em cám ơn anh Hiệp nhé. Gọn hơn rất là nhiều ạ.
Anh có thể giải thích giúp em công thức để em hiểu hơn không ạ. Em mới làm nên cũng chưa hiểu lắm ạ.
Vì sao "x/2*" và vì sao "x;*". Hai cái gần giống nhau nhưng cái thì không cần ";" cái thì phải cần ";" ạ
Lần chỉnh sửa cuối:
Phan Thế Hiệp
-⍟-
- Tham gia
- 10/10/17
- Bài viết
- 3,380
- Được thích
- 11,240
- Giới tính
- Nam
Phân tích:
Công thức của bạn như sau:
=COUNTIF(D6:AH6,"x")+COUNTIF(D6:AH6,"x/2")*0.5+COUNTIF(D6:AH6,"1.5x")*1.5+COUNTIF(D6:AH6,"x;T")+COUNTIF(D6:AH6,"x;v")+COUNTIF(D6:AH6,"x;n")+COUNTIF(D6:AH6,"2x")*2+COUNTIF(D6:AH6,"x/2;T")*0.5+COUNTIF(D6:AH6,"x/2;v")*0.5+COUNTIF(D6:AH6,"x/2;n")*0.5+COUNTIF(D6:AH6,"x/2;T/2")*0.5+COUNTIF(D6:AH6,"x/2;v/2")*0.5+COUNTIF(D6:AH6,"x/2;n/2")*0.5+COUNTIF(D6:AH6,"x/2;1.5T")*0.5+COUNTIF(D6:AH6,"x/2*1.5v")*0.5+COUNTIF(D6:AH6,"x/2;1.5n")*0.5
Có thể thấy rằng:- Nhóm được tính là 0.5, gồm: COUNTIF(D6:AH6,"x/2")*0.5; COUNTIF(D6:AH6,"x/2;T")*0.5; COUNTIF(D6:AH6,"x/2;v")*0.5; COUNTIF(D6:AH6,"x/2;n")*0.5; COUNTIF(D6:AH6,"x/2;T/2")*0.5; COUNTIF(D6:AH6,"x/2;v/2")*0.5; COUNTIF(D6:AH6,"x/2;n/2")*0.5; COUNTIF(D6:AH6,"x/2;1.5T")*0.5; COUNTIF(D6:AH6,"x/2*1.5v")*0.5; COUNTIF(D6:AH6,"x/2;1.5n")*0.5. Nó có cấu trúc lệnh giống nhau chỗ COUNTIF(D6:AH6,"x/2.....")*0.5, hiểu rằng bạn chỉ xét 'đặc biệt' cho các trường hợp có ký tự là x/2 mà thôi, nên toàn bộ phía sau nó bạn có thể dùng ký tự đại diện là được rồi "x/2*"
- Nhóm được tính là 1, gồm: COUNTIF(D6:AH6,"x"); COUNTIF(D6:AH6,"x;T"); COUNTIF(D6:AH6,"x;v"); COUNTIF(D6:AH6,"x;n"), tức bạn chỉ xét các trường hợp 'đặc biệt cho ký tự "x" đơn lẻ và có kết hợp các ký tự phía sau, cũng giống như trên, hễ nó ghép thì bạn dùng ký tự đại diện là được, nên nhớ "x"<>"x;*" (x có dấu ";" liền sau). Nếu bạn dùng chỉ "x*" thì nó sẽ đếm tất tần tật các ký tự ở nhóm 0.5 phía trên và ra kết quả "không mong đợi", riêng "x;*" sẽ hoàn toàn khác hẵn với "x/2*". Vì thế, phải dùng tách biệt cả hai ký tự "x" và "x;*" thì mới phân biệt được với nhóm tính là 0.5 ở trên.
- Hai trường hợp còn lại được tính là 1.5 và 2 thì đơn giản hơn.
- Dùng COUNTIF('Vùng so', 'Mảng so') sẽ tạo ra 1 Mảng sẽ có độ dài và chiều giống hoàn toàn như 'Mảng so', như trên bạn gom các ký tự cần tìm gộp vào chung 1 mảng chiều ngang như sau: {"x/2*","x","x;*","1.5x","2x"}, thì khi Countif() thực hiện nó sẽ trả ra kết quả, ví dụ đại khái là {0,3,20,2,0}, tức kết quả của các dạng ký tự:
- "x/2*" =0
- "x"=3
- "x;*"=20
- "1.5x"=2
- "2x"=0
- Công thức còn lại là: SUM( COUNTIF(D6:AH6,{"x/2*","x","x;*","1.5x","2x"}) * {0.5,1,1,1.5,2} ). Mảng {0.5,1,1,1.5,2} là các số nhân tương ứng với vị trí của Mảng ký tự cần tìm, ví dụ ứng với "x/2" bạn muốn nhân với 0.5, ứng với "2x" bạn muốn nhân với 2...
- =>SUM( {0,3,20,2,0} * {0.5,1,1,1.5,2} )
- =>SUM( {0,3,20,3,0})=26
Cứ nghiên cứu đi, hễ khó quá thì tính tiếp, nhưng tôi nghĩ sau khi hiểu rõ cách dùng ký tự đại diện rồi, thì bạn sẽ tự mình làm được.
Thân
Lần chỉnh sửa cuối:
Tandattb
Thành viên mới
- Tham gia
- 9/10/18
- Bài viết
- 45
- Được thích
- 9
- Donate (Momo)
- Giới tính
- Nam
Oh, em hiểu rồi anh Hiệp ơi.
em đã làm được rồi anh nhé.
Cám ơn anh rất nhiều ạ
Bài viết mới nhất
- Question
