Đếm bỏ qua dữ liệu trùng nhau (1 người xem)

[vanlan_ks]

Mình đang làm thống kê với yêu cầu là: Đếm tổng số dữ liệu nhưng bỏ qua dữ liệu trùng nhau, đồng thời đếm cả ô rỗng và kết hợp đếm với điều kiện thứ hai. Yêu cầu mình đã nêu trong file. Xin chỉ giúp công thức

 

[chuot0106]

Mình đang làm thống kê với yêu cầu là: Đếm tổng số dữ liệu nhưng bỏ qua dữ liệu trùng nhau, đồng thời đếm cả ô rỗng và kết hợp đếm với điều kiện thứ hai. Yêu cầu mình đã nêu trong file. Xin chỉ giúp công thức

Tôi thấy kết quả đúng chỉ là 6 thôi.

 

[chuot0106]

Mở File, nhập năm cần đếm vào ô H2 sau đó nhấn nút "ĐẾM" sẽ nhận được kết quả!

 

[ndu96081631]

Mình đang làm thống kê với yêu cầu là: Đếm tổng số dữ liệu nhưng bỏ qua dữ liệu trùng nhau, đồng thời đếm cả ô rỗng và kết hợp đếm với điều kiện thứ hai. Yêu cầu mình đã nêu trong file. Xin chỉ giúp công thức

Đây là bài toán đếm duy nhất có điều kiện, hàm bạn cần là FREQUENCY
Công thức cho bạn:

=COUNT(1/FREQUENCY(IF($C$4:$C$500=$H$2,IF($B$4:$B$500<>"",MATCH($B$4:$B$500,$B$4:$B$500,0))),IF($C$4:$C$500=$H$2,IF($B$4:$B$500<>"",MATCH($B$4:$B$500,$B$4:$B$500,0)))))

Gõ xong công thức, bấm tổ hợp phím Ctrl + Shift + Enter để kết thúc nhé

 

[siwtom]

Mình đang làm thống kê với yêu cầu là: Đếm tổng số dữ liệu nhưng bỏ qua dữ liệu trùng nhau, đồng thời đếm cả ô rỗng và kết hợp đếm với điều kiện thứ hai. Yêu cầu mình đã nêu trong file. Xin chỉ giúp công thức

Hiểu được bạn khó quá. Trong tập tin bạn viết: "đồng thời bỏ qua ô rỗng". Rõ ràng cái xanh và đỏ mâu thuẫn với nhau. Hoặc tôi quá buồn ngủ rồi

Không biết tôi có lường hết các trường hợp không. Mà tôi có cảm giác là công thức có thể ngắn gọn hơn.
Giả sử năm sinh nhập ở F2
Công thức

=SUM(IF($C$4:$C$500=$F$2;IF($B$4:$B$500="";"";--(MATCH($B$4:$B$500&"*"&$C$4:$C$500;$B$4:$B$500&"*"&$C$4:$C$500;0)=ROW($B$4:$B$500)-3));""))

Kết thúc bằng Ctrl+Shift+Enter

 

[vanlan_ks]

Mình cám ơn tất cả sự giúp đỡ.

 

[chuot0106]

Mình cám ơn tất cả sự giúp đỡ.

Bạn test thử chưa? Kết quả thế nào? Nhớ enable macros trước khi mở file nhé.(xem dưới chữ kí của tôi).

 

[vanlan_ks]

Bạn test thử chưa? Kết quả thế nào? Nhớ enable macros trước khi mở file nhé.(xem dưới chữ kí của tôi).

Mình text thử rồi. đáp án đúng, nhưng mình áp dụng theo công thức, nó phù hợp hơn bảng thống kê mình làm. Còn VBA mỗi lần cập nhật lại pải bấm nút.

Hai CT "=COUNT(1/FREQUENCY(IF($C$4:$C$500=$H$2,IF($B$4:$B$500<>"",MATCH($B$4:$B$500,$B$4:$B$500,0))),IF($C$4:$C$500=$H$2,IF($B$4:$B$500<>"",MATCH($B$4:$B$500,$B$4:$B$500,0)))))"
và công thúc này nữa "=SUM(IF($C$4:$C$500=$F$2;IF($B$4:$B$500="";"";--(MATCH($B$4:$B$500&"*"&$C$4:$C$500;$B$4:$B$500&"*"&$C$4:$C$500;0)=ROW($B$4:$B$500)-3));""))".
Xin cám ơn

 

[ndu96081631]

Mình text thử rồi. đáp án đúng, nhưng mình áp dụng theo công thức, nó phù hợp hơn bảng thống kê mình làm.

Công thức có thể rút gọn thêm nè:

=COUNT(1/FREQUENCY(IF($C$4:$C$500=$H$2,IF($B$4:$B$500<>"",MATCH($B$4:$B$500,$B$4:$B$500,0))),MATCH($B$4:$B$500,$B$4:$B$500,0)))

hoặc ngắn hơn:

=COUNT(1/FREQUENCY(IF($C$4:$C$500=$H$2,IF($B$4:$B$500<>"",MATCH($B$4:$B$500,$B$4:$B$500,0))),ROW($1:$497)))

 

[siwtom]

Mình text thử rồi. đáp án đúng, nhưng mình áp dụng theo công thức, nó phù hợp hơn bảng thống kê mình làm.

He he, nửa đêm buồn ngủ quá.
Như tôi đã có cảm giác, công thức ở bài #5 thực ra là thừa bởi MATCH được "gọi" cho các dòng có cột C y hệt nhau và = F2 (và B <> rỗng). Chỉ cần rút gọn thành

=SUM(IF($C$4:$C$500=$F$2;IF($B$4:$B$500="";"";--(MATCH($B$4:$B$500;$B$4:$B$500;0)=ROW($B$4:$B$500)-3));""))

Có lẽ không thể ngắn gọn hơn nữa

 

[taductam]

Tên nhân viên Công văn gửi đi số
Trần Thị Kim Oanh 2100
Trần Thị Kim Oanh 2453
Trần Thị Kim Oanh 784
Trần Thị Kim Oanh 2100
Trần Thị Kim Oanh 2098
Trần Thị Kim Oanh 2098
Trần Thị Kim Oanh 2099
Trần Thị Kim Oanh 2101
Trần Thị Kim Oanh 4130
Trần Thị Kim Oanh 4130
Phạm Thị Thu Huyền 41256
Phạm Thị Thu Huyền 41256
Phạm Thị Thu Huyền 4253
Phạm Thị Thu Huyền 4258
Phạm Thị Thu Huyền 4128
Phạm Thị Thu Huyền 7951
Phạm Tuấn Anh 1258
Phạm Tuấn Anh 5623
Phạm Tuấn Anh 5623
Phạm Tuấn Anh 1247
Phạm Tuấn Anh 1259
Phạm Tuấn Anh 1259
Phạm Tuấn Anh 1278
Phạm Tuấn Anh 3254
Trần Thị Kim Oanh 2099
Trần Thị Kim Oanh 4130
Các bác giúp em cái vụ này với. Em muốn đếm số công văn gửi đi cho từng nhân viên thì như thế nào ạ (không đếm các công văn trùng nhau)? Em xin cảm ơn!

 

[long10]

Mình làm thử bằng VBA nhé