Cần hỗ trợ hàm if(or chạy đủ các trường hợp (7 người xem)

[teechang306]

Chào mọi người, mình cần phân loại từng đơn hàng ( mỗi dòng là 1 đơn hàng) với điều kiện như sau: ô SLH (cột A)= HC hoặc HT hoặc NITA và số xe (cột I)= 51C-96006 hoặc 51c-96914 thì đươhc phân loại là đúng tải ở cột M. Mình đã thử làm công thức như sau
=IF(OR(A4&RIGHT(I4;5)="HC96006";A4&RIGHT(I4;5)="HC96914";A4&RIGHT(I4;5)="HT96006";A4&RIGHT(I4;5)="HT96914";A4&RIGHT(I4;5)="NITA96006";A4&RIGHT(I4;5)="NITA96194");" đúng tải";"x")

Nhưng hàm chạy không đủ các trường hợp và đối số hàm or quá nhìu, làm lâu dần file quá nặng, xử lý chậm. Mình mong người giúp đỡ mình cách xử lý ô công thức ở cột M ( phân loai), có hàm nào khác có thể rút gọn hơn không hay có phương pháp nào khác không.

Mình xài excel 2010 ( ko sử dụng được hàm ifs)
Mình cảm ơn mọi người.

 

[giaiphap]

Chào mọi người, mình cần phân loại từng đơn hàng ( mỗi dòng là 1 đơn hàng) với điều kiện như sau: ô SLH (cột A)= HC hoặc HT hoặc NITA và số xe (cột I)= 51C-96006 hoặc 51c-96914 thì đươhc phân loại là đúng tải ở cột M. Mình đã thử làm công thức như sau
=IF(OR(A4&RIGHT(I4;5)="HC96006";A4&RIGHT(I4;5)="HC96914";A4&RIGHT(I4;5)="HT96006";A4&RIGHT(I4;5)="HT96914";A4&RIGHT(I4;5)="NITA96006";A4&RIGHT(I4;5)="NITA96194");" đúng tải";"x")

Nhưng hàm chạy không đủ các trường hợp và đối số hàm or quá nhìu, làm lâu dần file quá nặng, xử lý chậm. Mình mong người giúp đỡ mình cách xử lý ô công thức ở cột M ( phân loai), có hàm nào khác có thể rút gọn hơn không hay có phương pháp nào khác không.

Mình xài excel 2010 ( ko sử dụng được hàm ifs)
Mình cảm ơn mọi người.

Bạn thử CT này cho ô M3 thử xem.

IF(ISNA(MATCH(A3&RIGHT(I3;5);{"HC96006";"HC96914";"HT96006";"HT96914";"NITA96006";"NITA96194"};0));"x";"DT")

 

[teechang306]

Bạn thử CT này cho ô M3 thử xem.

IF(ISNA(MATCH(A3&RIGHT(I3;5);{"HC96006";"HC96914";"HT96006";"HT96914";"NITA96006";"NITA96194"};0));"x";"DT")

Sáng nay mình chạy thử nhưng nó chỉ ra các trường hợp của xe 96006, vẫn bị thiếu các trường hợp của xe 96914. Bạn check lại giúp mình nhé. Mình cảm ơn.

 

[bebanhbeo]

Sáng nay mình chạy thử nhưng nó chỉ ra các trường hợp của xe 96006, vẫn bị thiếu các trường hợp của xe 96914. Bạn check lại giúp mình nhé. Mình cảm ơn.

Mình thấy công thức đã chạy đúng rồi mà ta !

 

[PhanQuynhVan471]

bổ ích quá

 

[teechang306]

tổng cộng kết quả theo bộ lọc là 19 trường hợp, phải bao gồm xe 96914 nữa. Mình chạy công thức thì xe 96914 vẫn bị đánh x, ko đc phân loại đúng tải

 

[giaiphap]

tổng cộng kết quả theo bộ lọc là 19 trường hợp, phải bao gồm xe 96914 nữa. Mình chạy công thức thì xe 96914 vẫn bị đánh x, ko đc phân loại đúng tải

Cái này không biết sao nửa, nhưng khi mình gõ tay lại số 96194 thì nó chạy bình thương.

=IF(ISNA(MATCH(A3&RIGHT(I3,5),{"HC96006","HC96194","HT96006","HT96194","NITA96006","NITA96194"},0)),"x","DT")

 

[teechang306]

Cái này không biết sao nửa, nhưng khi mình gõ tay lại số 96194 thì nó chạy bình thương.

=IF(ISNA(MATCH(A3&RIGHT(I3,5),{"HC96006","HC96194","HT96006","HT96194","NITA96006","NITA96194"},0)),"x","DT")

sao hình bạn chup phía trên lại không có kết quả của các số xe 96914 vậy, bạn có lọc bớt đi ko?

 

[giaiphap]

sao hình bạn chup phía trên lại không có kết quả của các số xe 96914 vậy, bạn có lọc bớt đi ko?

Tôi có up cái file nào lên đâu mà bạn nói. Còn nếu bạn nói #4 của @bebanhbeo thì bạn có nhìn kỷ cột nào đang lọc không vậy?

 

[teechang306]

Cái này không biết sao nửa, nhưng khi mình gõ tay lại số 96194 thì nó chạy bình thương.

=IF(ISNA(MATCH(A3&RIGHT(I3,5),{"HC96006","HC96194","HT96006","HT96194","NITA96006","NITA96194"},0)),"x","DT")

Mình đã thử lại trên file gốc thì đã chạy oke rùi nhé bạn, còn file nháp ko hiểu sao ra nó ko ra đủ trường hợp. Mình sẽ xem lại, cảm ơn bạn đã giúp đỡ mình gỡ rối.

 

[Ba Tê]

sao hình bạn chup phía trên lại không có kết quả của các số xe 96914 vậy, bạn có lọc bớt đi ko?

Ở đâu có số xe 51C-96914?
Tạo 1 bảng phụ ở đâu đó, dễ kiểm soát.

 

[teechang306]

Ở đâu có số xe 51C-96914?
Tạo 1 bảng phụ ở đâu đó, dễ kiểm soát.

tại file mình up lên là file nháp, còn file gốc làm việc nhiều bảng phụ kèm theo lắm. mình sợ tạo thêm bảng trông rối

 

[Ba Tê]

tại file mình up lên là file nháp, còn file gốc làm việc nhiều bảng phụ kèm theo lắm. mình sợ tạo thêm bảng trông rối

Chỉ cần 1 sheet chứa 100 cái bảng phụ.
Muốn thay đổi gì đó cứ vào sheet này mà chỉnh. Không dễ hơn chỉnh từng công thức?
Híc!

 

[teechang306]

Chỉ cần 1 sheet chứa 100 cái bảng phụ.
Muốn thay đổi gì đó cứ vào sheet này mà chỉnh. Không dễ hơn chỉnh từng công thức?
Híc!

Cảm ơn bạn Ba Tê nhiều lắm, mình sẽ chạy thử cách của bạn gợi ý.

 

[bebanhbeo]

Mình đã thử lại trên file gốc thì đã chạy oke rùi nhé bạn, còn file nháp ko hiểu sao ra nó ko ra đủ trường hợp. Mình sẽ xem lại, cảm ơn bạn đã giúp đỡ mình gỡ rối.

Do trong file gốccủa bạn là 51C-96194 mà bạn nói là 51C-96914
Mình đã sửa
công thức của anh giaiphap lại cho bạn rồi nha

 

[teechang306]

Do trong file gốccủa bạn là 51C-96194 mà bạn nói là 51C-96914
Mình đã sửa
công thức của anh giaiphap lại cho bạn rồi nha

đúng rùi, do gõ nhầm số xe nên hèn chi lúc đầu ko chạy ra đủ trường hợp. lúc sao đánh tay lại 2,3 lần thì được. thanks bạn, hehe

 

[ndu96081631]

Bạn thử CT này cho ô M3 thử xem.

IF(ISNA(MATCH(A3&RIGHT(I3;5);{"HC96006";"HC96914";"HT96006";"HT96914";"NITA96006";"NITA96194"};0));"x";"DT")

Có thể thay MATCH bằng COUNTIF thế này:

=IF(SUMPRODUCT(COUNTIF(A3,{"HT","HC","NITA"})*COUNTIF(I3,{"*96006";"*96194"})),"DT","x")

Hoặc chỉ SUMPRODUCT:

=IF(SUMPRODUCT(1*(A3&RIGHT(I3,5)={"HT","HC","NITA"}&{"96006";"96194"})),"DT","x")

Hoặc chỉ có hàm COUNT:

=IF(COUNT(1/(A3&RIGHT(I3,5)={"HT","HC","NITA"}&{"96006";"96194"})),"DT","x")

(công thức cuối phải Ctrl + Shift + Enter)
vân... vân... và hàng đống cách khác nữa

 

[teechang306]

Có thể thay MATCH bằng COUNTIF thế này:

=IF(SUMPRODUCT(COUNTIF(A3,{"HT","HC","NITA"})*COUNTIF(I3,{"*96006";"*96194"})),"DT","x")

Hoặc chỉ SUMPRODUCT:

=IF(SUMPRODUCT(1*(A3&RIGHT(I3,5)={"HT","HC","NITA"}&{"96006";"96194"})),"DT","x")

Hoặc chỉ có hàm COUNT:

=IF(COUNT(1/(A3&RIGHT(I3,5)={"HT","HC","NITA"}&{"96006";"96194"})),"DT","x")

(công thức cuối phải Ctrl + Shift + Enter)
vân... vân... và hàng đống cách khác nữa

mình ko rành về công thức mảng lắm, nhưng rất nhìêu công thức mới và ngắn gọn để tìm hiểu thêm. cảm ơn bạn rất nhiều.

 

[giaiphap]

Có thể thay MATCH bằng COUNTIF thế này:

=IF(SUMPRODUCT(COUNTIF(A3,{"HT","HC","NITA"})*COUNTIF(I3,{"*96006";"*96194"})),"DT","x")

Hoặc chỉ SUMPRODUCT:

=IF(SUMPRODUCT(1*(A3&RIGHT(I3,5)={"HT","HC","NITA"}&{"96006";"96194"})),"DT","x")

Hoặc chỉ có hàm COUNT:

=IF(COUNT(1/(A3&RIGHT(I3,5)={"HT","HC","NITA"}&{"96006";"96194"})),"DT","x")

(công thức cuối phải Ctrl + Shift + Enter)
vân... vân... và hàng đống cách khác nữa

Mới được bạn @Mộng Thường 2001 chỉ giúp công thức mảng, bây giờ được anh chỉ giúp nửa lại được học hỏi thêm.

 

[ndu96081631]

Mới được bạn @Mộng Thường 2001 chỉ giúp công thức mảng, bây giờ được anh chỉ giúp nửa lại được học hỏi thêm.

Cá là đại ca này người miền Nam (giống mình)
Ẹc... Ẹc...