Tìm số sổ BHYT (1 người xem)

[anchoi_85]

Mình có 1 file 2 shee1,
sheet 1 chứa họ và tên và ngày tháng năm sinh.
Sheet 2 chứa họ và tên và ngày tháng năm sinh và số sổ BHYT

*. Từ sheet 1 viết công thức nào để so sánh ngày tháng năm sinh sheet1 với sheet2 giống nhau thì lấy số sổ BHYT.

Ai hướng dẫn mình với

 

[befaint]

b2=IF(YEAR(--E2)>1905,LOOKUP(2,1/(D2=Sheet2!$A$2:$A$271)/(E2=Sheet2!$B$2:$B$271),Sheet2!$D$2:$D$271),LOOKUP(2,1/(D2=Sheet2!$A$2:$A$271)/(--E2=YEAR(--Sheet2!$B$2:$B$271)),Sheet2!$D$2:$D$271))

 

[quocgiacan]

b2=IF(YEAR(--E2)>1905,LOOKUP(2,1/(D2=Sheet2!$A$2:$A$271)/(E2=Sheet2!$B$2:$B$271),Sheet2!$D$2:$D$271),LOOKUP(2,1/(D2=Sheet2!$A$2:$A$271)/(--E2=YEAR(--Sheet2!$B$2:$B$271)),Sheet2!$D$2:$D$271))

Góp vui với em nè:

Anh biết là em có thử đưa điều kiện để chọn 1 trong hai (E2=Sheet2!$B$2:$B$271) hoặc (--E2=YEAR(--Sheet2!$B$2:$B$271)) vào phía trong, nhưng Lookup() nó hổng chịu phải không? Vậy em chơi theo kiểu vầy nha, coi nó có chịu phục tùng ý em nha hôn:

B2=IFERROR(LOOKUP(2,1/(D2=Sheet2!$A$2:$A$271)/IF(YEAR(--E2)>1905,[B]INDEX([/B]E2=Sheet2!$B$2:$B$271[B],)[/B],[B]INDEX([/B]--E2=--Sheet2!$B$2:$B$271[B],)[/B]),Sheet2!$D$2:$D$271),"")

Enter fill xuống. Khà khà! hổng có 2 cái INDEX(,) phải nhấn tổ hợp phím mảng.

Chúc em ngày cuối tuần thiệt vui.
p/s: anh thấy để con trỏ sau /QUOTE] Enter gần gũỉ với cách anh hay xài. Cảm ơn em.

 

[befaint]

Góp vui với em nè:

Anh biết là em có thử đưa điều kiện để chọn 1 trong hai (E2=Sheet2!$B$2:$B$271) hoặc (--E2=YEAR(--Sheet2!$B$2:$B$271)) vào phía trong, nhưng Lookup() nó hổng chịu phải không? Vậy em chơi theo kiểu vầy nha, coi nó có chịu phục tùng ý em nha hôn:

B2=IFERROR(LOOKUP(2,1/(D2=Sheet2!$A$2:$A$271)/IF(YEAR(--E2)>1905,[B]INDEX([/B]E2=Sheet2!$B$2:$B$271[B],)[/B],[B]INDEX([/B]--E2=--Sheet2!$B$2:$B$271[B],)[/B]),Sheet2!$D$2:$D$271),"")

Enter fill xuống. Khà khà! hổng có 2 cái INDEX(,) phải nhấn tổ hợp phím mảng.

Chúc em ngày cuối tuần thiệt vui.
p/s: anh thấy để con trỏ sau /QUOTE] Enter gần gũỉ với cách anh hay xài. Cảm ơn em.

Sao anh biết... Em thử mấy lần thấy không "ăn thua" thế là bê ra ngoài

Cảm ơn anh.

Chúc anh tối vui!

 

[quocgiacan]

Sao anh biết... Em thử mấy lần thấy không "ăn thua" thế là bê ra ngoài

Cảm ơn anh.

Chúc anh tối vui!

Làm anh mà không hiểu ý của em là "dỡ" lắm, đáng cho xuống chức.

Khà khà khà,

Chúc em buổi tối ngủ ngon giấc.

 

[eke_rula]

Mình có 1 file 2 shee1,
sheet 1 chứa họ và tên và ngày tháng năm sinh.
Sheet 2 chứa họ và tên và ngày tháng năm sinh và số sổ BHYT

*. Từ sheet 1 viết công thức nào để so sánh ngày tháng năm sinh sheet1 với sheet2 giống nhau thì lấy số sổ BHYT.

