Tách chuỗi: lấy Họ + Chữ lót + ký tự đầu của Tên (2 người xem)

[tucroiday]

Mình muốn lọc lấy họ tên ra như này: ví dụ: A1: Nguyễn Tuấn Anh; A2: Nguyễn Thị Quỳnh Vân ... -->> Thành: Nguyễn Tuấn A và Nguyễn Thị Quỳnh V. nghĩa là lấy chuỗi từ trước và ký tự đầu tiên của từ cuối cùng. Cao nhân nào biết cách chỉ dùm e với ạ!! Thanks!!!

 

[congnt92]

Mình muốn lọc lấy họ tên ra như này: ví dụ: A1: Nguyễn Tuấn Anh; A2: Nguyễn Thị Quỳnh Vân ... -->> Thành: Nguyễn Tuấn A và Nguyễn Thị Quỳnh V. nghĩa là lấy chuỗi từ trước và ký tự đầu tiên của từ cuối cùng. Cao nhân nào biết cách chỉ dùm e với ạ!! Cảm ơn!!!

- Đổi tên lại tiêu đề bài viết rõ ràng hơn vấn đề cần trợ giúp trước khi bài của bạn bị khóa
- Hướng giải quyết: tìm vị trí khoảng trắng cuối cùng, ví dụ đứng thứ 20 thì chuỗi cần lấy có độ dài 21 ký tự tính từ trái qua.

 

[salam]

{=LEFT(A1,MAX((MID(A1,ROW(INDIRECT("A1:A"&LEN(A1))),1)=" ")*ROW(INDIRECT("A1:A"&LEN(A1))))+1)}

 

[ndu96081631]

{=LEFT(A1,MAX((MID(A1,ROW(INDIRECT("A1:A"&LEN(A1))),1)=" ")*ROW(INDIRECT("A1:A"&LEN(A1))))+1)}

Thấy dùng công thức thường cũng được:

=LEFT(A1,FIND("*",SUBSTITUTE(A1," ","*",LEN(A1)-LEN(SUBSTITUTE(A1," ",""))))+1)

Cẩn thận chút thì thêm TRIM vào:

=LEFT(TRIM(A1),FIND("*",SUBSTITUTE(TRIM(A1)," ","*",LEN(TRIM(A1))-LEN(SUBSTITUTE(TRIM(A1)," ",""))))+1)

--------------------------------
Lâu lắm mới thấy bạn lên diễn đàn đó

 

[excel_lv1.5]

Mình muốn lọc lấy họ tên ra như này: ví dụ: A1: Nguyễn Tuấn Anh; A2: Nguyễn Thị Quỳnh Vân ... -->> Thành: Nguyễn Tuấn A và Nguyễn Thị Quỳnh V. nghĩa là lấy chuỗi từ trước và ký tự đầu tiên của từ cuối cùng. Cao nhân nào biết cách chỉ dùm e với ạ!! Cảm ơn!!!

CHo bạn thêm cách nữa:

=LEFT(TRIM(A1),LOOKUP(100,FIND(" ",TRIM(A1),ROW($1:$100)))+1)

 

[ndu96081631]

CHo bạn thêm cách nữa:

=LEFT(A1,LOOKUP(100,FIND(" ",A1,ROW($1:$100)))+1)

Dù không Ctrl + Shift + Enter nhưng đây vẫn là công thức mảng nha
Cẩn thận nếu chuỗi có khoảng trắng thừa. Nên thêm TRIM vào cho chắc ăn

 

[excel_lv1.5]

Dù không Ctrl + Shift + Enter nhưng đây vẫn là công thức mảng nha
Cẩn thận nếu chuỗi có khoảng trắng thừa. Nên thêm TRIM vào cho chắc ăn

Thì tôi đâu có nói là công thức thường
Đã sữa lại, thanks bạn!!

 

[Phan Thế Hiệp]

Mình muốn lọc lấy họ tên ra như này: ví dụ: A1: Nguyễn Tuấn Anh; A2: Nguyễn Thị Quỳnh Vân ... -->> Thành: Nguyễn Tuấn A và Nguyễn Thị Quỳnh V. nghĩa là lấy chuỗi từ trước và ký tự đầu tiên của từ cuối cùng. Cao nhân nào biết cách chỉ dùm e với ạ!! Cảm ơn!!!

Góp vui thêm với anh em đồng chí:

=LOOKUP("zzz",LEFT(TRIM(C6),FIND(" ",TRIM(C6),ROW($1:$100))+1))

Enter, fill xuống.
Thân

 

[befaint]

Một vé cho Flash Fill.

 

[tucroiday]

Tuyệt quá! cảm ơn các bạn rất nhiều!!!

 

[Lê Duy Thương]

Một vé cho Flash Fill.

cái này đúng ý tui nè.Dạo này công thức của tui bị lục rồi. vì toàn dùng đồ có sẵn.