Tạo cột dãy số tăng dần từ 2 hay nhiều dãy số (1 người xem)

[Hidden2562]

Mình đang có nhiều dãy số từ A ->B, hiện tại mình cần lôi chi tiết từng số ra và sắp xếp theo hàng dọc, có công thức hay cách nào để mình làm nhanh hơn không ạ vì data của mình rất nhiều, nếu làm tay thì không nỗi .

Dãy số của mình có lúc liên tục và có lúc không liên tục ạ, không cố định.

VD:
Mình có 2 dãy số: 1 -> 3, 8 -> 12
Kết quả mong muốn:
1
2
3
8
9
10
11
12

Cảm ơn các bạn.

 

[SA_DQ]

Tiêu đề nên là:
"Tạo cột dẫy số tăng (hay giảm) dần từ 2 hay nhiều dẫy (số)

em xin lỗi ạ, lâu lâu mới đăng bài mong anh thông cảm

Bạn sửa lại tiêu đề & sẽ nhanh chóng hơn để nhận được kết quả trợ giúp!

 

[Hidden2562]

Tiêu đề nên là:
"Tạo cột dẫy số tăng (hay giảm) dần từ 2 hay nhiều dẫy (số)

em xin lỗi ạ, lâu lâu mới đăng bài mong anh thông cảm

 

[Binbo2020]

Mình đang có nhiều dãy số từ A ->B, hiện tại mình cần lôi chi tiết từng số ra và sắp xếp theo hàng dọc, có công thức hay cách nào để mình làm nhanh hơn không ạ vì data của mình rất nhiều, nếu làm tay thì không nỗi .
VD:
Mình có 2 dãy số: 1 -> 3, 8 -> 12
Kết quả mong muốn:
1
2
3
8
9
10
11
12

Cảm ơn các bạn.

Thứ nhất bạn nên sửa lại tiêu đề bài viết cho đúng với nội quy của diễn đàn

Thứ 2 dãy số của bạn có liên tục không hay kiểu 5-10, 15-16, 23-34

Bài đã được tự động gộp: 9/6/21

em xin lỗi ạ, lâu lâu mới đăng bài mong anh thông cảm

Bạn vào nút này là sửa được mà

 

[Hidden2562]

Thứ nhất bạn nên sửa lại tiêu đề bài viết cho đúng với nội quy của diễn đàn
View attachment 260279
Thứ 2 dãy số của bạn có liên tục không hay kiểu 5-10, 15-16, 23-34

Bài đã được tự động gộp: 9/6/21

Bạn vào nút này là sửa được mà View attachment 260280

mình đã sử tiêu đề rồi ạ.

dãy số của mình có lúc liên tục và có lúc không liên tục ạ, không cố định.

 

[Binbo2020]

dãy số của mình có lúc liên tục và có lúc không liên tục ạ, không cố định

Tạm thời thế này, chờ xem ai có cách hay hơn không

H2=IF(AND(H1>=SMALL($C$3:$C$5;IFERROR(MATCH(H1;$D$2:$D$5);1));H1<SMALL($D$3:$D$5;IFERROR(MATCH(H1;$D$2:$D$5);1)));H1+1;SMALL($C$3:$C$5;IFERROR(MATCH(H1;$D$2:$D$5);1)))

 

[Hidden2562]

Tạm thời thế này, chờ xem ai có cách hay hơn không

H2=IF(AND(H1>=SMALL($C$3:$C$5;IFERROR(MATCH(H1;$D$2:$D$5);1));H1<SMALL($D$3:$D$5;IFERROR(MATCH(H1;$D$2:$D$5);1)));H1+1;SMALL($C$3:$C$5;IFERROR(MATCH(H1;$D$2:$D$5);1)))

mình bấm nó không ra kết quả

 

[Binbo2020]

mình bấm nó không ra kết quả

Bấm kiểu gì vậy không ra kết quả thì nó ra cái gì phải nói mới biết chứ

Bài đã được tự động gộp: 9/6/21

Hoặc không nghịch kiểu mảng thế này (tiếp tục học hàm MMULT bạn @Phan Thế Hiệp dạy)

=IFERROR(AGGREGATE(15;6;ROW($A$1:$A$100)/MMULT((ROW($A$1:$A$100)>=SMALL($C$3:$C$5;{1\2\3}))*(ROW($A$1:$A$100)<=SMALL($D$3:$D$5;{1\2\3}));{1;1;1});ROW(A1));"")

 

