Cách dùng hàm sumifs nhiều điều kiện (1 người xem)

[kugura]

Chào các bạn, mình có thắc mắc bài toán này là làm thế nào dùng hàm sumifs để tính tổng thành tiền của xi măng và ván ép, cũng như của gạch men và sắt.

p/s : mình hỉ biết dùng hàm sumifs để tính tổng của 1 mặt hàng ak, còn 2 mặt hàng thì mình chưa biết cách lập công thức. Mong nhận được sự giúp đỡ của các bạn.
Cảm ơn mọi người.

 

[nhat chi mai]

Chào các bạn, mình có thắc mắc bài toán này là làm thế nào dùng hàm sumifs để tính tổng thành tiền của xi măng và ván ép, cũng như của gạch men và sắt.

p/s : mình hỉ biết dùng hàm sumifs để tính tổng của 1 mặt hàng ak, còn 2 mặt hàng thì mình chưa biết cách lập công thức. Mong nhận được sự giúp đỡ của các bạn.
Cảm ơn mọi người.

Dùng sumif cho đơn giản bạn ạ

 

[leonguyenz]

Mấy dạng bài này thường là dùng DSUM. Vì các trung tâm tin học, hay ở các trường thường đưa hàm dữ liệu vào giảng dạy, ít khi đưa hàm SUMIFS (một hàm mảng được đưa vào Excel 2007 trở lên). Đặt điều kiện ở F20:F23, công thức:

=DSUM($A$3:$J$10,J$3,F20:F22)

 

[leonguyenz]

Muốn sử dụng SUMIFS như bài này thì viết điều kiện loại dần (áp dụng cho trường hợp ít mã hàng), công thức:

=SUMIFS(J4:J10,F4:F10,"<>G*",F4:F10,"<>S*")

Tương tự với câu còn lại:

=SUMIFS(J4:J10,F4:F10,"<>X*",F4:F10,"<>V*")

(* là ký tự đại diện).

 

[kugura]

Cảm ơn tất cả các bạn rất nhiều.

 

[phamkhacni]

Đối với SUMIFS thì k dùng được công thức bên trong, như hàm MID
Em mún cộng những mẫu tin có 0000 liên tiếp thì phải làm sao: TE1930000030092, TE1720000021129...
Các bác giúp em với ạ

 

[leonguyenz]

Đối với SUMIFS thì k dùng được công thức bên trong, như hàm MID
Em mún cộng những mẫu tin có 0000 liên tiếp thì phải làm sao: TE1930000030092, TE1720000021129...
Các bác giúp em với ạ

Dùng dấu * làm đại diện các ký tự còn lại.
Bạn đưa file lên chứ ngồi đoán mò mất thời gian lắm.

 

[nghiaphuc]

Đối với SUMIFS thì k dùng được công thức bên trong, như hàm MID
Em mún cộng những mẫu tin có 0000 liên tiếp thì phải làm sao: TE1930000030092, TE1720000021129...
Các bác giúp em với ạ

Giả sử vùng dữ liệu chứ mấy cái 00000 đó là A1:A100, vùng chứa số liệu để cộng là B1:B100. Khi đó công thức sẽ là:

=SUMPRODUCT((MID(A1:A100,6,5)="00000")*B1:B100)

 

[phamkhacni]

A B C D E
Văn 1991 TE1930000030092 500 A
Bò 1990 TE1930000030084 200 A

=sumifs(D14,E1:E4,"A",B1:B4,"1990") và điều kiện mid(C1,8,3)=000
=sumifs(D14,E1:E4,"A",B1:B4,"1990") và điều kiện mid(C1,8,3)=000

Mục đích của em là thế đó ạ, nhờ các bác giúp với

 

[leonguyenz]

A B C D E
Văn 1991 TE1930000030092 500 A
Bò 1990 TE1930000030084 200 A

=sumifs(D14,E1:E4,"A",B1:B4,"1990") và điều kiện mid(C1,8,3)=000
=sumifs(D14,E1:E4,"A",B1:B4,"1990") và điều kiện mid(C1,8,3)=000

Mục đích của em là thế đó ạ, nhờ các bác giúp với

Sử dụng SUMPRODUCT thêm điều kiện khác vào:
=sumproduct((e1:e4="A")*(b1:b4=1990)*(mid(c1:c4,8,3)="000")*d1:d4)

 

[phamkhacni]

Các bác giúp em vấn đề Đếm và Tổng với nhiều điều kiện với ạ
Em mài mò mấy ngày nay mà vẫn k được
Hàm SUMIFS nó k hiểu điều kiện là HÀM
Đính kèm tập tin và yêu cầu đó ạ

 

[nghiaphuc]

