Tìm giá trị tiệm cận của 1 số trong bảng dữ liệu và trả về giá trị tương ứng (1 người xem)

[ancrayzy]

Chào ace cộng đồng GPE,
Mình đang gặp vấn đề sau, mong mọ người giải đáp giúp nhé
Bài toán:
Mình cần tìm giá trị tiệm cận của ô D2 trong cột A2 -> A10, sao đó trả về giá trị tương ứng trong cột B2 -> B10.
Cảm ơn mọi người.

 

[CHAOQUAY]

Chào ace cộng đồng GPE,
Mình đang gặp vấn đề sau, mong mọ người giải đáp giúp nhé
Bài toán:
Mình cần tìm giá trị tiệm cận của ô D2 trong cột A2 -> A10, sao đó trả về giá trị tương ứng trong cột B2 -> B10.
Cảm ơn mọi người.

View attachment 250720

E2=INDEX($B$2:$B$10,COUNTIF($A$2:$A$10,"<="&$D$2)+1)
E4=INDEX($B$2:$B$10,COUNTIF($A$2:$A$10,"<="&$D$2))

Thêm IFERROR() nếu cần

 

[Phuocam]

Chào ace cộng đồng GPE,
Mình đang gặp vấn đề sau, mong mọ người giải đáp giúp nhé
Bài toán:
Mình cần tìm giá trị tiệm cận của ô D2 trong cột A2 -> A10, sao đó trả về giá trị tương ứng trong cột B2 -> B10.
Cảm ơn mọi người.

View attachment 250720

Trường hợp bạn nhập giá trị 15 trong ô D2 thì kết quả cận trên, cận dưới là gì?

 

[ancrayzy]

Trường hợp bạn nhập giá trị 15 trong ô D2 thì kết quả cận trên, cận dưới là gì?

Giá trị sẽ bằng 8 đó bạn. Như hình mình hoa mình có ghi rõ

Bài đã được tự động gộp: 7/12/20

E2=INDEX($B$2:$B$10,COUNTIF($A$2:$A$10,"<="&$D$2)+1)
E4=INDEX($B$2:$B$10,COUNTIF($A$2:$A$10,"<="&$D$2))

Thêm IFERROR() nếu cần

Cảm ơn bạn nhiều .
Nhưng nếu nhập D2 bằng giá trị của cột A2 -> A10 thì mình phải thêm công thức như thế nào vậy bạn.
Ví dụ: mình nhập ô D2 bằng 15 thì giá trị của E2 và E4 cùng bằng 17

 

[CHAOQUAY]

...
Nhưng nếu nhập D2 bằng giá trị của cột A2 -> A10 thì mình phải thêm công thức như thế nào vậy bạn.
Ví dụ: mình nhập ô D2 bằng 15 thì giá trị của E2 và E4 cùng bằng 17

Kết quả mong muốn của bạn là thế nào

 

[bomberman211]

Chào ace cộng đồng GPE,
Mình đang gặp vấn đề sau, mong mọ người giải đáp giúp nhé
Bài toán:
Mình cần tìm giá trị tiệm cận của ô D2 trong cột A2 -> A10, sao đó trả về giá trị tương ứng trong cột B2 -> B10.
Cảm ơn mọi người.

E2=INDEX(B2:B10,MATCH(MIN(IF(A2:A10<=D2,10^100,ABS(A2:A10-D2))),IF(A2:A10<=D2,10^100,ABS(A2:A10-D2)),0))
E4=INDEX(B2:B10,MATCH(MIN(IF(A2:A10>=D2,10^100,ABS(A2:A10-D2))),IF(A2:A10>=D2,10^100,ABS(A2:A10-D2)),0))
Kết thúc bằng Ctrl+Shift+Enter nhé. Hàm này dùng được trong cả trường hợp dữ liệu của bạn chưa được sắp xếp tăng dần.

 

[VetMini]

Trường hợp bạn nhập giá trị 15 trong ô D2 thì kết quả cận trên, cận dưới là gì?

Tiệm cận dưới dùng VLOOKUP căn bản.
Tiệm cận trên dùng Index/Match tiệm cận dưới, với Index trệch một dòng.

 

[ancrayzy]

