GIÚP ĐỠ LÀM CÔNG THỨC CHỌN RA 2 TRONG 3 (2 người xem)

[giaydabo]

Dear anh chị em!

Em có công thức với điều kiện như sau: Mua 5 con vịt và 3 con gà, 3 con gà phải bắt buộc có 2 loại trong số 3 loại sau ( gà trống, gà mái, gà con) được giảm giá 10k.
File em gửi File đính kèm.
Anh chị tìm giúp em công thức để biết được sẽ được giảm giá bn tiền. Em xin cảm ơn ạ!

Bài đã được tự động gộp: 7/11/18

@HieuCD các bạn giúp mình với

 

[salam]

Không biết có đúng không?
=IF(AND(B5>4,SUM(C5:E5)>2,COUNT(C5:E5)>1),B5/5*10000,0)

 

[giaydabo]

@leonguyenz giúp mình nhé

 

[giaydabo]

Không biết có đúng không?
=IF(AND(B5>4,SUM(C5:E5)>2,COUNT(C5:E5)>1),B5/5*10000,0)

không đúng trong trường hợp này bạn ạ
VỊT GÀ TRỐNG GÀ MÁI GÀ CON SỐ TiỀN ĐƯỢC GiẢM
30 2 24 0 6

 

[salam]

không đúng trong trường hợp này bạn ạ
VỊT GÀ TRỐNG GÀ MÁI GÀ CON SỐ TiỀN ĐƯỢC GiẢM

=IF(AND(B5>4,SUM(C5:E5)>2,COUNT(C5:E5)>1),int(MIN(B5/5,SUM(C5:E5)/3))*10000,0)

 

[Phan Thế Hiệp]

Dear anh chị em!

Em có công thức với điều kiện như sau: Mua 5 con vịt và 3 con gà, 3 con gà phải bắt buộc có 2 loại trong số 3 loại sau ( gà trống, gà mái, gà con) được giảm giá 10k.
File em gửi File đính kèm.
Anh chị tìm giúp em công thức để biết được sẽ được giảm giá bn tiền. Em xin cảm ơn ạ!
@HieuCD các bạn giúp mình với

Thử:

F5=IF(COUNTIF(C5:E5,">0")>1,MIN(INT(SUM(C5:E5)/3),INT(B5/5)),)*10000

Enter fill xuống

Thân

 

[giaydabo]

Thử:

F5=IF(COUNTIF(C5:E5,">0")>1,MIN(INT(SUM(C5:E5)/3),INT(B5/5)),)*10000

Enter fill xuống

Thân

trường hợp dưới file đính kèm sẽ bị sai, bạn xem lại giúp tớ. cảm ơn b!

Bài đã được tự động gộp: 7/11/18

không đúng trong trường hợp này bạn ạ
VỊT GÀ TRỐNG GÀ MÁI GÀ CON SỐ TiỀN ĐƯỢC GiẢM

=IF(AND(B5>4,SUM(C5:E5)>2,COUNT(C5:E5)>1),int(MIN(B5/5,SUM(C5:E5)/3))*10000,0)

bạn xem file đính kèm, sẽ sai trong trường hợp này

 

[Phuocam]

VỊT GÀ TRỐNG GÀ MÁI GÀ CON
30-------0---------1--------3 0

Trường hợp này , theo bạn giảm bao nhiêu?

 

[giaydabo]

VỊT GÀ TRỐNG GÀ MÁI GÀ CON
30---------0---------1---------3 0

Trường hợp này , theo bạn giảm bao nhiêu?

t cũng chưa tìm ra công thức

 

[Phuocam]

t cũng chưa tìm ra công thức

Chỉ cần biết quả mong muốn của bạn, công thức các thành viên khác sẽ trợ giúp.

 

[giaydabo]

Chỉ cần biết quả mong muốn của bạn, công thức các thành viên khác sẽ trợ giúp.

