Công thức gom danh mục hợp đồng theo tuần (1 người xem)

[hml89]

Gửi các anh,chị, em trong diễn đàn.
Em đang có một khó khăn nhờ các anh,chị và các bạn giúp đỡ.
Ở phần Báo cáo, mong các anh, chị giúp đỡ em công thức để gom danh mục Hợp Đồng của 3 công đoạn xử lý theo điều kiện tuần ở ô k1.

Em xin cám ơn ạ.

 

[befaint]

gom danh mục Hợp Đồng

Cột phụ cũng được chứ sao. Không làm sao, mà còn tốt vì công thức đỡ nặng hơn.

Thêm cột phụ H
=COUNTIF($E3:$G3,$K$1)>0
Rồi dựa vào cột phụ này để lọc cột A, dùng hàm index + aggreate là được.

 

[hml89]

Cột phụ cũng được chứ sao. Không làm sao, mà còn tốt vì công thức đỡ nặng hơn.

Vâng ạ. Mong nhận được sự giúp đỡ của anh ở phần gom danh mục với ạ. Em có nhớ là có bài gom kiểu này rồi mà em tìm mãi không thấy.

 

[befaint]

Vâng ạ. Mong nhận được sự giúp đỡ của anh ở phần gom danh mục với ạ. Em có nhớ là có bài gom kiểu này rồi mà em tìm mãi không thấy.

Đọc mấy chủ đề của cô công chúa này xem.

 

[hml89]

Đọc mấy chủ đề của cô công chúa này xem.

View attachment 259917

Thưa anh, em vẫn chưa thấy có chủ đề phù hợp.

 

[Binbo2020]

Thưa anh, em vẫn chưa thấy có chủ đề phù hợp.

Bạn thử nghiên cứu hàm mmult trong bài này xem, thấy tương tự
https://www.giaiphapexcel.com/diend...hời-gian-không-trùng-nhau.155592/post-1027935

 

[befaint]

Thưa anh, em vẫn chưa thấy có chủ đề phù hợp.

Đọc bài nào mà kêu chưa thấy?

Truy xuất dữ liệu định kì

Em chào anh/chị. Em đang có một vấn đề liên quan đến bài toán truy xuât dữ liệu mong được anh chị giúp đỡ ạ. Bên Sheet SP là báo cáo số lượng xuất kho hàng ngày Bên Sheet TH là tổng hợp báo cáo định kì theo thời gian từng khách hàng Kết quả em mong muốn: Khi lựa chọn thời gian cần tra cứu và...

www.giaiphapexcel.com

 

[Binbo2020]

Mong nhận được sự giúp đỡ

Bài này có năm khác không nhỉ hay chỉ một năm thôi

Bài đã được tự động gộp: 3/6/21

Đọc bài nào mà kêu chưa thấy

Chắc đang tìm công thức không dùng cột phụ nhìn cho hoa mắt

 

[befaint]

Chắc đang tìm công thức không dùng cột phụ nhìn cho hoa mắt

Bạn ấy muốn bớt cột nhìn cho thoáng, còn có cột phụ cũng không sao vì phục vụ công việc thực tế. Miễn giải quyết được việc là được.

 

[hml89]

Bài này có năm khác không nhỉ hay chỉ một năm thôi

Bài đã được tự động gộp: 3/6/21

Chắc đang tìm công thức không dùng cột phụ nhìn cho hoa mắt

Có cả năm khác bạn ạ. Những mã hợp đồng bị tồn đọng của năm khác vẫn có.

 

[Binbo2020]

Miễn giải quyết được việc là được

Bình thường với những bài phức tạp mình cũng thích dùng cột phụ cho dễ đọc công thức, làm công thức khủng lâu lâu mới đọc lại mất thời gian tư duy lại nếu cần sửa.

 

[hml89]

Bạn ấy muốn bớt cột nhìn cho thoáng, còn có cột phụ cũng không sao vì phục vụ công việc thực tế. Miễn giải quyết được việc là được.

