Giúp đỡ: Sử dụng kết hợp hàm vlookup với hàm index hoặc hàm match (1 người xem)

[loctnmt]

Chào mọi người!
Em đang kết công để làm lương. Bình thường nếu chỉ dùng hàm vlookup kể tính công mỗi ngày thì em chon từng vùng cụ thể, như vậy rất mất thời gian. Em muốn chon cả bảng tính chi tiết chấm công và dò với 2 điều kiện là mã số và ngày. Mọi người giúp em với ạ

 

[leonguyenz]

Sửa D2 thành dạng ngày tháng (01/11/2015), D4 dùng công thức:

=LOOKUP(2,1/('CHI TIẾT CHẤM CÔNG'!$B$5:$B$1000=$C4)/('CHI TIẾT CHẤM CÔNG'!$C$5:$C$1000=D$2),'CHI TIẾT CHẤM CÔNG'!$D$5:$D$1000)

VLOOKUP và INDEX không sử dụng được cho bảng chấm công như file đính kèm.

 

[thangbithu]

Sửa D2 thành dạng ngày tháng (01/11/2015), D4 dùng công thức:

=LOOKUP(2,1/('CHI TIẾT CHẤM CÔNG'!$B$5:$B$1000=$C4)/('CHI TIẾT CHẤM CÔNG'!$C$5:$C$1000=D$2),'CHI TIẾT CHẤM CÔNG'!$D$5:$D$1000)

VLOOKUP và INDEX không sử dụng được cho bảng chấm công như file đính kèm.

INDEX và MATCH sử dụng được chứ leonguyenz, chỉ có điều phải sử dụng hàm mảng thôi

 

[leonguyenz]

INDEX và MATCH sử dụng được chứ leonguyenz, chỉ có điều phải sử dụng hàm mảng thôi

INDEX mảng nhiều điều kiện cũng mệt.

=INDEX('CHI TIẾT CHẤM CÔNG'!$D$5:$D$45,MATCH($C4&D$2,'CHI TIẾT CHẤM CÔNG'!$B$5:$B$45&'CHI TIẾT CHẤM CÔNG'!$C$5:$C$45,0))

Ctrl+Shift+Enter

 

[thangbithu]

INDEX mảng nhiều điều kiện cũng mệt.

=INDEX('CHI TIẾT CHẤM CÔNG'!$D$5:$D$45,MATCH($C4&D$2,'CHI TIẾT CHẤM CÔNG'!$B$5:$B$45&'CHI TIẾT CHẤM CÔNG'!$C$5:$C$45,0))

Ctrl+Shift+Enter

Cảm ơn leonguyenz nhé, mình định đưa công thức lên nhưng sợ chủ thớt rối nên thôi.
leonguyenz khỏe không?

 

[doveandrose]

Chào mọi người!
Em đang kết công để làm lương. Bình thường nếu chỉ dùng hàm vlookup kể tính công mỗi ngày thì em chon từng vùng cụ thể, như vậy rất mất thời gian. Em muốn chon cả bảng tính chi tiết chấm công và dò với 2 điều kiện là mã số và ngày. Mọi người giúp em với ạ

làm vầy cho nó khiêu gợi . hí hí

=OFFSET('CHI TIẾT CHẤM CÔNG'!$D$4,MATCH($C4,$C$4:$C$8,0)+(COUNTA($C$4:$C$8)+1)*(D$2-1),0)

 

[leonguyenz]

Cảm ơn leonguyenz nhé, mình định đưa công thức lên nhưng sợ chủ thớt rối nên thôi.
leonguyenz khỏe không?

Cảm ơn anh, em khoẻ ạ!

Cần gì mảng cũng được mà. Enter thường thử xem

 =INDEX('CHI TIẾT CHẤM  CÔNG'!$D$5:$D$45,INDEX(MATCH($C4&D$2,'CHI TIẾT CHẤM  CÔNG'!$B$5:$B$45&'CHI TIẾT CHẤM CÔNG'!$C$5:$C$45,0),0))

Cơ chế hoạt động như hàm mảng rồi, kể cả LOOKUP như trên.

 

[hoamattroicoi]

INDEX mảng nhiều điều kiện cũng mệt.

=INDEX('CHI TIẾT CHẤM CÔNG'!$D$5:$D$45,MATCH($C4&D$2,'CHI TIẾT CHẤM CÔNG'!$B$5:$B$45&'CHI TIẾT CHẤM CÔNG'!$C$5:$C$45,0))

Ctrl+Shift+Enter

Thế này bấm Enter cho nó khỏe này anh, khỏi lo hỏng bàn phím và tay nó mềm

=INDEX('CHI TIẾT CHẤM CÔNG'!$D$5:$D$45,MATCH($C4&D$2,INDEX('CHI TIẾT CHẤM CÔNG'!$B$5:$B$45&'CHI TIẾT CHẤM CÔNG'!$C$5:$C$45,0),0))

 

[thangbithu]

Thế này bấm Enter cho nó khỏe này anh, khỏi lo hỏng bàn phím và tay nó mềm

=INDEX('CHI TIẾT CHẤM CÔNG'!$D$5:$D$45,MATCH($C4&D$2,INDEX('CHI TIẾT CHẤM CÔNG'!$B$5:$B$45&'CHI TIẾT CHẤM CÔNG'!$C$5:$C$45,0),0))

Đúng là cao thủ, hàm lạ quá

 

[thangbithu]

làm vầy cho nó khiêu gợi . hí hí

=OFFSET('CHI TIẾT CHẤM CÔNG'!$D$4,MATCH($C4,$C$4:$C$8,0)+(COUNTA($C$4:$C$8)+1)*(D$2-1),0)

Mình thích công thức này, không tổng quát nhưng doveandrose nghiên cứu bài toán rất kỹ

 

[thangbithu]

Mà lạ ta:
Công thức số #6 của hpkhuong
=INDEX('CHI TIẾT CHẤM CÔNG'!$D$5:$D$45,INDEX(MATCH($C4&D$2,'CHI TIẾT CHẤM CÔNG'!$B$5:$B$45&'CHI TIẾT CHẤM CÔNG'!$C$5:$C$45,0),0))
Với công thức số #9 của hoamattroicoi
=INDEX('CHI TIẾT CHẤM CÔNG'!$D$5:$D$45,MATCH($C4&D$2,INDEX('CHI TIẾT CHẤM CÔNG'!$B$5:$B$45&'CHI TIẾT CHẤM CÔNG'!$C$5:$C$45,0),0))
nghịch đảo nhau mà công thức nào cũng chạy tốt, anh chị nào có thể giúp mình hiểu rõ hơn 2 công thức này không nhỉ?

 

[VetMini]

Hàm INDEX có khả năng trả về hoặc trực tiếp (value - trị của 1 cell), hoặc gián tiếp (reference - 1 mảng).