[Hidden2562]

Bấm kiểu gì vậy không ra kết quả thì nó ra cái gì phải nói mới biết chứ

Bài đã được tự động gộp: 9/6/21

Hoặc không nghịch kiểu mảng thế này (tiếp tục học hàm MMULT bạn @Phan Thế Hiệp dạy)

=IFERROR(AGGREGATE(15;6;ROW($A$1:$A$100)/MMULT((ROW($A$1:$A$100)>=SMALL($C$3:$C$5;{1\2\3}))*(ROW($A$1:$A$100)<=SMALL($D$3:$D$5;{1\2\3}));{1;1;1});ROW(A1));"")

hình như dãy số không theo thứ tự bé -> lớn thì không dùng được công thức của bạn được phải không ạ
VD:
Dãy số:
7 -> 15
2 -> 5
18 -> 20

 

[Binbo2020]

hình như dãy số không theo thứ tự bé -> lớn thì không dùng được công thức của bạn được phải không ạ
VD:
Dãy số:
7 -> 15
2 -> 5
18 -> 20

Hàm thứ 2 làm được việc đấy, bạn không thử à

 

[Hidden2562]

Hàm thứ 2 làm được việc đấy, bạn không thử à
View attachment 260294

hix, excel của mình báo lỗi chỗ hàm small (1\2\3) ấy, bạn giúp mình với
À, mà nếu data của mình trên >10000 dòng
Thanks

 

[befaint]

excel của mình báo lỗi chỗ hàm small (1\2\3)

Đổi dấu phân cách cho giống của người ta ấy.

Nếu rành mấy cái dấu phân cách đó thì chấm phẩy thành phẩy, xược xược thành phẩy.

 

[Binbo2020]

À, mà nếu data của mình trên >10000 dòng

Dữ liệu lớn thế thì bạn nên nhờ người viết VBA nhé, hàm thế này là khoai chạy như rùa đấy

 

[HieuCD]

View attachment 260295
hix, excel của mình báo lỗi chỗ hàm small (1\2\3) ấy, bạn giúp mình với
À, mà nếu data của mình trên >10000 dòng
Thanks

Khoảng 16000 dòng

=IFERROR(AGGREGATE(15,6,COLUMN($A:$XAA)/(COLUMN($A:$XAA)>=$C$3:$C$5)/(COLUMN($A:$XAA)<=$D$3:$D$5),ROWS($1:1)),"")

 

[Hidden2562]

Khoảng 16000 dòng

=IFERROR(AGGREGATE(15,6,COLUMN($A:$XAA)/(COLUMN($A:$XAA)>=$C$3:$C$5)/(COLUMN($A:$XAA)<=$D$3:$D$5),ROWS($1:1)),"")

Hix, mình có dãy seri này nhưng sao công thức nó chạy vậy ạ , 1 file data của mình gồm nhiều dãy seri giống như vậy ấy
Thanks anh.

 

[Binbo2020]

COLUMN($A:$XAA)>=$C$3:$C$5

Hix cái đoạn này lúc đầu viết thế này row(A1:A10)>=$C$3:$C$5 không được quên không đảo lại, phần mảng vẫn mù mờ quá

 

[HieuCD]

Hix, mình có dãy seri này nhưng sao công thức nó chạy vậy ạ , 1 file data của mình gồm nhiều dãy seri giống như vậy ấy
Thanks anh.

Chỉ xét 4 số cuối vì giới hạn bởi khoảng 16000 dòng

=IFERROR(LEFT($C$3,7)&AGGREGATE(15,6,COLUMN($A:$XAA)/(COLUMN($A:$XAA)>=--RIGHT($C$3:$C$5,4))/(COLUMN($A:$XAA)<=--RIGHT($D$3:$D$5,4)),ROWS($1:1)),"")

 

[Hidden2562]

Chỉ xét 4 số cuối vì giới hạn bởi khoảng 16000 dòng

=IFERROR(LEFT($C$3,7)&AGGREGATE(15,6,COLUMN($A:$XAA)/(COLUMN($A:$XAA)>=--RIGHT($C$3:$C$5,4))/(COLUMN($A:$XAA)<=--RIGHT($D$3:$D$5,4)),ROWS($1:1)),"")

không lấy hết toàn bộ số được hả anh, nhiều khi có dãy seri đầu số 20, 21, 22,.... á. Có cách nào khác không ạ
Thanks anh

 

[Binbo2020]