J3=IFERROR(INDEX($A$3:$A$13,AGGREGATE(15,6,ROW($A$3:$A$13)/($E$3:$E$13=$K$1)/($F$3:$F$13=$K$1)/($G$3:$G$13=$K$1)/(COUNTIF($J$2:J2,$A$3:$A$13)=0),1)),"")
Không phải, em làm nó không ra nên em không biết như nào.
Nhưng kể bớt cột phụ thì nó thoáng thật anh ạ, trong trường hợp dữ nguyên cột phụ cũng không làm sao anh ạ.

 

[hocexcel_1991]

Gửi các anh,chị, em trong diễn đàn.
Em đang có một khó khăn nhờ các anh,chị và các bạn giúp đỡ.
Ở phần Báo cáo, mong các anh, chị giúp đỡ em công thức để gom danh mục Hợp Đồng của 3 công đoạn xử lý theo điều kiện tuần ở ô k1.

Em xin cám ơn ạ.

Nếu không muốn dùng cột phụ thì dùng công thức này:

J3=IFERROR(INDEX($A$3:$A$13,AGGREGATE(15,6,ROW($1:$100)/SIGN(MMULT(N(WEEKNUM($B$3:$D$13+0)=$K$1),{1;1;1})),ROWS(J$2:J2))),"")
K3=IFERROR(INDEX($B$3:$D$13/(WEEKNUM($B$3:$D$13+0)=$K$1),MATCH($J3,$A$3:$A$13,),RIGHT(K$2)+0),"")

 

[befaint]

J3=IFERROR(INDEX($A$3:$A$13,AGGREGATE(15,6,ROW($A$3:$A$13)/($E$3:$E$13=$K$1)/($F$3:$F$13=$K$1)/($G$3:$G$13=$K$1)/(COUNTIF($J$2:J2,$A$3:$A$13)=0),1)),"")
Không phải, em làm nó không ra nên em không biết như nào.
Nhưng kể bớt cột phụ thì nó thoáng thật anh ạ, trong trường hợp dữ nguyên cột phụ cũng không làm sao anh ạ.

Làm trong file ở bài #7 rồi đó.

 

[Binbo2020]

Có cả năm khác bạn ạ. Những mã hợp đồng bị tồn đọng của năm khác vẫn có.

Thử thế này xem ổn không

=IFERROR(INDEX($A$3:$A$13;AGGREGATE(15;6;ROW($A$1:$A$100)/(MMULT(1*(WEEKNUM(DATE(YEAR($B$3:$D$13);MONTH($B$3:$D$13);DAY($B$3:$D$13)))=$K$1);{1;1;1})>0);ROW(A1)));"")

Bài đã được tự động gộp: 3/6/21

WEEKNUM($B$3:$D$13+0)

Cho mình hỏi chút cái hàm này sao không có +0 thì báo lỗi mà có+0 lại chạy được nhỉ, cái này chưa biết

 

[hocexcel_1991]

Cho mình hỏi chút cái hàm này sao không có +0 thì báo lỗi mà có+0 lại chạy được nhỉ, cái này chưa biết

Cái này mình học từ anh @Phan Thế Hiệp nên mình cũng không rõ, chắc phải nhờ anh ấy giải thích .

 

[Binbo2020]

chắc phải nhờ anh ấy giải thích

Viết không được đâm ra lồng vào cái hàm date làm dài quá. Chưa gặp kiểu này lần nào

 

[hml89]

Đọc bài nào mà kêu chưa thấy?

Truy xuất dữ liệu định kì

Em chào anh/chị. Em đang có một vấn đề liên quan đến bài toán truy xuât dữ liệu mong được anh chị giúp đỡ ạ. Bên Sheet SP là báo cáo số lượng xuất kho hàng ngày Bên Sheet TH là tổng hợp báo cáo định kì theo thời gian từng khách hàng Kết quả em mong muốn: Khi lựa chọn thời gian cần tra cứu và...

www.giaiphapexcel.com

Em cám ơn anh nhiều ạ.

 

[befaint]

Cho mình hỏi chút cái hàm này sao không có +0 thì báo lỗi mà có+0 lại chạy được nhỉ, cái này chưa biết

