Các câu hỏi về Hàm Index và Match (1 người xem)

[dat_butmuc]

<br>Hy vọng mọi ngưòi chỉ cho em cách giải bài này bàng hàm Index và match để em hiểu hơn về hàm này, cách sử dụng em còn mông lung chưa biết sử lý cũng như vận dụng trong những trường hợp khác nhau. trường hợp này rất mong được giải đáp

Index & Match thì đây:

=INDEX($C$14:$E$14,,MATCH(LEFT(B2),$C$12:$E$12,))

Trong trường hợp này nó tương đương với:

=HLOOKUP(LEFT(B2),$C$12:$E$14,3,)

 

[thehungqnu]

Các Pác chỉ giùm em bài tạp sau với!
thanks!View attachment 3293

Trong excel có Lookup Wizard dùng kết hợp giữa match và index Bạn tham khảo thêm, chúc vui!

 

[lethuyduong_92]

anh chị giúp em làm câu 4 và 9 bài này với: View attachment bt.xls

 

[lethuyduong_92]

giúp em làm thêm câu 3 bài này nữa:View attachment bt2.xls

 

[dat_butmuc]

anh chị giúp em làm câu 4 và 9 bài này với: View attachment 56566

- Câu 4:

=SUM(OFFSET($N$23:$P$23,MATCH(LEFT(A5),$M$24:$M$27,),))*0.075

hoặc

=SUMPRODUCT(($M$24:$M$27=LEFT(A5))*$N$24:$P$27)*0.075

- Câu 9:

=SUMIF($B$5:$B$16,LOOKUP($A32,$M$6:$P$7)&" "&B$31,$E$5:$E$16)

 

[1onggiabienca]

Rất cảm ơn Anh (chị) đã giúp em hiểu được thêm phần nữa vê hàm này. Thank! Hiện nay thì em đã có thể làm được bài này rồi.

 

[PIT]

Các bác ơi mình có bạn chỉ cho mình công thức này mà mình muốn hiểu bản chất của công thức đó,

CÁc bác giải thích giúp em được không ah, em hỏi bác ý mà hình như bác ý đang bận không trả lời được mà mình đang cần gấp quá.

Cám ơn các bạn.

=OFFSET(M3,MATCH($G$3,$L$3:$L$100,)+ROWS($1:1)-1,)

Cột M3 = Tên công ty
Cột G3 là thông tin về tên công ty
Cột L3 là tên của nhiều tên công ty.

Mục đích của mình là khi có tên 1 công ty nào đó tự động các thông tin khác của công ty đó sẽ hiện ra, các bác xem giúp em file này.

 

[junior_pear]

mọi ng giúp mình bài index vs match này vs.

 

[nghiaphuc]

Tiếc chi mà gõ tiết kiệm dữ vậy bạn?

mọi ng giúp mình bài index vs match này vs.

Đây là công thức cho ô J3:

=INDEX($C$17:$E$20,MATCH(H3,$B$17:$B$20,0),MATCH(I3&"*",$C$16:$E$16,1))

Ủa, nhìn lại thấy bài giải ở Sheet thứ 3 đó bạn kìa.

 

[1onggiabienca]

Giúp em bài tập này với

Anh (chị) hãy giiups em làm bài này với nhé

 

[MinhCong]

Anh (chị) hãy giiups em làm bài này với nhé

1/Sử dụng validation: Chỉ số cũ -> Quét chọn từ ô D211 -> Data -> Validation. Trong thẻ setting -> Trong Allow -> Chọn whole number -> Ô Data chọn between -> Ô Minimum chọn 0 và maximum chọn 150. (Tương tự cho chỉ số mới)
2/Câu 2

F2 =INDEX($B$16:$I$21;MATCH(RIGHT(C2;3);$B$16:$B$21;0);MATCH(MID(C2;2;3);$B$16:$I$16;0))

G2 =MAX(E2-D2-F2;0)

H2 =INDEX($B$24:$G$29;MATCH(MID(C2;3;2);$B$24:$B$29;0);MATCH(RIGHT(C2;3);$B$24:$G$24;0))

Tiền vượt định mức (Hình như Bạn đưa thiếu dữ liệu về phần này)
3/Câu 3
a/Số hộ sử dụng tiền vượt định mức

=COUNTIF($G$2:$G$11;[COLOR=red]">0"[/COLOR])

b/Tổng số tiền phải trả của các hộ sử dụng điện vượt mức

=SUMIF(G2:G11;[COLOR=red]">0"[/COLOR];J2:J11)

2 câu còn lại tương tự câu trên nhưng chỉ thay đổi lại điều kiện chữ màu đỏ (Tự Bạn suy luận nhé)!

 

[tvquan41]

Hàm Index và Match ???

Chào gia đình GPE!
Mình có một câu hỏi cho bài tập sau khi dùng hàm Index và Match!
Câu hỏi được trình bày trong file đính kèm! Mong anh/chị giúp đỡ!

 

[nghiaphuc]

Chào gia đình GPE!
Mình có một câu hỏi cho bài tập sau khi dùng hàm Index và Match!
Câu hỏi được trình bày trong file đính kèm! Mong anh/chị giúp đỡ!

Bạn sửa lại công thức thành: =INDEX($B$3:$C$4,MATCH(C7,$A$3:$A$4,1),MATCH(C6,$B$2:$C$2,1))
Ngoài ra, bạn sửa B2=0, C2=12 là được.

 

[nghiaphuc]

Thanks!
Trên cả tuyệt vời! Phải là 13 chứ nhỉ! ^^

Đúng rồi, mình nhầm. Chính xác là như vậy. Nếu không thì nhập 12 ra bb mất.

 

[xyzt]

Cần giúp về hàm INDEX và MATCH

Cô giáo cho lớp em bài tập này , cô gợi ý là dùng hàm INDEX kết hợp với MATCH để làm. Em ko làm được. AI giúp em với

 

[ndu96081631]

Cô giáo cho lớp em bài tập này , cô gợi ý là dùng hàm INDEX kết hợp với MATCH để làm. Em ko làm được. AI giúp em với

Dùng INDEX và MATCH thì sẽ vầy:

=INDEX($A$22:$C$25,MATCH(LEFT(B7),$A$22:$A$25,0),MATCH(1*RIGHT(B7),$A$22:$C$22,0))

