Tìm thứ trong tuần (3 người xem)

[buiduytandat79]

Em chào Anh chị ạ.
Em có 1 file đính kèm, từ ETD có dữ liệu là ngày/tháng/năm ( đang định dạng là văn bản) em muốn tìm được thứ trong tuần, và sau khi tìm được thứ trong tuần thì sẽ tìm ra được ngày/tháng/năm của tuần kế tiếp và tháng kế tiếp.
Ví dụ ngày 11.04.2025: Tìm và cho ra kết quả 1 là thứ 6 ; kết quả 2 là 18.04.2025
Em cảm ơn anh chị nhiều ạ

 

[minhminh27]

Bạn tìm hiểu hàm WEEKDAY để trả về "thứ trong tuần".
Chưa hiểu ý ngày/tháng/năm của tháng kế tiếp,
Đoán, tuần kế tiếp có phải là + 7 ngày, tháng kế tiếp +28 hay 30 ngày không?

 

[vietduc147258]

Để đơn giản thì Ctrl+H -> rồi thay dấu "." thành dấu "/" là đổi định dạng text sang date rồi. Khâu còn lại tự nghiên cứu nha. không rành mấy cái hàm này lắm

 

[minhminh27]

nếu chỉ muốn chuyển dấu "." thành dấu "/" thì dùng hàm SUBSTITUTE thay replace (Ctrl =H) là được

 

[HUONGHCKT]

Em chào Anh chị ạ.
Em có 1 file đính kèm, từ ETD có dữ liệu là ngày/tháng/năm ( đang định dạng là văn bản) em muốn tìm được thứ trong tuần, và sau khi tìm được thứ trong tuần thì sẽ tìm ra được ngày/tháng/năm của tuần kế tiếp và tháng kế tiếp.
Ví dụ ngày 11.04.2025: Tìm và cho ra kết quả 1 là thứ 6 ; kết quả 2 là 18.04.2025
Em cảm ơn anh chị nhiều ạ

Tham khảo:
F4=WEEKDAY(TEXT(LEFT(D4;2)&
"/"&MID(D4;4;2)&"/"&RIGHT(D4;4);"dd/mm/yyyy");2)
G4=TEXT(LEFT(D4;2)&"/"&MID(D4;4;2)&"/"&RIGHT(D4;4);"dd/mm/yyyy")+7
Copy cho các ô còn lại.
Thay đổi dấu ";" thành dấu phù họp với máy bạn.
nghiên cứu thêm hàm choose()

 

[vietduc147258]

nếu chỉ muốn chuyển dấu "." thành dấu "/" thì dùng hàm SUBSTITUTE thay replace (Ctrl =H) là được

nhờ gợi ý này mà làm được yêu cầu của chủ thớt rồi.
ô F4

=CHOOSE(WEEKDAY(SUBSTITUTE(D8,".","/")),"Chủ nhật","Thứ 2","Thứ 3","Thứ 4","Thứ 5","Thứ 6","Thứ 7")

Ô G4

=EDATE(SUBSTITUTE(D4,".","/"),0)+7

 

[Phan Thế Hiệp]

Em chào Anh chị ạ.
Em có 1 file đính kèm, từ ETD có dữ liệu là ngày/tháng/năm ( đang định dạng là văn bản) em muốn tìm được thứ trong tuần, và sau khi tìm được thứ trong tuần thì sẽ tìm ra được ngày/tháng/năm của tuần kế tiếp và tháng kế tiếp.
Ví dụ ngày 11.04.2025: Tìm và cho ra kết quả 1 là thứ 6 ; kết quả 2 là 18.04.2025
Em cảm ơn anh chị nhiều ạ

Dùng Substitute() thay dấu "." bằng dấu "/" (Vd: 11.04.2025 thành 11/04/2025) chỉ ra kết quả đúng cho các máy cài mặc định ngày theo VN, công thức sẽ báo lỗi khi qua các máy cài mặc định theo dạng khác. Nên cẩn thận khi dùng cách thay thế này.

Để an toàn và có thể sử dụng cho các máy cài mặc định ngày khác nhau nên dùng hàm Date(y,m,d), như sau:

1/ ô F4:

=TEXT(DATE(RIGHT(D4,4),MID(D4,4,2),LEFT(D4,2)),"[$-42A]dddd")

Hoặc thêm mắm dậm muối:

=TEXT(DATE(RIGHT(D4,4),MID(D4,4,2),LEFT(D4,2)),"[$-42A]dddd, dd/mm/yyyy")

2/ ô G4: đơn giản chỉ cộng thêm 7

=DATE(RIGHT(D4,4),MID(D4,4,2),LEFT(D4,2))+7

3/ ô H4:

=EDATE(DATE(RIGHT(D4,4),MID(D4,4,2),LEFT(D4,2)),1)

Tôi dùng hàm Text(...,"[$-42A]dddd") chia sẻ với anh em mới vào sau này biết thêm 1 điều lý thú, và cũng nhằm để tôi nhớ về huyền thoại của diễn đàn GPE vang bóng 1 thời: Thầy NDU.

Thân