Tính tổng với điều kiện (1 người xem)

[banhia]

Các a chị giúp em bài này với ạ, tự nhiên e không thể nghĩ ra

 

[Let'GâuGâu]

Các a chị giúp em bài này với ạ, tự nhiên e không thể nghĩ ra

tự nhiên không nghĩ ra thì từ từ suy nghĩ

=SUMPRODUCT(SUBSTITUTE(D4:D7,"A",0)*1)

 

[giaiphap]

D8 công thức như sau:

=SUMPRODUCT(--LEFT(D4:D7,3))

 

[nghiaphuc]

Các a chị giúp em bài này với ạ, tự nhiên e không thể nghĩ ra

Với dữ liệu như trong file (bên trái là phần số, bên phải chỉ có 1 chữ A) thì bạn có thể sử dụng công thức mảng sau:

=SUM(--SUBSTITUTE(D4:D7,"A",""))

Hoặc như sau nếu bên phải là 1 ký tự bất kỳ:

=SUM(--LEFT(D4:D7,LEN(D4:D7)-1))

Lưu ý: Nhớ kết thúc bằng tổ hợp Ctrl+Shift+Enter nhé.

 

[banhia]

Trường hợp, trước "A" không có giá trị gì thì sao các a chị ơi!

 

[banhia]

Với dữ liệu như trong file (bên trái là phần số, bên phải chỉ có 1 chữ A) thì bạn có thể sử dụng công thức mảng sau:

=SUM(--SUBSTITUTE(D4:D7,"A",""))

Hoặc như sau nếu bên phải là 1 ký tự bất kỳ:

=SUM(--LEFT(D4:D7,LEN(D4:D7)-1))

Lưu ý: Nhớ kết thúc bằng tổ hợp Ctrl+Shift+Enter nhé.

CHO EM HỎI, DẤU "--" Dùng trước công thức có ý nghĩa gì vậy ạ?

 

[giaiphap]

Trường hợp, trước "A" không có giá trị gì thì sao các a chị ơi!

Thì làm như #3, còn phía trước có dấu -- thay cho hàm Value

 

[nghiaphuc]

CHO EM HỎI, DẤU "--" Dùng trước công thức có ý nghĩa gì vậy ạ?

Nó có tác dụng tương tự hàm VALUE, nhằm chuyển một chuỗi số thành một số.

 

[banhia]

View attachment TÍNH TỔNG VỚI ĐIỀU KIỆN.xlsx
nếu bài toán của e nó thuộc dạng như file này, thì dùng công thức nào được ạ!

 

[banhia]

Nhờ giúp đỡ với dữ liệu dạng như file excel ạ!

 

[khuongvietphong]

View attachment 158555
nếu bài toán của e nó thuộc dạng như file này, thì dùng công thức nào được ạ!

Bạn dùng CT này:

=SUM(IFERROR(IF(FIND("A",C15:K15),--SUBSTITUTE(C15:K15,"A",(LEN(C15:K15)=1)*1)),0))

Kết thúc = 3 phím : CTRL+SHIFT+ENTER

 

[lenongree]

bạn thử Ct này!!!!!!

N15=SUM(IFERROR((FIND("A",$C$15:$K$15)>0)*(--SUBSTITUTE($C$15:$K$15,"A","")),0))

Ctrl+Shift+Enter

 

[khuongvietphong]

bạn thử Ct này!!!!!!

N15=SUM(IFERROR((FIND("A",$C$15:$K$15)>0)*(--SUBSTITUTE($C$15:$K$15,"A","")),0))

Ctrl+Shift+Enter

Công thức này của bạn hình như chưa cho kết quả đúng rồi

 

[lenongree]

Công thức này của bạn hình như chưa cho kết quả đúng rồi

Dạ, đúng rồi bị sai, để em chỉnh lại!!!

=SUM(IFERROR((FIND("A",$C$15:$K$15)>0)*(--SUBSTITUTE($C$15:$K$15,"A",IF(LEN($C$15:$K$15)=1,1,""))),0))

Ctrl+Shift+Enter

 

[HieuCD]

Bạn dùng CT này:

=SUM(IFERROR(IF(FIND("A",C15:K15),--SUBSTITUTE(C15:K15,"A",(LEN(C15:K15)=1)*1)),0))

Kết thúc = 3 phím : CTRL+SHIFT+ENTER

ô K15 nhập 2A ra kết quả 22 ?

 

[dhn46]

Góp vui 1 công thức nữa

=SUM(IFERROR((RIGHT(C15:K15,1)="A")*LEFT(C15:K15,LEN(C15:K15)-1),0))+COUNTIF(C15:K15,"A")

 

[khuongvietphong]

ô K15 nhập 2A ra kết quả 22 ?

ờ hén ,vậy thì sửa lại CT thế này cho chắc ăn luôn:

=SUM(IFERROR(IF(FIND("A",C15:K15),--SUBSTITUTE(C15:K15,"A",if(LEN(C15:K15)=1,1,""),0))