Các bác giúp em vấn đề Đếm và Tổng với nhiều điều kiện với ạ
Em mài mò mấy ngày nay mà vẫn k được
Hàm SUMIFS nó k hiểu điều kiện là HÀM
Đính kèm tập tin và yêu cầu đó ạ

Công thức như sau:

[D14]=SUMPRODUCT((MID($C$2:$C$7,8,3)="000")*($F$2:$F$7=0)*($H$2:$H$7="3"))

[D15]=SUMPRODUCT((MID($C$2:$C$7,8,3)="000")*($F$2:$F$7=0)*($H$2:$H$7="3")*$E$2:$E$7)

 

[phamkhacni]

Công thức như sau:

[D14]=SUMPRODUCT((MID($C$2:$C$7,8,3)="000")*($F$2:$F$7=0)*($H$2:$H$7="3"))

[D15]=SUMPRODUCT((MID($C$2:$C$7,8,3)="000")*($F$2:$F$7=0)*($H$2:$H$7="3")*$E$2:$E$7)

Cảm ơn bác rất nhiều, để em ứng dụng vào thực tế của em,hj.
Em dùng sumifs mãi k được

 

[Phuocam]

Cảm ơn bác rất nhiều, để em ứng dụng vào thực tế của em,hj.
Em dùng sumifs mãi k được

Thử dủng SUMIFS:
D14: =SUMIFS(G2:G7,C2:C7,"???????000*",F2:F7,"0",H2:H7,"3")
D15: =SUMIFS(E2:E7,C2:C7,"???????000*",F2:F7,"0",H2:H7,"3")
Thân!

 

[phamkhacni]

Do dữ liệu lớn em dùng hàm SUMPRODUCT nó chạy cực chậm.
Giờ em mún quay về SUMIFS, mà lại vướn ngay ở điều kiện SUM: là SUM điều kiện rỗng NULL
Các bác giúp em tính tổng với hàm SUMIFS với điều kiện rỗng và k rỗng với ạ

 

[whenyougone]

View attachment De 6.xlsx Có ai giúp mình bài này với không ? Tính tổng số lượng ấy,mình dùng hàm sumifs thì ra nhưng phải đặt 1 cột month bất tiện quá

 

[Ba Tê]

View attachment 112562 Có ai giúp mình bài này với không ? Tính tổng số lượng ấy,mình dùng hàm sumifs thì ra nhưng phải đặt 1 cột month bất tiện quá

Công thức ô H16:

=SUMIFS($D$3:$D$12;$E$3:$E$12;$G16;$B$3:$B$12;">="& DATE(2009;COLUMNS($A:G);1);$B$3:$B$12;"<" & DATE(2009;COLUMNS($A:H);1))

Ô G16 phải nhập giống như ô B16 (hiện đang không giống nhau - ẩu)

 

[luu thao]

Cả nhà giúp em vụ này với ạ:
- Trong file có 2 sheet "Hopdong" và "Giaohang"
- Em muốn đặt công thức tính tại Cột "SL giao" trong sheet "Hop dong": bằng tổng các lần giao hàng trong sheet "Giaohang" với điều kiện tên HD và tên hang hoa giống nhau.
Cả nhà giúp em với ạ, Em cảm ơn nhiều <3

 

[Ba Tê]

Cả nhà giúp em vụ này với ạ:
- Trong file có 2 sheet "Hopdong" và "Giaohang"
- Em muốn đặt công thức tính tại Cột "SL giao" trong sheet "Hop dong": bằng tổng các lần giao hàng trong sheet "Giaohang" với điều kiện tên HD và tên hang hoa giống nhau.
Cả nhà giúp em với ạ, Em cảm ơn nhiều <3

Trong File thấy bạn biết sử dụng "hàng đống Name" (rác).
Giờ thì ở sheet Giaohang, bạn đặt Name SoHD cho cột B, Name HangHoa cho cột C và Name SLG cho cột E
Trong sheet Hopdong, ô I2 nhập công thức:

=SUMIFS(SLG;SoHD;B2;HangHoa;D2)

 

[luu thao]

Trong File thấy bạn biết sử dụng "hàng đống Name" (rác).
Giờ thì ở sheet Giaohang, bạn đặt Name SoHD cho cột B, Name HangHoa cho cột C và Name SLG cho cột E
Trong sheet Hopdong, ô I2 nhập công thức:

=SUMIFS(SLG;SoHD;B2;HangHoa;D2)

Hihi, được rồi ạ, vậy mà sáng nay e mò Sumifs mãi không ra.
Em cảm ơn bác Cội Gạo nhé!
Tái bàn phím: Em xóa hết name rác đi rầu