Xin chỉ em cách truy xuất 1 mảng dữ liệu từ sheet khác (1 người xem)

[Duongcoss]

làm cách nào để lọc và in ra bảng kết quả ra Timkiem theo điều kiện Học Phần và Lớp từ các sheet dữ liệu khác nhau

 

[HieuCD]

A5 =INDEX(INDIRECT("'"&$B$1&"'!$A$4:$A$1000"),MATCH($B$2,INDIRECT("'"&$B$1&"'!$C$4:$C$1000"),0)+ROWS($1:1))

B5 =INDEX(INDIRECT("'"&$B$1&"'!$B$4:$B$1000"),MATCH($B$2,INDIRECT("'"&$B$1&"'!$C$4:$C$1000"),0)+ROWS($1:1))

C5 =INDEX(INDIRECT("'"&$B$1&"'!$C$4:$C$1000"),MATCH($B$2,INDIRECT("'"&$B$1&"'!$C$4:$C$1000"),0)+ROWS($1:1))

copy xuống

 

[Duongcoss]

Giải thích e m xíu đc ko ạ,rối quá

 

[Duongcoss]

Em coppy paste hiện lỗi Err:508

 

[HieuCD]

Em coppy paste hiện lỗi Err:508

mình đã chỉnh công thức lại, bạn chọn từng vùng trong công thức bấm phím chức năng F9 để xem kết quả của từng phần, giải thích công thức hơi khó

 

[Duongcoss]

Hình như chung 1 công thức phải ko ạ

 

[Duongcoss]

Nếu e thêm 1 cột mã số đằng trc cột tên thì sao ạ

 

[HieuCD]

Nếu e thêm 1 cột mã số đằng trc cột tên thì sao ạ

bạn cứ thêm và tự chỉnh cột trong lại công thức xem sao, lưu ý "'!$C$4:$C$1000" với C là cột lớp

 

[Duongcoss]

Mà a có thể giải thích sơ cho e hiểu đc ko ạ, biết công thức mà ko hiểu cũng v

 

[HieuCD]

Mà a có thể giải thích sơ cho e hiểu đc ko ạ, biết công thức mà ko hiểu cũng v

vídụ công thức tại ô A6 là tên SV thứ 2
=IF(ROWS($1:2)>COUNTIF(INDIRECT("'"&$B$1&"'!$C$4:$C$1000"),$B$2),"",INDEX(INDIRECT("'"&$B$1&"'!$A$4:$A$1000"),MATCH($B$2,INDIRECT("'"&$B$1&"'!$C$4:$C$1000"),0)+ROWS($1:2)-1))

INDIRECT("'"&$B$1&"'!$C$4:$C$1000") là địa chỉ dãy ô $C$4:$C$1000 của sheet qui định bởi ô B1

COUNTIF(INDIRECT("'"&$B$1&"'!$C$4:$C$1000"),$B$2) là đếm số SV của lớp (ô B2) trong sheet (ô B1)

ROWS($1:2) là SV thứ mấy? (kết quả là SV thứ 2), nếu lớn hơn số SV của lớp thì trả về ""

MATCH($B$2,INDIRECT("'"&$B$1&"'!$C$4:$C$1000"),0) tìm thứ tự dòng của SV đầu tiên trong lớp (ô B2) trong vùng dữ liệu $C$4:$C$1000

MATCH($B$2,INDIRECT("'"&$B$1&"'!$C$4:$C$1000"),0)+ROWS($1:2)-1
tìm thứ tự dòng của SV thứ 2 là dòng SV thứ 1 cộng cho 1= ROWS($1:2)-1, dùng làm tham số dòng cho hàm INDEX

 

[Duongcoss]

Hàm INDIRECT, e chưa hiểu lắm, giải thích xíu zùm e đc ko ạ

 

[Duongcoss]

em hiểu r, cám ơn ạ