không lấy hết toàn bộ số được hả anh, nhiều khi có dãy seri đầu số 20, 21, 22,.... á. Có cách nào khác không ạ

Sao bạn không đưa hẳn dãy số thật của bạn lên đi, bao nhiêu dãy, bao nhiêu trường hợp. Cứ đoạn một thế này người sửa oải lắm

 

[Hidden2562]

Sao bạn không đưa hẳn dãy số thật của bạn lên đi, bao nhiêu dãy, bao nhiêu trường hợp. Cứ đoạn một thế này người sửa oải lắm

Hi, mình xin lỗi, cho mình gửi lại file nhé

Chỉ xét 4 số cuối vì giới hạn bởi khoảng 16000 dòng

=IFERROR(LEFT($C$3,7)&AGGREGATE(15,6,COLUMN($A:$XAA)/(COLUMN($A:$XAA)>=--RIGHT($C$3:$C$5,4))/(COLUMN($A:$XAA)<=--RIGHT($D$3:$D$5,4)),ROWS($1:1)),"")

 

[Binbo2020]

data của mình trên >10000 dòng

Cái này của bạn tính ra là gần 73.000 dòng đấy, số lớn nhất và nhỏ nhất chênh nhau gần 4 triệu dòng. Các cách trên đều phá sản vì vượt quá giới hạn dòng và cột trong excel rồi

 

[Hidden2562]

Cái này của bạn tính ra là gần 73.000 dòng đấy, số lớn nhất và nhỏ nhất chênh nhau gần 4 triệu dòng. Các cách trên đều phá sản vì vượt quá giới hạn dòng và cột trong excel rồi

đâu có, nếu mình kéo hết là khoảng 73.000 dòng thôi ạ. Em chỉ muốn lấy chi tiết theo thứ tự từ Seri này đến Seri này thôi, chứ không phải liên tục từ số Seri nhỏ nhất tới lớn nhất ạ.

 

[Binbo2020]

đâu có, nếu mình kéo hết là khoảng 73.000 dòng thôi ạ. Em chỉ muốn lấy chi tiết theo thứ tự từ Seri này đến Seri này thôi, chứ không phải liên tục từ số Seri nhỏ nhất tới lớn nhất ạ.

Hai cái mã này đang lồng vào nhau này

nếu không có trường hợp này bạn có thể sắp xếp lại cột "Đến Seri" từ nhỏ đến lớn xong dùng cái công thức đầu tiên của mình ấy

 

[HieuCD]

Hi, mình xin lỗi, cho mình gửi lại file nhé

Các con số quá lớn vượt quá 4 số, phải xếp thứ tự theo cột C

F2 =C3

F3 =IF(IFERROR(MATCH(F1,$D$3:$D$523),0)=IFERROR(MATCH(F2,$D$3:$D$23),0),F2+1,INDEX($C$3:$C$23,IFERROR(MATCH(F2,$D$3:$D$23),0)+1))

Copy F3 xuống đến khi lỗi dừng lại

 

[excel_lv1.5]

Hi, mình xin lỗi, cho mình gửi lại file nhé

Dùng công thức này ở M2 bấm ctrl+shift+enter kéo đến khi nào lỗi thì dừng, công thức này không cần sort , cho phép các số seri lồng nhau:

=IF(OR((M1>=$C$3:$C$23)*($D$3:$D$23>M1)),M1+1,1/(1/MIN(IF($C$3:$C$23>M1,$C$3:$C$23))))

 

[HieuCD]

Dùng công thức này ở M2 bấm ctrl+shift+enter kéo đến khi nào lỗi thì dừng, công thức này không cần sort , cho phép các số seri lồng nhau:

=IF(OR((M1>=$C$3:$C$23)*($D$3:$D$23>M1)),M1+1,1/(1/MIN(IF($C$3:$C$23>M1,$C$3:$C$23))))

Công thức hay quá, nhưng gặp dữ liệu chồng lấn nên tính dư khá nhiều

 

[excel_lv1.5]

Công thức hay quá, nhưng gặp dữ liệu chồng lấn nên tính dư khá nhiều

View attachment 260353

Với số seri trên thì tổng số phải là 72.556 (đã loại trùng), tôi chạy bằng power query đã loại trùng cũng là số đó, do seri bị chồng nên công thức của bạn nó bị tính thiếu , bạn xem hình số 2 là những số công thức bạn chạy thiếu nó thuộc seri từ 22001433001->22001453180