Còn tôi thì thích dùng VLOOKUP hơn:

=VLOOKUP(LEFT(B7),$A$22:$C$25,RIGHT(B7)+1,0)

Cái nào gọn hơn?

 

[xyzt]

Dùng INDEX và MATCH thì sẽ vầy:

=INDEX($A$22:$C$25,MATCH(LEFT(B7),$A$22:$A$25,0),MATCH(1*RIGHT(B7),$A$22:$C$22,0))

Còn tôi thì thích dùng VLOOKUP hơn:

=VLOOKUP(LEFT(B7),$A$22:$C$25,RIGHT(B7)+1,0)

Cái nào gọn hơn?

cảm ơn bạn nhiều. bạn có thể chỉ rõ hơn trong câu lệnh 2, RIGHT(B7)+1 có nghĩa là gì vậy?

 

[nghiaphuc]

cảm ơn bạn nhiều. bạn có thể chỉ rõ hơn trong câu lệnh 2, RIGHT(B7)+1 có nghĩa là gì vậy?

Điều này dễ hiểu thôi mà: Bạn nhìn trong bảng tham chiếu, nếu ký tự cuối của mã hàng (RIGHT(B7)) là 1 thì đơn giá được lấy ở cột 2, nếu ký tự cuối của mã hàng là 2 thì đơn giá được lấy ở cột 3. Như vậy, tham số thứ 3 của VLOOKUP là RIGHT(B7)+1

 

[xyzt]

nếu thay đổi như file dưới thì làm thế nào đây?

 

[linhngoc]

nếu thay đổi

----Nếu thay đổi thì thay đổi chút xíu theo thôi bạn.

F7=INDEX($B$23:$D$25,MATCH(LEFT(B7),$A$23:$A$25,0),MATCH(RIGHT(B7),$B$22:$D$22,0))
Hoặc:

G7=OFFSET($B$23,MATCH(LEFT(B7),$A$23:$A$25,0)-1,MATCH(RIGHT(B7),$B$22:$D$22,0)-1)

H7=VLOOKUP(LEFT(B7),$A$23:$D$25,MATCH(RIGHT(B7),$B$22:$D$22,0)+1,)

I7=HLOOKUP(RIGHT(B7),$B$22:$D$25,MATCH(LEFT(B7),$A$23:$A$25,0)+1,)
-----

 

[Lê Duy Thương]

----Nếu thay đổi thì thay đổi chút xíu theo thôi bạn.

F7=INDEX($B$23:$D$25,MATCH(LEFT(B7),$A$23:$A$25,0),MATCH(RIGHT(B7),$B$22:$D$22,0))
Hoặc:

G7=OFFSET($B$23,MATCH(LEFT(B7),$A$23:$A$25,0)-1,MATCH(RIGHT(B7),$B$22:$D$22,0)-1)

H7=VLOOKUP(LEFT(B7),$A$23:$D$25,MATCH(RIGHT(B7),$B$22:$D$22,0)+1,)

I7=HLOOKUP(RIGHT(B7),$B$22:$D$25,MATCH(LEFT(B7),$A$23:$A$25,0)+1,)
-----

nếu dữ liệu chỉ như trong bảng 3 thì cái này cũng được

=VLOOKUP(LEFT(B7),$A$23:$D$25,CODE(RIGHT(B7))-63,0)

 

[xyzt]

----Nếu thay đổi thì thay đổi chút xíu theo thôi bạn.

F7=INDEX($B$23:$D$25,MATCH(LEFT(B7),$A$23:$A$25,0),MATCH(RIGHT(B7),$B$22:$D$22,0))
Hoặc:

G7=OFFSET($B$23,MATCH(LEFT(B7),$A$23:$A$25,0)-1,MATCH(RIGHT(B7),$B$22:$D$22,0)-1)

H7=VLOOKUP(LEFT(B7),$A$23:$D$25,MATCH(RIGHT(B7),$B$22:$D$22,0)+1,)

I7=HLOOKUP(RIGHT(B7),$B$22:$D$25,MATCH(LEFT(B7),$A$23:$A$25,0)+1,)
-----

sao minh dùng cách của bạn như bài này lại ko được? Giúp với

 

[duongdv]

Bạn xem trong file đính kèm đã được chưa!

 

[linhngoc]

sao minh dùng cách của bạn như bài này lại ko được?

-----Được mờ. Nhưng nói chung những bài như này thì bạn nên dùng vlookup hay hlookup thì CT ngắn hơn.
Thân!

 

[redhairpro]

Ai giúp em với

Bác nào tốt bụng làm ơn giúp em bài này với. Em ngồi cả tiếng mà ko làm đc cái hàm INDEX
Bài ở Sheet 9, cột đơn giá ý, làm thế nào cũng bị lỗi #N/A. Bực không chịu được
Cảm ơn nhìu!!!

 

[ndu96081631]

Bác nào tốt bụng làm ơn giúp em bài này với. Em ngồi cả tiếng mà ko làm đc cái hàm INDEX
Bài ở Sheet 9, cột đơn giá ý, làm thế nào cũng bị lỗi #N/A. Bực không chịu được
Cảm ơn nhìu!!!

Để ý chữ Sản xuất ở cell I16 có bấm Alt + Enter để xuống hàng... còn chữ Sản xuất ở cell H21 thì được gõ bình thường
Nói chung, bạn chỉ cần sửa sao cho dữ liệu ở I16:K16 giống y chang với dữ liệu tại H20:H22 là ổn

 

[redhairpro]