Ai hướng dẫn mình với

Bạn dùng thử CT này xem:

B2=IFERROR(LOOKUP(2,1/(D2=Sheet2!$A$2:$A$271)/(IFERROR(--("01/01/"&E2),E2)=Sheet2!$B$2:$B$271),Sheet2!$D$2:$D$271),"")

Fill xuống!!!

 

[HieuCD]

lạ nhỉ, tại sao lại không dùng công thức đơn giản hơn, không lẽ có bí mật gì chăng?

=IFERROR(LOOKUP(2,1/(D2=Sheet2!$A$2:$A$271)/(E2=Sheet2!$B$2:$B$271),Sheet2!$D$2:$D$271),"")

 

[quocgiacan]

lạ nhỉ, tại sao lại không dùng công thức đơn giản hơn, không lẽ có bí mật gì chăng?

=IFERROR(LOOKUP(2,1/(D2=Sheet2!$A$2:$A$271)/(E2=Sheet2!$B$2:$B$271),Sheet2!$D$2:$D$271),"")

Bạn hiền bỏ đi đâu mất biệt mấy bửa..

Do số liệu ngày sinh năm sinh của chủ thớt rất "thoải mái" "ngẫu hứng lý qua cầu" lắm nên công thức mới rắc rối đó mà.

Khà khà! Chưa ngủ hả!

Vậy chúc ngủ ngon vậy.

 

[eke_rula]

Mình có 1 file 2 shee1,
sheet 1 chứa họ và tên và ngày tháng năm sinh.
Sheet 2 chứa họ và tên và ngày tháng năm sinh và số sổ BHYT

*. Từ sheet 1 viết công thức nào để so sánh ngày tháng năm sinh sheet1 với sheet2 giống nhau thì lấy số sổ BHYT.

Ai hướng dẫn mình với

Có lẽ CT này đúng hơn:

B2=IFERROR(LOOKUP(2,SEARCH(D2&"*"&E2,Sheet2!$A$2:$A$271&Sheet2!$B$2:$B$271),Sheet2!$D$2:$D$271),"")

Fill xuống!!!

 

[eke_rula]

lạ nhỉ, tại sao lại không dùng công thức đơn giản hơn, không lẽ có bí mật gì chăng?

=IFERROR(LOOKUP(2,1/(D2=Sheet2!$A$2:$A$271)/(E2=Sheet2!$B$2:$B$271),Sheet2!$D$2:$D$271),"")

Nếu thời gian đăng kí bảo hiểm lâu quá, không nhớ rõ ngày tháng mà chỉ nhớ năm thì công thức của anh không bao quát hết trường hợp!!!

 

[HieuCD]

Bạn hiền bỏ đi đâu mất biệt mấy bửa..
Do số liệu ngày sinh năm sinh của chủ thớt rất "thoải mái" "ngẫu hứng lý qua cầu" lắm nên công thức mới rắc rối đó mà.
Khà khà! Chưa ngủ hả!
Vậy chúc ngủ ngon vậy.

cuối tuần phải ngũ bụi nên không lên mạng được, chỉ rảnh ngày làm việc thôi, về tới nơi mới tranh thủ lên mạng góp vui với các bạn

 

[HieuCD]

Nếu thời gian đăng kí bảo hiểm lâu quá, không nhớ rõ ngày tháng mà chỉ nhớ năm thì công thức của anh không bao quát hết trường hợp!!!

vậy thì dùng thử công thức nầy

=IFERROR(LOOKUP(2,1/(D2=Sheet2!$A$2:$A$271)/(E2=RIGHT(Sheet2!$B$2:$B$271,LEN(E2))),Sheet2!$D$2:$D$271),"")

 

[quocgiacan]

vậy thì dùng thử công thức nầy

=IFERROR(LOOKUP(2,1/(D2=Sheet2!$A$2:$A$271)/(E2=RIGHT(Sheet2!$B$2:$B$271,LEN(E2))),Sheet2!$D$2:$D$271),"")

Nhớ có anh em nào nói "Lợi thế của người đến sau", tức gom cái hay của người khác làm cho mình. Khà khà đáng bị:

Ai cũng chơi với LOOKUP() hết, vậy mình chơi với OFFSET() vậy.

B2=IFERROR(OFFSET(Sheet2!D$1,MATCH(D2&"*"&E2,INDEX(Sheet2!$A$2:$A$271&Sheet2!$B$2:$B$271,),),),"")

Dzọt lẹ!!

Chúc anh em ngày thiệt vui.