weeknum nếu truyền vào Range thì lỗi, dùng mảng số thì được.
Range+0 --> Mảng

 

[hml89]

Nếu không muốn dùng cột phụ thì dùng công thức này:

J3=IFERROR(INDEX($A$3:$A$13,AGGREGATE(15,6,ROW($1:$100)/SIGN(MMULT(N(WEEKNUM($B$3:$D$13+0)=$K$1),{1;1;1})),ROWS(J$2:J2))),"")
K3=IFERROR(INDEX($B$3:$D$13/(WEEKNUM($B$3:$D$13+0)=$K$1),MATCH($J3,$A$3:$A$13,),RIGHT(K$2)+0),"")

Cám ơn bạn nhiều ạ. Nhưng công thức mình chưa gặp kiểu này. Đoạn này SIGN(MMULT(N(WEEKNUM($B$3:$D$13+0)=$K$1),{1;1;1})) khó hiểu quá bạn ạ

 

[hocexcel_1991]

Viết không được đâm ra lồng vào cái hàm date làm dài quá. Chưa gặp kiểu này lần nào

Cám ơn bạn nhiều ạ. Nhưng công thức mình chưa gặp kiểu này. Đoạn này SIGN(MMULT(N(WEEKNUM($B$3:$D$13+0)=$K$1),{1;1;1})) khó hiểu quá bạn ạ

Hàm SIGN chuyển số 0->0, 1,2,3,..->1
Hàm MMULT là hàm ma trận, bạn có thể tham khảo file này của anh @Phan Thế Hiệp.
Thêm công thức này bạn có thể tham khảo nếu không muốn dùng MMULT:

=INDEX($A$3:$A$13,AGGREGATE(15,6,ROW($1:$11)/(COUNTIF(J$12:J12,$A$3:$A$13)=0)/(WEEKNUM($B$3:$D$13+0)=$K$1),1))

 

[HUONGLIEN6577]

Gửi các anh,chị, em trong diễn đàn.
Em đang có một khó khăn nhờ các anh,chị và các bạn giúp đỡ.
Ở phần Báo cáo, mong các anh, chị giúp đỡ em công thức để gom danh mục Hợp Đồng của 3 công đoạn xử lý theo điều kiện tuần ở ô k1.

Em xin cám ơn ạ.

Góp thêm một cách để bạn tham khảo. Làm bằng VBA => Không phải dùng cột phụ và không cần công thức, dữ liệu có thể rất dài dến hàng trăm ngàn dòng.
Nếu phát triển thêm có thể dò tìm trong khoảng thời gian nào đó ( từ tuần x đến tuần y).
Cót két là học mót của anh chị em trên diễn đàn.

 

[hml89]

Góp thêm một cách để bạn tham khảo. Làm bằng VBA => Không phải dùng cột phụ và không cần công thức, dữ liệu có thể rất dài dến hàng trăm ngàn dòng.
Nếu phát triển thêm có thể dò tìm trong khoảng thời gian nào đó ( từ tuần x đến tuần y).
Cót két là học mót của anh chị em trên diễn đàn.

Cám ơn bạn nhiều ạ.

Bài đã được tự động gộp: 4/6/21

Hàm SIGN chuyển số 0->0, 1,2,3,..->1
Hàm MMULT là hàm ma trận, bạn có thể tham khảo file này của anh @Phan Thế Hiệp.
Thêm công thức này bạn có thể tham khảo nếu không muốn dùng MMULT:

=INDEX($A$3:$A$13,AGGREGATE(15,6,ROW($1:$11)/(COUNTIF(J$12:J12,$A$3:$A$13)=0)/(WEEKNUM($B$3:$D$13+0)=$K$1),1))

Cám ơn bạn nhiều ạ. Mình đã tìm hiểu file giải thích MMULT, có trường hợp thì mình cũng hiểu ra,có trường hợp MMULT(3) thì mình chưa rõ lắm, tuy nhiên mình sẽ đọc và tìm hiểu thêm.