E2=INDEX(B2:B10,MATCH(MIN(IF(A2:A10<=D2,10^100,ABS(A2:A10-D2))),IF(A2:A10<=D2,10^100,ABS(A2:A10-D2)),0))
E4=INDEX(B2:B10,MATCH(MIN(IF(A2:A10>=D2,10^100,ABS(A2:A10-D2))),IF(A2:A10>=D2,10^100,ABS(A2:A10-D2)),0))
Kết thúc bằng Ctrl+Shift+Enter nhé. Hàm này dùng được trong cả trường hợp dữ liệu của bạn chưa được sắp xếp tăng dần.

vẫn chưa được bạn. mình có áp công thức trên vào E3 và E5 nhưng không đúng

 

[bomberman211]

View attachment 250741
vẫn chưa được bạn. mình có áp công thức trên vào E3 và E5 nhưng không đúng

Ủa mình tưởng tiệm cận dưới là 8 mới đúng chứ, 17 là bằng rồi chứ đâu còn gọi là tiệm cận nữa? Nếu "tiệm cận" dưới là 17 thì "tiệm cận" trên cũng phải là 17 chứ hả?
Nếu muốn vậy thì bạn đổi <=, >= trong hàm thành <,> là được:

E2=INDEX(B2:B10,MATCH(MIN(IF(A2:A10<D2,10^100,ABS(A2:A10-D2))),IF(A2:A10<D2,10^100,ABS(A2:A10-D2)),0))
E4=INDEX(B2:B10,MATCH(MIN(IF(A2:A10>D2,10^100,ABS(A2:A10-D2))),IF(A2:A10>D2,10^100,ABS(A2:A10-D2)),0))

 

[Nhattanktnn]

Ủa mình tưởng tiệm cận dưới là 8 mới đúng chứ, 17 là bằng rồi chứ đâu còn gọi là tiệm cận nữa? Nếu "tiệm cận" dưới là 17 thì "tiệm cận" trên cũng phải là 17 chứ hả?
Nếu muốn vậy thì bạn đổi <=, >= trong hàm thành <,> là được:

E2=INDEX(B2:B10,MATCH(MIN(IF(A2:A10<D2,10^100,ABS(A2:A10-D2))),IF(A2:A10<D2,10^100,ABS(A2:A10-D2)),0))
E4=INDEX(B2:B10,MATCH(MIN(IF(A2:A10>D2,10^100,ABS(A2:A10-D2))),IF(A2:A10>D2,10^100,ABS(A2:A10-D2)),0))

Này chắc gọn hơn tí:

=INDEX(B2:B10,AGGREGATE(14,6,ROW(B1:B9)/(A2:A10<=D2),1))
=INDEX(B2:B10,AGGREGATE(15,6,ROW(B1:B9)/(A2:A10>=D2),1))

 

[ancrayzy]

Này chắc gọn hơn tí:

=INDEX(B2:B10,AGGREGATE(14,6,ROW(B1:B9)/(A2:A10<=D2),1))
=INDEX(B2:B10,AGGREGATE(15,6,ROW(B1:B9)/(A2:A10>=D2),1))

Tuyệt vời quá, cảm ơn bạn rất nhiều

 

[bomberman211]

Này chắc gọn hơn tí:

=INDEX(B2:B10,AGGREGATE(14,6,ROW(B1:B9)/(A2:A10<=D2),1))
=INDEX(B2:B10,AGGREGATE(15,6,ROW(B1:B9)/(A2:A10>=D2),1))

Hehe, tại đề bài chưa nói rõ là dữ liệu thực tế của thớt đã được sắp xếp hay chưa nên mình mới phải đi đường dài đó mà.

 

[phuongvq123]

Vào muộn quá cũng đóng góp chút

 

[Nhattanktnn]

Vào muộn quá cũng đóng góp chút

Nếu đã dùng:

=AGGREGATE(15,6,($B$2:$B$10)/($A$2:$A$10>=$D$2),1)

Thì dùng luôn:

=AGGREGATE(14,6,($B$2:$B$10)/($A$2:$A$10<=$D$2),1)

Nhưng chú ý, công thức này tôi đã nghĩ ra nhưng không dùng tại vì nó bắt buộc cả A và B đều phải được sắp xếp
A là cột dò lấy trong khoảng nên khả năng A được sắp xếp là rất cao (theo dữ liệu giả cũng vậy), nhưng B là giá trị cần lấy, có thể có khả năng nó không được sắp xếp