Đếm thỏa mãn 2 điều kiện (1 người xem)

[lamchanphieu]

Giúp em công thức đếm thỏa mãn 2 điều kiện

 

[ndu96081631]

Giúp em công thức đếm thỏa mãn 2 điều kiện

Công thức cho A13 là:

=COUNT(1/FREQUENCY(IF($D$1:$D$7="a",$C$1:$C$7),$C$1:$C$7))

Công thức mảng, gõ xong phải kết thúc bằng tổ hợp phím Ctrl + Shift + Enter nha

 

[lamchanphieu]

mình đã làm được rồi,xin cảm ơn nhiều nhé!

 

[lamchanphieu]

nhưng sau công thức đó vẫn chưa được ạ!

 

[lamchanphieu]

vì ở cột c ,không phải lúc nào là cũng là 1 con số, có khi là nội dung thì không đúng,mong các anh chị giúp dùm ah

 

[lamchanphieu]

View attachment DEM THOA MAN 2 DIEU KIEN2.xls
vd: như file này , thì công thức đó chưa áp dụng được ạ!

 

[ndu96081631]

View attachment 111021
vd: như file này , thì công thức đó chưa áp dụng được ạ!

Nếu giá trị cần tìm dạng text thì dùng hàm MATCH. Ví dụ:

=COUNT(1/FREQUENCY(IF($D$1:$D$7="a",MATCH($C$1:$C$7,$C$1:$C$7,0)),MATCH($C$1:$C$7,$C$1:$C$7,0)))

 

[lamchanphieu]

công thức này thì được ,nhưng sao em xóa bỏ 1 cột bất kỳ từ cột C1 cho đến C7 thi nó lại = 0 , có công thức để không bị vậy nữa không ạ !

 

[ndu96081631]

công thức này thì được ,nhưng sao em xóa bỏ 1 cột bất kỳ từ cột C1 cho đến C7 thi nó lại = 0 , có công thức để không bị vậy nữa không ạ !

Đương nhiên vậy rồi!
Dữ liệu của bạn cảng phức tạp thì công thức càng dài ra

=COUNT(1/FREQUENCY(IF($D$1:$D$7="a",IF($C$1:$C$7<>"",MATCH($C$1:$C$7,$C$1:$C$7,0))),IF($C$1:$C$7<>"",MATCH($C$1:$C$7,$C$1:$C$7,0))))

Chủ yếu là thêm IF vào thôi

 

[lamchanphieu]

Mình đã làm được rồi,công thức này dài nhưng rất hay,cám ơn bạn rất rất nhiều ah !

 

[truckhoa2006]

Cho em hỏi: Em có hiểu ra hàm Thấy viết rồi, như tại sao chỗ này
IF($C$1:$C$7<>"",MATCH($C$1:$C$7,$C$1:$C$7,0))),IF($C$1:$C$7<>"",MATCH($C$1:$C$7,$C$1:$C$7,0)
Sao phải lặp lại 2 lần vậy, em càng đọc em càng không hiểu.
Cám ơn thầy

 

[ndu96081631]

Cho em hỏi: Em có hiểu ra hàm Thấy viết rồi, như tại sao chỗ này
IF($C$1:$C$7<>"",MATCH($C$1:$C$7,$C$1:$C$7,0))),IF($C$1:$C$7<>"",MATCH($C$1:$C$7,$C$1:$C$7,0)
Sao phải lặp lại 2 lần vậy, em càng đọc em càng không hiểu.
Cám ơn thầy

Đỏ và xanh là 2 đối số của hàm FREQUENCY mà