Sau khi sửa thì đã không bị lỗi nữa. Nhưng số liệu lại sai.
Ai giúp em hàm INDEX này với (

 

[Ba Tê]

Sau khi sửa thì đã không bị lỗi nữa. Nhưng số liệu lại sai.
Ai giúp em hàm INDEX này với (

Bạn dò lộn tùng phèo, hàng thành cột, cột thành hàng, cột 5 dòng, cột 4 dòng...
Làm dùm Bạn luôn đây.

 

[redhairpro]

Cảm ơn nhé, tui hiểu rùi.
Hóa ra hàm MATCH thì phải match cột trước rùi mới đến hàng ah. Từ lần sau rút kinh nghiệm
Cảm ơn 1 lần nữa!! Từ tối hôm qua tới h làm ko xong điên cả đầu

 

[ly19912181]

Giúp tìm lỗi cú pháp

Mình là bài này sử dụng index và match nhưng ko hiểu sao lại không ra được kết quả
mong mọi người giúp đỡ

 

[ndu96081631]

Sau khi sửa thì đã không bị lỗi nữa. Nhưng số liệu lại sai.
Ai giúp em hàm INDEX này với (

Chán bạn quá... Sao tôi sửa thì lại được nhỉ?
Nói thêm: Ngoài việc định dạng sai thì công thức của bạn còn sai nhiều chổ khác:
- Sai tham chiếu ở hàm MATCH ---> Hàm INDEX lấy trong vùng $H$19:$K$23 thì 2 hàm MATCH phải lấy tham chiếu tại $H$19:$H$23 và $H$19:$K$19 mới đúng
- Ngược thứ tự hàm MATCH ---> Dò theo dòng trước, cột sau

 

[dat_butmuc]

Mình là bài này sử dụng index và match nhưng ko hiểu sao lại không ra được kết quả
mong mọi người giúp đỡ

Lỗi ở đây là bạn chưa hiểu hết được nguyên lý của index & match nên thực hiện sai,
Làm lại cái này bằng:
- Tên vật tư:

=VLOOKUP(E4,$B$22:$H$29,RIGHT(D4)+1,)

- Đơn giá:

=INDEX($C$22:$H$29,MATCH(E4,$B$22:$B$29,)+1,RIGHT(D4))

hoặc:

=HLOOKUP(--RIGHT(D4),$C$21:$H$29,MATCH(E4,$B$21:$B$29,)+1,)

 

[ly19912181]

Ai có thể giải thích cho mình biết tại sao ở câu lệnh thứ nhất lại có 1*right(b7) mà ko phải right(b7),mình thử right(b7)thì quả thực không ra kết quả
thank

 

[ly19912181]

Dùng INDEX và MATCH thì sẽ vầy:

=INDEX($A$22:$C$25,MATCH(LEFT(B7),$A$22:$A$25,0),MATCH(1*RIGHT(B7),$A$22:$C$22,0))

Còn tôi thì thích dùng VLOOKUP hơn:

=VLOOKUP(LEFT(B7),$A$22:$C$25,RIGHT(B7)+1,0)

Cái nào gọn hơn?

Ai có thể giải thích cho mình biết tại sao ở câu lệnh thứ nhất lại có 1*right(b7) mà ko phải right(b7),mình thử right(b7)thì quả thực không ra kết quả
thank

 

[ndu96081631]

Ai có thể giải thích cho mình biết tại sao ở câu lệnh thứ nhất lại có 1*right(b7) mà ko phải right(b7),mình thử right(b7)thì quả thực không ra kết quả
thank

Vì các hàm xử lý chuổi như LEFT, RIGHT, MID.. cho dù có tách được số ra thì đó vẫn là Text, phải nhân thêm 1 hoặc cộng thêm 0 vào để biến TEXT thành NUMBER thật sư thì khi dùng hàm MATCH, nó dò số đó trong vùng $A$22:$C$22 nó mới tìm thấy

 

[vominhtri1977]

Xin giúp em về hàm index()

Xin các bác giúp em sử dụng hàm index() để dò tìm cự ly trong file em gửi kèm. Em chưa biết gì về hàm này nên mong các bác chỉ dẫn thêm cho em. Bác nào có ví dụ khác về cách kết hợp hàm này với các hàm khác thì cho em xin luôn để học hỏi thêm. En xin cám ơn các bác lắm lắm!!!

 

[nghiaphuc]

Xin các bác giúp em sử dụng hàm index() để dò tìm cự ly trong file em gửi kèm. Em chưa biết gì về hàm này nên mong các bác chỉ dẫn thêm cho em. Bác nào có ví dụ khác về cách kết hợp hàm này với các hàm khác thì cho em xin luôn để học hỏi thêm. En xin cám ơn các bác lắm lắm!!!

Bạn dùng công thức này cho ô I3 và fill cho toàn cột:
=INDEX($B$25:$G$30,MATCH(F3,$A$25:$A$30,0),MATCH(G3,$B$24:$G$24,0))

 

[Lê Duy Thương]

Xin các bác giúp em sử dụng hàm index() để dò tìm cự ly trong file em gửi kèm. Em chưa biết gì về hàm này nên mong các bác chỉ dẫn thêm cho em. Bác nào có ví dụ khác về cách kết hợp hàm này với các hàm khác thì cho em xin luôn để học hỏi thêm. En xin cám ơn các bác lắm lắm!!!

cách thứ nhất dùng hàm dò tìm cho I3 để tính cự ly
=INDEX($A$24:$G$30,MATCH($G3,$A$24:$A$30,0),MATCH($F3,$A$24:$G$24,0))
cách thứ 2 dùng sumproduct
=SUMPRODUCT(($A$24:$A$30=$G3)*($A$24:$G$24=$F3),$A$24:$G$30)
cách thứ 3
=SUM(IF(($A$24:$A$30=$G3)*($A$24:$G$24=$F3),$A$24:$G$30)) bấm ctrl+shift+enter
ngoài ra còn có thể dung hlookup, vlookup kết hợp với match

 

[nghiaphuc]

cách thứ nhất dùng hàm dò tìm cho I3 để tính cự ly
=INDEX($A$24:$G$30,MATCH($G3,$A$24:$A$30,0),MATCH($F3,$A$24:$G$24,0))
cách thứ 2 dùng sumproduct
=SUMPRODUCT(($A$24:$A$30=$G3)*($A$24:$G$24=$F3),$A$24:$G$30)

Trong 2 công thức này, F3 và G3 cứ để địa chỉ tương đối chứ đâu cần cố định cột làm gì đâu anh?

 

[Lê Duy Thương]

Trong 2 công thức này, F3 và G3 cứ để địa chỉ tương đối chứ đâu cần cố định cột làm gì đâu anh?

hì mình quen đặt như vậy rồi . cho dù tác giả có copy nhầm cũng không sao
hi hi

 

[vominhtri1977]

Vẫn lại là hàm Index()

Bài tập em gửi kèm vẫn giống như bài bữa hôm nhưng lại phải kết hợp thêm hàm match, left, right cắt chuỗi là sao e không thể hiểu được, mong các bác giúp dùm e ở 2 cột giá 1 ngày và tiền cước. Xin cám ơn!!!

 

[Ba Tê]

Bài tập em gửi kèm vẫn giống như bài bữa hôm nhưng lại phải kết hợp thêm hàm match, left, right cắt chuỗi là sao e không thể hiểu được, mong các bác giúp dùm e ở 2 cột giá 1 ngày và tiền cước. Xin cám ơn!!!

1. Giá 1 ngày ô J3:
Hàm INDEX:

=INDEX($A$27:$F$32;MATCH(IF(COUNTIF($A$27:$A$32;RIGHT(C3;2))=0;"KHAC";RIGHT(C3;2));$A$27:$A$32;0);MATCH(IF(COUNTIF($B$26:$F$26;LEFT(C3;2))=0;"KHAC";LEFT(C3;2));$A$26:$F$26;0))

Vlookup:

=VLOOKUP(IF(COUNTIF($A$27:$A$32;RIGHT(C3;2))=0;"KHAC";RIGHT(C3;2));$A$27:$F$32;MATCH(IF(COUNTIF($B$26:$F$26;LEFT(C3;2))=0;"KHAC";LEFT(C3;2));$A$26:$F$26;0);0)

2. Tiền cước: Hổng hiểu, không phải = cự ly x 2.5 sao?

 

[nguyenvanthiep]

trời ơi bạn redhaipro bạn ấy viết không thống nhất cách viết thì làm sao mà tính được chứ.ví dụ như: Thành thị ở trên thì khác Thành thị ở dưới thì làm sao mà hàm Match hiểu được chứ:Công thức của ô hệ số là: G4=vlookup(E4,$D$27:$H$29,match(D4,$E$26:$H$26,0)+1,0) còn cách 2 thì dùng index+match lúc nào rảnh mình viết cho nha.đi ngủ đây muộn rồi.

 

[hoaxoantim]

Đây nè... Xem thử đúng ý chưa?

em đang mon men tìm hiểu về hàm Index và hàm Match. Em vẫn chưa hiểu công thức anh tính trong cột đơn giá ( sao lại phải là (D4-100)/400+2). Hic hic, Anh Tuấn có thể giải thích giúp em được không?

 

[vantam280889]

Bài tập của bạn Kachiusa108 chỉ cần dùng hàm Vookup kết hợp với hàm Left nữa là ok mà . Theo mình hiểu thì hàm INDEX là hàm tìm kiếm đa chiều . Chứ một chiều như bài của bạn Kachiusa108 thì dùng Vlookup ngon hơn nhiều .

 

[haiduongtrang506]

Dear anh chị !

Anh chị giúp em với, em kết hợp hàm match với hàm index nhưng không được. Em có file đính kèm, anh chị chỉ em công thức để lấy giá xuất xướng giúp em.(Dựa vào 2 ký tự đầu của MA XE tra trong bảng 1, tùy vào 2 ký tự cuối của mã xe để có giá tương ứng)View attachment FILE EXCEL.xls
Em cảm ơn anh chị

 

[dongducnhiem]

Dear anh chị !

Anh chị giúp em với, em kết hợp hàm match với hàm index nhưng không được. Em có file đính kèm, anh chị chỉ em công thức để lấy giá xuất xướng giúp em.(Dựa vào 2 ký tự đầu của MA XE tra trong bảng 1, tùy vào 2 ký tự cuối của mã xe để có giá tương ứng)View attachment 93112
Em cảm ơn anh chị

Dùng cái này cho gọn cell D4

,=VLOOKUP(LEFT(A4,2),$A$18:$E$21,MATCH(RIGHT(A4,2),$C$17:$E$17,0)+2,0)

 

[ho-vanlong]

Mình có bảng tính như hình vẽ các bác hẫy giúp mình tìm công thức với nha
Mình cảm ơn nhiều: hovanlongktxd@gmail.com

 

[leonguyenz]

Mình có bảng tính như hình vẽ các bác hẫy giúp mình tìm công thức với nhaView attachment 98715
Mình cảm ơn nhiều: hovanlongktxd@gmail.com

Giả sửa ô đặt công thức là ô M12:

=SUMIF($L$3:$L$9,L12,OFFSET($L$3:$L$9,,1*RIGHT(M11)))

 

[khanhlyabc]

các bác ơi sửa cho em hàm index trong bài tạp này với ạ.em là đủ mọi cách mà không ra
View attachment MO RONG - BAI TAP 7.xls

 

[xuan.nguyen82]

các bác ơi sửa cho em hàm index trong bài tạp này với ạ.em là đủ mọi cách mà không ra
View attachment 99447

Bạn đưa nguyên cả bài lên nhờ làm giúp hết à?

Mình đọc file thấy có yêu cầu là: TỰ GIẢI.

Mà bài này chắc không làm Index, Match được mà dùng công thức mảng hoặc Sumproduct thì tiện hơn.

Mua với Bán cũng không giải thích thế nào là mua? thế nào là bán?

Người đọc tự đọc đề, tự hiểu và tự giải giúp bạn, cứ như là đánh đố nhau ấy.

 

[canhsatlangtu113]

Dùng công thức mảng được không nhỉ?

 

[xuan.nguyen82]

các bác ơi sửa cho em hàm index trong bài tạp này với ạ.em là đủ mọi cách mà không ra
View attachment 99447

Người đọc tự hiểu đề bài, tự giải....
Ở đây bạn không nói rõ phân biệt SL mua và bán ở chỗ nào, thế nào thì được xác định là mua hoặc bán, nên tự hiểu là mã hóa đơn có đuôi là M=Mua., đuôi là B= Bán
Ô B42 dùng công thức: =SUMPRODUCT((RIGHT($B$4:$B$23)="M")*($C$4:$C$23=$A42)*($G$4:$G$23))

Phần thống kê bạn tự làm nhé, dùng countif đơn giản.

Bạn xem file.

 

[khanhlyabc]

các bác ơi

 

[xuan.nguyen82]

các bác ơi giúp em cái bài này với ạ..phần index em làm đủ mọi cách mà nó không ra

Bạn không đọc bài giải trên à? bài #153 Hay là không hiểu đề bài? Cong thức và kết quả trong đó đã có cơ mà?
Bạn còn hỏi cái nào nữa?
Mà index nào? với bài của bạn đã dùng Sumproduct rồi cơ mà????

 

[khanhlyabc]

Bạn không đọc bài giải trên à? bài #153 Hay là không hiểu đề bài? Cong thức và kết quả trong đó đã có cơ mà?
Bạn còn hỏi cái nào nữa?
Mà index nào? với bài của bạn đã dùng Sumproduct rồi cơ mà????

em đúng là vô duyên thật không để ý bác cho em sr nhé
em cảm ơn bác nhiều ạ

 

[xuan.nguyen82]

em đúng là vô duyên thật không để ý bác cho em sr nhé
em cảm ơn bác nhiều ạ

Chỉ còn mỗi phần thống kê bạn tự làm thôi.
Dùng hàm countif

Công thức trong mục thống kê:

F42=COUNTIF($D$4:$D$23;F41)

 

[khanhlyabc]

Chỉ còn mỗi phần thống kê bạn tự làm thôi.
Dùng hàm countif

Công thức trong mục thống kê:

F42=COUNTIF($D$4:$D$23;F41)

à bác ơi,cái phần Nhãn Hiệu ý em dùng hàm index khong ra,hình như con này bác quên chưa làm í. bác xem lại giúp em với ạ,thanks bác tốt bụng

 

[xuan.nguyen82]

à bác ơi,cái phần Nhãn Hiệu ý em dùng hàm index khong ra,hình như con này bác quên chưa làm í. bác xem lại giúp em với ạ,thanks bác tốt bụng

Thực sự chán bài của bạn.

Thứ nhất là: Bạn gửi file lên không 1 lời giải thích là lấy dữ liệu từ đâu gắn vào đâu?
Quy luật bạn xác định các yêu cầu đề bài là gì?
Chẳng biết cột nhãn hiệu ấy làm thế nào để xác định?

Toàn là tôi tự đọc tự hiểu đề bài tự giải. Đề bài đặt mấy dấu chấm hỏi và tôi làm hết mấy dấu chấm hỏi đó, có thấy bạn hỏi cụ thể về "nhãn hiệu" nhãn hiếc gì đâu? Bạn bảo làm hoài không ra mà tôi thấy bạn làm gì đâu? Ít nhất thì bạn cũng để nguyên cái công thức lỗi của bạn ở đó để mà biết bạn định làm gì còn sửa.

Thứ hai là: Bạn cũng chẳng có trách nhiệm gì với bài của bạn cả. Cứ quăng lên ai muốn hiểu thế nào thì hiểu giải thế nào thì giải.


Bạn tự làm phần đó đi nhé. Sai chỗ nào mang lên đây mọi người sửa cho.

Lần sau bạn gửi bài nhớ ghi chú hoặc yêu cầu và giải thích muốn làm gì với cái file đó thì mọi người mới giúp được.

 

[khanhlyabc]

Thực sự chán bài của bạn.

Thứ nhất là: Bạn gửi file lên không 1 lời giải thích là lấy dữ liệu từ đâu gắn vào đâu?
Quy luật bạn xác định các yêu cầu đề bài là gì?
Chẳng biết cột nhãn hiệu ấy làm thế nào để xác định?

Toàn là tôi tự đọc tự hiểu đề bài tự giải. Đề bài đặt mấy dấu chấm hỏi và tôi làm hết mấy dấu chấm hỏi đó, có thấy bạn hỏi cụ thể về "nhãn hiệu" nhãn hiếc gì đâu? Bạn bảo làm hoài không ra mà tôi thấy bạn làm gì đâu? Ít nhất thì bạn cũng để nguyên cái công thức lỗi của bạn ở đó để mà biết bạn định làm gì còn sửa.

Thứ hai là: Bạn cũng chẳng có trách nhiệm gì với bài của bạn cả. Cứ quăng lên ai muốn hiểu thế nào thì hiểu giải thế nào thì giải.


Bạn tự làm phần đó đi nhé. Sai chỗ nào mang lên đây mọi người sửa cho.

Lần sau bạn gửi bài nhớ ghi chú hoặc yêu cầu và giải thích muốn làm gì với cái file đó thì mọi người mới giúp được.

bài này em tải trên mạng về nên cũng thấy như bác nói đúng ạ..trả có đề bài gì cả nên e cứ tự lần mò thôi .e quên mất không nói
lần sau em sẽ chú ý ạ
cảm ơn bác đã nhắc nhở ạ

 

[khanhlyabc]

à bác ơi,cái phần Nhãn Hiệu ý em dùng hàm index khong ra,hình như con này bác quên chưa làm í. bác xem lại giúp em với ạ,thanks bác tốt bụng
bác giải nốt cho em phần Nhãn Hiệu được không ạ,theo em nghĩ thì phần này lấy ở bảng Nhãn Hiệu ạ mà em dùng hàm index không được
em cảm ơn bác

 

[siwtom]

à bác ơi,cái phần Nhãn Hiệu ý em dùng hàm index khong ra,hình như con này bác quên chưa làm í. bác xem lại giúp em với ạ,thanks bác tốt bụng
bác giải nốt cho em phần Nhãn Hiệu được không ạ,theo em nghĩ thì phần này lấy ở bảng Nhãn Hiệu ạ mà em dùng hàm index không được
em cảm ơn bác

Có việc trích mà bạn cũng không làm cho đàng hoàng.
Bạn đang nói chuyện với ma đấy à? "Bác ơi"? Bác nào vậy bạn? Hay mọi người phải đọc hết các bài trong chủ đề để biết bạn đang gọi ai?
-------------------

Công thức cho ô E4:

=VLOOKUP($C4;$A$35:$E$38;MATCH($D4;$B$33:$E$33;0)+1;0)

hoặc nếu bạn cứ bắt buộc phải là INDEX thì:

=INDEX($B$35:$E$38;MATCH($C4;$A$35:$A$38;0);MATCH($D4;$B$33:$E$33;0))

À mà ô D4 bạn sửa thành

=HLOOKUP([COLOR=#ff0000][B]--[/B][/COLOR]MID(B4;2;2);$A$27:$F$28;2;0)

Mọi công thức kéo xuống dưới

 

[pidu25251325]

Công thức mảng và tìm kiếm

các bạn ơi, cho mình hỏi bài này với:
có 2 yêu cầu mà mình làm mãi không được
-yêu cầu 1: cho biết sản phẩm có số lượng lớn nhất được bán trong tháng 7 và tháng 9 sử dụng công thức mảng
Đối với yêu cầu này mình đã dùng hàm index kết hợp match và rank nhưng không được vì ô dò nó không cụ thể nên không dò ra. làm mãi mà không được
-yêu cầu 2: nhập loại sp và mã số tìm kiếm, nếu tồn tại tỏng bảng kê khai thì "có" nếu không tồn tại trong bảng kê khai thì "không"
cái này mình thử làm như trong file nhưng làm với loại sản phẩm (tại làm không được nên thử làm với loại sp trước ) cuối cùng là nó chỉ ra "có", nếu mình ấn khác thì nó hiện ""#N/A"
các bạn giúp mình với, nghĩ từ tối qua, giờ vẫn không làm được.

 

[nhapmon]

các bạn ơi, cho mình hỏi bài này với:
có 2 yêu cầu mà mình làm mãi không được
-yêu cầu 1: cho biết sản phẩm có số lượng lớn nhất được bán trong tháng 7 và tháng 9 sử dụng công thức mảng
Đối với yêu cầu này mình đã dùng hàm index kết hợp match và rank nhưng không được vì ô dò nó không cụ thể nên không dò ra. làm mãi mà không được
-yêu cầu 2: nhập loại sp và mã số tìm kiếm, nếu tồn tại tỏng bảng kê khai thì "có" nếu không tồn tại trong bảng kê khai thì "không"
cái này mình thử làm như trong file nhưng làm với loại sản phẩm (tại làm không được nên thử làm với loại sp trước ) cuối cùng là nó chỉ ra "có", nếu mình ấn khác thì nó hiện ""#N/A"
các bạn giúp mình với, nghĩ từ tối qua, giờ vẫn không làm được.

bạn thử xem vậy được ko
yeu cầu 1:
=INDEX($D$3:$D$12,MATCH(MAX(IF((MONTH($E$3:$E$12)=7)+(MONTH($E$3:$E$12)=9),$F$3:$F$12)),$F$3:$F$12,0))
Ctrl Shìft Enter, nhưng nếu bạn có 2 sản phẩm có số lượng bằng nhau trong 2 tháng đó thì chú nào đứng trước nó lấy chú đó

yêu cầu 2
=IF(VLOOKUP(B17,$B$3:$C$12,2,0)=C17,"co","ko")

 

[leonguyenz]

Câu 1: Công thức mảng tìm sp bán lớn nhất trong tháng 7 hoặc tháng 9:

=INDEX(B3:B12,MATCH(MAX(IF((MONTH(E3:E12)=7)+(MONTH(E3:E12)=9),F3:F12,"")),F3:F12,0),)

Câu 2: Bạn phải xem cần tìm sp hay theo mã số, nếu 1 trong 2 thì:

=IF(COUNTIF(B3:B12,B17)+COUNTIF(C3:C12,C17)>0,"Có","Không")

 

[Ba Tê]

Câu 1: Công thức mảng tìm sp bán lớn nhất trong tháng 7 hoặc tháng 9:

=INDEX(B3:B12,MATCH(MAX(IF((MONTH(E3:E12)=7)+(MONTH(E3:E12)=9),F3:F12,"")),F3:F12,0),)

Câu 2: Bạn phải xem cần tìm sp hay theo mã số, nếu 1 trong 2 thì:

=IF(COUNTIF(B3:B12,B17)+COUNTIF(C3:C12,C17)>0,"Có","Không")

Câu 1 "hổng chắc ăn" à nghe Leonguyenz.
F8=9 hiện là lớn nhất trong tháng 7 và tháng 9, nhưng nếu gõ F4 (Tháng 6) cũng =9 thì kết quả ra cái gì? Tèn tèn.
----------------
Nếu không đưa vào Name thì "lòng vòng" một chút cho chắc ăn:
=INDEX($D$3:$D$12;MATCH(MAX(IF(MONTH($E$3:$E$12)=7;$F$3:$F$12;0)+IF(MONTH($E$3:$E$12)=9;F3:F12;0));IF(MONTH($E$3:$E$12)=7;$F$3:$F$12;0)+IF(MONTH($E$3:$E$12)=9;F3:F12;0);0)
Híc! Mà lòng vòng thiệt.

 

[pidu25251325]

cảm ơn các bạn nhìu lắm ^^, mà sao các bạn giỏi quá vậy, biết thế mình hỏi lẹ hôm qua cho xong
cơ mà mình vẫn chưa hiểu lám đoạn nàycủa bạn Nhapmon
=INDEX($D$3:$D$12,MATCH(MAX(IF((MONTH($E$3:$E$12)= 7)+(MONTH($E$3:$E$12)=9),$F$3:$F$12)),$F$3:$F$12,0 ))
vì - if(dk,đúng,sai) mà bạn ìf(dk, đúng) bỏ phần sai vẫn được hả
-index( vùng dò, dòng, cột) mà bạn chỉ mới (vùng dò, dòng) bỏ cột vẫn được hả bạn
hix, hay tại mình chậm tiêu không có biết ý đồ
P/s: làm theo cách bạn ra kết quả ^^

 

[nhapmon]

cảm ơn các bạn nhìu lắm ^^, mà sao các bạn giỏi quá vậy, biết thế mình hỏi lẹ hôm qua cho xong
cơ mà mình vẫn chưa hiểu lám đoạn nàycủa bạn Nhapmon
=INDEX($D$3:$D$12,MATCH(MAX(IF((MONTH($E$3:$E$12)= 7)+(MONTH($E$3:$E$12)=9),$F$3:$F$12)),$F$3:$F$12,0 ))
vì - if(dk,đúng,sai) mà bạn ìf(dk, đúng) bỏ phần sai vẫn được hả
-index( vùng dò, dòng, cột) mà bạn chỉ mới (vùng dò, dòng) bỏ cột vẫn được hả bạn
hix, hay tại mình chậm tiêu không có biết ý đồ
P/s: làm theo cách bạn ra kết quả ^^

ok, nhưng nó có vấn đề mà anh Bate nêu ở bài #166

còn 2 vấn đề bạn hỏi thì
ìf(dk, đúng) thì nó chỉ lấy cái nào đúng thôi, nếu toàn bộ vùng dữ liệu ko có cái nào đúng nó sẻ báo lổi
index( vùng dò, dòng): mặ nhiên nó hiểu là cột 1, vì vùng dò chỉ có một cột

 

[pidu25251325]

hớ hớ, jo thì mình hiểu rồi ^^, cái này mới à nha. mình còn nhìu cái không biết và muốn hỏi lắm, một hồi mình làm bài mà lòi ra cái j làm không được hỏi nữa thì mấy bạn chỉ dùm mình cái nha

 

[Ba Tê]

hớ hớ, jo thì mình hiểu rồi ^^, cái này mới à nha. mình còn nhìu cái không biết và muốn hỏi lắm, một hồi mình làm bài mà lòi ra cái j làm không được hỏi nữa thì mấy bạn chỉ dùm mình cái nha

Các thành viên GPE sẵn sàng trả lời những gì họ có thể giúp được nhưng khi đọc những từ tiếng Việt không ra tiếng Việt (NHƯ NHỮNG CHỮ TÔ ĐỎ BÊN TRÊN) có khi không ai thèm trả lời đâu.
Viết kiểu "Chít chát" ở các box nghiêm chỉnh trao đổi học tập trên GPE thường các bạn rất "dị ứng", bị xóa bài theo "quê lắm".

 

[pidu25251325]

mình sẽ chú ý hơn về cách viết ^^
Mình có bài này cũng liên quan tới công thức mảng, mình đã làm nhưng không sao đúng với yêu cầu người ta cho
- yêu cầu: Nhập vào giá trị STT tại ô A3 để hiện thị thông tin chi tiết tại các cột tương ứng, nếu không tìm thấy thì định dạng có điều kiện để ẩn lỗi #N/A và hiển thị tại ô H3 là không tìm thấy (cái này trong đề người ta cho là ô H2, n mình nghĩ người ta ghi nhầm)
Mình đã thử làm như trong file, nhưng không được, mọi người chỉ mình với

 

[hoalan14]

mình sẽ chú ý hơn về cách viết ^^
Mình có bài này cũng liên quan tới công thức mảng, mình đã làm nhưng không sao đúng với yêu cầu người ta cho
- yêu cầu: Nhập vào giá trị STT tại ô A3 để hiện thị thông tin chi tiết tại các cột tương ứng, nếu không tìm thấy thì định dạng có điều kiện để ẩn lỗi #N/A và hiển thị tại ô H3 là không tìm thấy (cái này trong đề người ta cho là ô H2, n mình nghĩ người ta ghi nhầm)
Mình đã thử làm như trong file, nhưng không được, mọi người chỉ mình với

Gửi bạn, không phai dùng công thức mảng đau

 

[pidu25251325]

Gửi bạn, không phai dùng công thức mảng đau

Mình cảm ơn bạn nha ^^
nhưng người ta yêu cầu là công thức mảng bạn ạ

 

[hoalan14]

Mình cảm ơn bạn nha ^^
nhưng người ta yêu cầu là công thức mảng bạn ạ

máy móc nhỉ? Nếu thíchcông thức mảng thì bạn cứ gõ công thức như vậy và ctrl shift enter thôi

 

[pidu25251325]

máy móc nhỉ? Nếu thíchcông thức mảng thì bạn cứ gõ công thức như vậy và ctrl shift enter thôi

^^ tại mình có hỏi bạn mình rằng cái này dùng hàm vlookup là đượcrồi không hiểu sao lại có công thức mảng nữa nên mình nghĩ nó không đơn giản chỉ dùng vlookup và gõ ctrl+shift enter, hóa ra nó chỉ đơn giản mà mình nghĩ nó phức tạp lên ^^ cảm ơn bạn nhiều

 

[Trang Định]

mình cũng có bài tập này ( ở sheet 7 bài tập 8 các yêu cầu đưa ra danh sách những người tên An hoặc họ Trần... ) ko biết nên dùng hàm nào, mong mọi người giúp đỡ
View attachment Bài tập thực hành.xls

 

[kaka1904]

mọi người cho mình hỏi bài này với, chỗ đơn giá bắt dùng mảng kết hợp hàm index vs match....mình làm hoài mà nó không ra, mọi người giúp mình với, cuối tuần mình thi tin b rồi mà phần mảng này ngu quá

 

[leonguyenz]

mọi người cho mình hỏi bài này với, chỗ đơn giá bắt dùng mảng kết hợp hàm index vs match....mình làm hoài mà nó không ra, mọi người giúp mình với, cuối tuần mình thi tin b rồi mà phần mảng này ngu quá

Bài 02 dùng COUNTIF có thể giải quyết vấn đề.
Bài 03: Đơn giá tại ô E2.

=INDEX($B$27:$F$31,MATCH(B2,$A$27:$A$31,0),MATCH(A2,$B$26:$F$26,0))

hoặc:

=VLOOKUP(B2,$A$27:$F$31,1+MATCH(A2,$B$26:$F$26,0),0)

 

[euteamo509]

Các bạn giúp mình câu này với:
Câu 1: Mã loại dựa vào dữ liệu trong Bảng Loại Hàng để chọn (không nhập trưc tiếp) (câu này mình làm được).
Câu 2: Tên dựa vào Mã Loại tra trong Bảng Loại Hàng (dùng hàm Index_công thức mảng) (mình làm chỉ hiện ra được 1 tên loại hàng duy nhất).
Cảm ơn mọi người đã giúp đỡ!

 

[ngocanh-key]

Mọi người giúp mình với, không biết sai chỗ nào nữa.
Giá trị vẫn ra bình thường, nhưng khi không có giá trị nào thì nó trả kết quả #VALUE.
=IF((LEFT($H$11,1)="X"),INDEX(DLNX!$O$6:$O$9000,$N19),INDEX((DLNX!$I$6:$I$9000)+(DLNX!$J$6:$J$9000),$N19))

 

[Hieu07061984]

Mọi người giúp mình với, không biết sai chỗ nào nữa.
Giá trị vẫn ra bình thường, nhưng khi không có giá trị nào thì nó trả kết quả #VALUE.
=IF((LEFT($H$11,1)="X"),INDEX(DLNX!$O$6:$O$9000,$N19),INDEX((DLNX!$I$6:$I$9000)+(DLNX!$J$6:$J$9000),$N19))

Bạn úp file lên có dữ liệu thì mình mới kiểm tra chính xác được

 

[anhthanh123]

giúp e với các anh/chị

 

[jaispierre]

Nhờ các anh chị xem giúp hàm index ở trong file đính kèm có gì sai? Khi ấn vào ô chứa hàm rồi ấn F9 thì giá trị trả về mới đúng.

 

[quocgiacan]

Nhờ các anh chị xem giúp hàm index ở trong file đính kèm có gì sai? Khi ấn vào ô chứa hàm rồi ấn F9 thì giá trị trả về mới đúng.

Chào jaispierre,

Đó là công thức mảng, nên sau khi gõ hoặc copy vào bạn phải kết thúc bằng CTRL+SHIFT+ENTER
Hàm trên có thể viết theo cách nữa:

H3=INDEX(B$2:B$80,SMALL(IF($G$2=$A$2:$A$80,ROW(A$1:A$7)),ROW(A1)))

CTRL+SHIFT+ENTER fill xuống, muốn không báo lỗi thì bao thêm Iferror(...........,"") bên ngoài công thức trên.

Chúc bạn ngày vui.

 

[jaispierre]

Không có nút cảm ơn, mình muốn cảm ơn bạn nhiều

 

[iamhatinh]

nhờ các bác xem giúp em công thức bị sai chỗ nào ạ

 

[Phan Thế Hiệp]

View attachment 284417



nhờ các bác xem giúp em công thức bị sai chỗ nào ạ

Nếu dữ liệu như file bạn gửi, và công thức của bạn đang là:
=INDEX($C$3:$N$9,MATCH(1,($B16=$A$3:$A$9)*(C$15=$B$3:$B$9),0),$A16)
Kết thúc bằng Ctrl+Shift+Enter

Nên thêm vào 1 điều kiện nữa:
=INDEX($C$3:$N$9,MATCH(1,($B16=$A$3:$A$9)*(C$15=$B$3:$B$9)*(INDEX($C$3:$N$9,,$A16)>0),0),$A16)
Kết thúc bằng Ctrl+Shift+Enter

Cách khác để bạn tham khảo thêm:
=SUMIFS(INDEX($C$3:$N$9,,$A16),$A$3:$A$9,$B16,$B$3:$B$9,C$15)
Enter

Hoặc:
=SUMPRODUCT(($C$2:$N$2=$A16)*($A$3:$A$9=$B16)*($B$3:$B$9=C$15)*$C$3:$N$9)
Enter

Thân

 

[uyenluv]

Nhờ mọi người xem giúp công thức trong file đính kèm. Ở ô G2 Sheet1 mình muốn viết công thức để dò tìm giá trị ở cột A Sheet2 theo điều kiện là cột B ở Sheet1, tương tự cho các ô ở dưới
Xin cảm ơn mọi người

 

[hoangtuaotrang_hp_vn]

Nhờ mọi người xem giúp công thức trong file đính kèm. Ở ô G2 Sheet1 mình muốn viết công thức để dò tìm giá trị ở cột A Sheet2 theo điều kiện là cột B ở Sheet1, tương tự cho các ô ở dưới
Xin cảm ơn mọi người

Bạn sửa công thức lại thế này:

=INDEX(Sheet2!$A$2:$A$52,MATCH(B2,Sheet2!$C$2:$C$52,0))

 

[uyenluv]

Bạn sửa công thức lại thế này:

=INDEX(Sheet2!$A$2:$A$52,MATCH(B2,Sheet2!$C$2:$C$52,0))

Cảm ơn bạn. Nhưng kéo xuống đến ô G4 bắt đầu bị lỗi #N/A ạ.

 

[Maika8008]

Cảm ơn bạn. Nhưng kéo xuống đến ô G4 bắt đầu bị lỗi #N/A ạ.

Công thức không tìm thấy giá trị nào thì nó trả về lỗi #N/A thôi

 

[uyenluv]

Công thức không tìm thấy giá trị nào thì nó trả về lỗi #N/A thôi

Ý mình là muốn tìm kiếm giá trị trong mảng $D$2:$W$51 của sheet 2 để trả về giá trị ở cột A tương ứng (vì các giá trị dò tìm nằm ở các cột khác nhau), chứ không phải chỉ tìm trong mỗi cột C ạ.

 

[dangductuong2125]

Ý mình là muốn tìm kiếm giá trị trong mảng $D$2:$W$51 của sheet 2 để trả về giá trị ở cột A tương ứng (vì các giá trị dò tìm nằm ở các cột khác nhau), chứ không phải chỉ tìm trong mỗi cột C ạ.

Chắc không phải thử đâu, thật luôn đi :

G2=IFERROR(INDEX(Sheet2!$A$2:$W$192,AGGREGATE(15,6,ROW(Sheet2!$A$1:$W$192)/SEARCH(TRANSPOSE(B2),Sheet2!$A$2:$W$192)^0,1),1),"")

 

[Maika8008]

Ý mình là muốn tìm kiếm giá trị trong mảng $D$2:$W$51 của sheet 2 để trả về giá trị ở cột A tương ứng (vì các giá trị dò tìm nằm ở các cột khác nhau), chứ không phải chỉ tìm trong mỗi cột C ạ.

Rõ ràng là bạn đang nói công thức này, chừ sao lại bẻ lái sang chuyện khác?

 

[uyenluv]

Chắc không phải thử đâu, thật luôn đi :

G2=IFERROR(INDEX(Sheet2!$A$2:$W$192,AGGREGATE(15,6,ROW(Sheet2!$A$1:$W$192)/SEARCH(TRANSPOSE(B2),Sheet2!$A$2:$W$192)^0,1),1),"")

Cảm ơn bạn, kết quả ra như mình mong muốn rồi

View attachment 286789
Rõ ràng là bạn đang nói công thức này, chừ sao lại bẻ lái sang chuyện khác?

Sr bạn, do đang gấp nên mình không để ý, lần sau mình sẽ chú ý hơn ^^