Tính tổng số trận thắng, hòa bằng COUNTIFS. (3 người xem)

[khacdinh2003]

làm sao tính tổng số trận thắng, hòa, thua từng đội trong file này ạ, em counifs hoài không ra

 

[HUONGHCKT]

làm sao tính tổng số trận thắng, hòa, thua từng đội trong file này ạ, em counifs hoài không ra

Tham khảo cách củ chuối này xem sao:
Thêm 1 cột phụ ví dụ cột J :
J4=G4-H4
Cột D (D18xx) chỉ có tên các đội
Thắng: E18=COUNTIFS($D$4:$D$15,D18,$J$4:$J$15,">0")
Thua: F18= COUNTIFS($D$4:$D$15,D18,$J$4:$J$15,"<0")
Hòa: G18= COUNTIFS($D$4:$D$15,D18,$J$4:$J$15,0)

 

[OverAC]

Lần sau lưu ý cách đặt tên tiêu đề bài nha. @khacdinh2003

 

[Duy Tùng 9x]

làm sao tính tổng số trận thắng, hòa, thua từng đội trong file này ạ, em counifs hoài không ra

Nếu bạn dùng Office365 thì khá đơn giản Điểm số tính theo trận thắng, hòa, thua lần lượt 3, 1, 0

=LET(H,HSTACK,L,TOCOL,c,E4:E15,d,IMREAL(c&"i"),e,-IMAGINARY(c&"i"),a,L(H(d,e)),b,L(H(e,d)),g,L(IFS(d-e=0,1,(d-e)*{1,-1}>0,3,1,0)),H(SEQUENCE(4),SORT(GROUPBY(L(H(D4:D15,F4:F15)),H(g,N(g=3),N(g=1),N(g=0),a,b,a-b),SUM,,0),{2,8,6,7},-1)))

 

[Phan Thế Hiệp]

làm sao tính tổng số trận thắng, hòa, thua từng đội trong file này ạ, em counifs hoài không ra

1/ Excel trước 365:
D23: D26 chứa tên các đội "A;B;C;D"

• Thắng: ô E23

  =COUNT(1/(MMULT(--MID($E$4:$E$15,{1,2},{1,2}),{1;1})/(($D23=$D$4:$D$15)-($D23=$F$4:$F$15))>0))

  Fill xuống.
• Thua: ô F23

  =COUNT(1/(MMULT(--MID($E$4:$E$15,{1,2},{1,2}),{1;1})/(($D23=$D$4:$D$15)-($D23=$F$4:$F$15))<0))

  Fill xuống.
• Hòa: ô G23

  =COUNT(1/(MMULT(--MID($E$4:$E$15,{1,2},{1,2}),{1;1})/(($D23=$D$4:$D$15)-($D23=$F$4:$F$15))=0))

  Fill xuống.

2/ Excel 365: ô E23

=LET(a,MMULT(--MID($E$4:$E$15,{1,2},{1,2}),{1;1})/(($D23=$D$4:$D$15)-($D23=$F$4:$F$15)),BYCOL((1/HSTACK(a>0,a<0,a=0)),LAMBDA(x,COUNT(x))))

Fill xuống.

Thân

 

[khacdinh2003]

Lần sau lưu ý cách đặt tên tiêu đề bài nha. @khacdinh2003

dạ ad

1/ Excel trước 365:
D23: D26 chứa tên các đội "A;B;C;D"

• Thắng: ô E23

  =COUNT(1/(MMULT(--MID($E$4:$E$15,{1,2},{1,2}),{1;1})/(($D23=$D$4:$D$15)-($D23=$F$4:$F$15))>0))

  Fill xuống.
• Thua: ô F23

  =COUNT(1/(MMULT(--MID($E$4:$E$15,{1,2},{1,2}),{1;1})/(($D23=$D$4:$D$15)-($D23=$F$4:$F$15))<0))

  Fill xuống.
• Hòa: ô G23

  =COUNT(1/(MMULT(--MID($E$4:$E$15,{1,2},{1,2}),{1;1})/(($D23=$D$4:$D$15)-($D23=$F$4:$F$15))=0))

  Fill xuống.

2/ Excel 365: ô E23

=LET(a,MMULT(--MID($E$4:$E$15,{1,2},{1,2}),{1;1})/(($D23=$D$4:$D$15)-($D23=$F$4:$F$15)),BYCOL((1/HSTACK(a>0,a<0,a=0)),LAMBDA(x,COUNT(x))))

Fill xuống.

Thân

dạ em cảm ơn bác nhiều