Mua 5 con vịt và 3 con gà, 3 con gà phải bắt buộc có 2 loại trong số 3 loại sau ( gà trống, gà mái, gà con) được giảm giá 10k. t muốn biết sẽ được giảm bao nhiều tiền nếu mua theo cách này.

 

[Phan Thế Hiệp]

Mua 5 con vịt và 3 con gà, 3 con gà phải bắt buộc có 2 loại trong số 3 loại sau ( gà trống, gà mái, gà con) được giảm giá 10k. t muốn biết sẽ được giảm bao nhiều tiền nếu mua theo cách này.

Thử:

F5=IF(COUNTIF(C5:E5,">0")>1,MIN(SUM(AGGREGATE(15,6,C5:E5*1,{1,2})),INT(MAX(C5:E5)/2),INT(B5/5)),)*10000

Enter fill xuống

Thân

 

[giaydabo]

Thử:

F5=IF(COUNTIF(C5:E5,">0")>1,MIN(SUM(AGGREGATE(15,6,C5:E5*1,{1,2})),INT(MAX(C5:E5)/2),INT(B5/5)),)*10000

Enter fill xuống

Thân

bạn ơi! enter fill là ấn thế nào vậy? MÌnh vào xem công thức là hỏng ngay
bạn có thể giải thích giúp mình công thức được ko? Mình ko hiểu gì hết. hic
cảm ơn b!

 

[Phan Thế Hiệp]

bạn ơi! enter fill là ấn thế nào vậy? MÌnh vào xem công thức là hỏng ngay
bạn có thể giải thích giúp mình công thức được ko? Mình ko hiểu gì hết. hic
cảm ơn b!

Tôi thấy bài này giống với bài trước bạn hỏi và đã được anh @HieuCD chỉ công thức rồi.
Nay tôi vận dụng công thức đó thấy hay hơn công thức tôi làm ở bài #12

F5=MIN(INT(B5/5),IF(MAX(C5:E5)*2>SUM(C5:E5),SUM(C5:E5)-MAX(C5:E5),INT(SUM(C5:E5)/3)))*10000

Enter, copy xuống.

Thân

 

[Phuocam]

Góp vui:

=INT(MIN(B5/5,SUM(C5:E5)-MAX(C5:E5),SUM(C5:E5)/3))*10000

 

[sỉ thoọc]

Nhầm, sorry

 

[giaydabo]

Nếu vẫn là File này nhưng đề bài thay đổi là:
Mua số lượng 4 con trong 4 loại (vịt, gà trống, gà mái, gà con) với điều kiện tối thiểu có 3 loại trong 4 loại kia. thì sẽ có bao nhiêu cặp như thế?
mọi người xem file đính kèm nhé!

 

[HieuCD]

Nếu vẫn là File này nhưng đề bài thay đổi là:
Mua số lượng 4 con trong 4 loại (vịt, gà trống, gà mái, gà con) với điều kiện tối thiểu có 3 loại trong 4 loại kia. thì sẽ có bao nhiêu cặp như thế?
mọi người xem file đính kèm nhé!

F5=MIN(MAX(MIN(INT((SUM(B5:E5)-MAX(B5:E5))/2),MAX(B5:E5)),LARGE(B5:E5,2)),SUM(B5:E5)-SUM(LARGE(B5:E5,{1,2})))

 

[Phuocam]

Trường hợp 100 100 100 0 có kết quả là 75

=MIN(INT(SUM(B5:E5)/4),SUM(B5:E5)-SUM(LARGE(B5:E5,{1,2})))

 

[HieuCD]

Trường hợp 100 100 100 0 có kết quả là 75

=MIN(INT(SUM(B5:E5)/4),SUM(B5:E5)-SUM(LARGE(B5:E5,{1,2})))

11, 1, 1, 1 kết quả là 1
Chỉnh lại
=INT(MIN(SUM(B5:E5)/4,LARGE(B5:E5,2),SUM(B5:E5)-SUM(LARGE(B5:E5,{1,2}))))