So sánh từng giá trị của sản phẩm với mẫu để đánh giá sản phẩm đạt hay không (2 người xem)

[hoangtuaotrang_hp_vn]

em chào anh chị,
mong anh chị giúp em vấn đề này:
1. Hiện tại em có 2 mẫu (Mẫu 1, Mẫu 2) có các thông số cho phép
2. Có 1 Danh sách sản phẩm cần so sánh từng thành phần trong từng sản phẩm ấy với từng thành phần trong mẫu để đưa ra kết luận đạt (OK) hay không đạt (NG)
Cần: So sánh lần lượt các thành phẩn trong từng sản phẩm với các thành phần của từng mẫu (Mẫu 1, Mẫu 2)
- Nếu các nguyên tố có trong sản phẩm mà không có trong mẫu thì không cần xét những nguyên tố đó,
- Nếu nguyên tố có trong sản phẩm trùng với nguyên tố trong mẫu thì so sánh xem giá trị của nguyên tố trong sản phẩm đó có nằm trong dải cho phép của nguyên tố đó ở trong mẫu hay không, rồi đưa ra kết luận

 

[Phuocam]

Mẫu 1: Nguyên tố Zn, Au, Ti, O để trống có nghĩa là => Sản phẩm có bao nhiêu kết quả cũng Đạt?

 

[hoangtuaotrang_hp_vn]

Mẫu 1: Nguyên tố Zn, Au, Ti, O để trống có nghĩa là => Sản phẩm có bao nhiêu kết quả cũng Đạt?

vâng, đúng rồi anh à

 

[Phuocam]

vâng, đúng rồi anh à

Bạn có thể ghi kết quả mong muốn 14 trường hợp trong file?

 

[hoangtuaotrang_hp_vn]

Bạn có thể ghi kết quả mong muốn 14 trường hợp trong file?

anh ơi, em up lại file yêu cầu cho rõ ràng, chứ giờ bảo rò bằng mắt tưng đấy hàng thì cần gì công thức nữa ạ

 

[Phuocam]

anh ơi, em up lại file yêu cầu cho rõ ràng, chứ giờ bảo rò bằng mắt tưng đấy hàng thì cần gì công thức nữa ạ

Pb model đầu tiên có 0.0008. Mẫu 1 chuẩn Pb từ 0.020 đến 22.5, sao kết quả là OK?

 

[hoangtuaotrang_hp_vn]

Pb model đầu tiên có 0.0008. Mẫu 1 chuẩn Pb từ 0.020 đến 22.5, sao kết quả là OK?

Ôi, em xin lỗi, kết quả phải là NG mới đúng, cả ngày nay ngồi máy tính nên mắt bị mỏi quá anh à, giờ không muốn mở ra nữa, rò hết chỗ này chắc em chết luôn, mà lại dễ nhầm lẫn nữa (

 

[Phan Thế Hiệp]

anh ơi, em up lại file yêu cầu cho rõ ràng, chứ giờ bảo rò bằng mắt tưng đấy hàng thì cần gì công thức nữa ạ

Thử:

AN6=IF(AND(IFERROR(SUMIF($M$5:$AL$5,$A$6:$A$30,$M6)/COUNTIFS($M6:$AL6,">0",$M$5:$AL$5,$A$6:$A$30)/($B$6:$B$30>0)*{1,-1}>=CHOOSE({1,2},$B$6:$B$30,$D$6:$D$30)*{1,-1},"")),"OK","NG")
AO6=IF(AND(IFERROR(SUMIF($M$5:$AL$5,$A$6:$A$30,$M6)/COUNTIFS($M6:$AL6,">0",$M$5:$AL$5,$A$6:$A$30)/($B$6:$B$30>0)*{1,-1}>=CHOOSE({1,2},$E$6:$E$30,$G$6:$G$30)*{1,-1},"")),"OK","NG")

Kết thúc bằng Ctrl+Shift+Enter. Fill xuống.

Thân

 

[Phuocam]

Nếu sắp xếp bảng Mẫu hợp lý, công thức có thể rút gọn.

 

[hoangtuaotrang_hp_vn]

Hiện tại thì công thức của anh/chú Phan Thế Hiệp giúp đã quá thành công và đạt rồi ạ.

Nếu sắp xếp bảng Mẫu hợp lý, công thức có thể rút gọn.

vâng anh, em cũng chưa hiểu ý anh là sắp xếp thế nào cho phù hợp, hì hì (tại em chưa hiểu chứ không có ý gì đâu anh)
Tự nhiên, sáng nay, đầu óc, thông thoáng chút, chợt nghĩ ra 1 cách hơi củ chuối là sắp xếp lại bảng mẫu như file và check thủ công như dòng 22 đến dòng 24 ( nếu như trong lúc chưa nhận được giúp đỡ đành phải làm vậy, rất may là sáng sớm nay em đã nhận được giúp đỡ kịp thời). Có phải ý anh là sắp xếp như trong file mới này không? hay như thế nào thì hướng dẫn giúp em để em được học hỏi và rút kinh nghiệm cho những bài tương tự ạ

 

[Phuocam]

Bảng dò này rất tốt, bạn có thể thử công thức này tại AS8:

=IF(SUMPRODUCT(($N$3:$AP$3<>0)*(N8:AP8<>0)-($N$3:$AP$3<>0)*($N$3:$AP$3<=N8:AP8)*($N$4:$AP$4>=N8:AP8)),"NG","OK")

 

[HieuCD]

Bảng dò này rất tốt, bạn có thể thử công thức này tại AS8:

=IF(SUMPRODUCT(($N$3:$AP$3<>0)*(N8:AP8<>0)-($N$3:$AP$3<>0)*($N$3:$AP$3<=N8:AP8)*($N$4:$AP$4>=N8:AP8)),"NG","OK")

Công thức khó hiểu và hơi dài Vọt lẹ

 

[Phuocam]

Rút gọn một chút:

=IF(SUMPRODUCT(($N$3:$AP$3<>0)*(N8:AP8<>0)*(($N$3:$AP$3>N8:AP8)+($N$4:$AP$4<N8:AP8))),"NG","OK")

 

[Phan Thế Hiệp]

Nếu sắp xếp bảng Mẫu hợp lý, công thức có thể rút gọn.

Bạn hiền chính xác 100%

Vậy, cũng góp vui thêm công thức mảng, cho chủ thớt tham khảo thêm:

AS8=IF(AND(IFERROR({1;-1}*((N8:AP8-$N$3:$AP$4)/(N8:AP8*$N$3:$AP$3>0))>=0,"")),"OK","NG")
AT8=IF(AND(IFERROR({1;-1}*((N8:AP8-$N$5:$AP$6)/(N8:AP8*$N$5:$AP$5>0))>=0,"")),"OK","NG")

Kết thúc bằng Ctrl+Shift+Enter. Fill xuống.

Thân