Tìm lấy đơn giá trong bảng tính

[tt_kimbai]

Chào cả nhà
Mình có bảng tính cần lấy đơn giá để tính chiết khấu cho khách
ở sheet NPK mình vlookup để lấy theo từng khách hàng được hưởng chiết khấu , đơn giá thì lại theo bảng CK có nhiều mức hưởng,
Giờ muốn lấy đơn giá qua để điền mà không biết kết hợp hàm cho đúng
Cả nhà giúp mình với ạ
Cảm ơn cả nhà rất nhiều ạ

 

[cantl]

Hàm dài quá, nhìn chán cực.
F16=IFERROR(INDEX(CK!$C$3:$F$54;MATCH($L$9;IF(CK!$C$3:$C$54=$K$9;CK!$E$3:$E$54);1);4);0)

Bài đã được tự động gộp: 18/11/22

Chào cả nhà
Mình có bảng tính cần lấy đơn giá để tính chiết khấu cho khách
ở sheet NPK mình vlookup để lấy theo từng khách hàng được hưởng chiết khấu , đơn giá thì lại theo bảng CK có nhiều mức hưởng,
Giờ muốn lấy đơn giá qua để điền mà không biết kết hợp hàm cho đúng
Cả nhà giúp mình với ạ
Cảm ơn cả nhà rất nhiều ạ

 

[VetMini]

Bảng CK của bạn không được thiết kế theo đúng chuẩn để dò. Luật của bảng dò là phải dòng nào rõ rệt ra dòng nấy, để khi cần, người tra có thể sort bảng. Vì vậy, bạn chỉ có hai cách:

1. Nếu phiên bản có hàm Filter thì dùng hàm filter lọc lấy cái range chứa mã khách hàng. Sort theo sản lượng, và Vlookup gần đúng (tham thứ từ là 1) để lấy chiết khấu.

2. Nếu phiên bản không có hàm Filter thì bắt buộc phải lập bảng phụ:
- Copy bảng CK thành CK2
- Sort bảng CK2 theo Mã Khách Hàng và số lượng từ lớn đến nhỏ.
Dùng Lookup với mẹo dò 2 điều kiện để dò. Điều kiện thứ nhất là mã khách hàng. Điều kiện thứ hai là nhỏ hơn hay bằng số lượng chiết khấu.
Cách dò này, ở GPE có cả đống bài.

Chú thích: vì mẹo Lookup trả về theo thứ tự từ dưới lên trên cho nên bắt buộc bảng tra phải được sort theo thứ tự số lượng giảm dần.

Chứ thích 2: Có thể có cách dễ hơn. Trước mắt thì tôi chỉ mới nghĩ ra cách này.

 

[VetMini]

Bổ sung thêm cho bài trên.

Tôi mới nhớ ra rằng nếu phiên bản có hàm Filter thì cũng có hàm XLookUp. Với XLookup, công thức dễ hơn một chút.
Dùng hàm filter lọc lấy cái range chứa mã khách hàng. Và Xlookup số lượng với tham thứ năm là 1 (lấy số lớn hơn gần nhất) để lấy chiết khấu.

 

[dangductuong2125]

Chào cả nhà
Mình có bảng tính cần lấy đơn giá để tính chiết khấu cho khách
ở sheet NPK mình vlookup để lấy theo từng khách hàng được hưởng chiết khấu , đơn giá thì lại theo bảng CK có nhiều mức hưởng,
Giờ muốn lấy đơn giá qua để điền mà không biết kết hợp hàm cho đúng
Cả nhà giúp mình với ạ
Cảm ơn cả nhà rất nhiều ạ

Bạn thử công thức sau : ( Điều kiện phức tạp nên công thức hơi dài )

Cột phụ : J16=IF(I16="","",IFERROR(INDEX(CK!$E$4:$E$54,AGGREGATE(15,6,(ROW(CK!$E$4:$E$54)-3)/($K$9=CK!$C$4:$C$54),ROW(A1))),""))

F16=IFERROR(IF(I16="","",IF(AND($E$42>=$J$16,$E$42<$J$17),INDEX(CK!$F$4:$F$54,AGGREGATE(15,6,(ROW(CK!$F$4:$F$54)-3)/($K$9=CK!$C$4:$C$54),1)),IF(AND($E$42>=$J$17,$E$42<$J$18),INDEX(CK!$F$4:$F$54,AGGREGATE(15,6,(ROW(CK!$F$4:$F$54)-3)/($K$9=CK!$C$4:$C$54),2)),INDEX(CK!$F$4:$F$54,AGGREGATE(15,6,(ROW(CK!$F$4:$F$54)-3)/($K$9=CK!$C$4:$C$54),3))))),"")

 

[tt_kimbai]

Hàm dài quá, nhìn chán cực.
F16=IFERROR(INDEX(CK!$C$3:$F$54;MATCH($L$9;IF(CK!$C$3:$C$54=$K$9;CK!$E$3:$E$54);1);4);0)

Bài đã được tự động gộp: 18/11/22

mình làm mà kết quả trả về giá trị =0 thôi không ra kết quả không biết sai ở điểm nào ạ, mong Anh/Chị/Bạn chỉ giúp mình ạ

 

[cantl]

View attachment 283605
mình làm mà kết quả trả về giá trị =0 thôi không ra kết quả không biết sai ở điểm nào ạ, mong Anh/Chị/Bạn chỉ giúp mình ạ

Mình không rõ, nhưng đối chiếu 2 công thức thấy khác nhau đoạn cuối ấy. CK!$E$3:$E$54);1);4);0)

 

[tt_kimbai]

Mình không rõ, nhưng đối chiếu 2 công thức thấy khác nhau đoạn cuối ấy. CK!$E$3:$E$54);1);4);0)

Mình không rõ, nhưng đối chiếu 2 công thức thấy khác nhau đoạn cuối ấy. CK!$E$3:$E$54);1);4);0)

dạ cũng vẫn không ra đơn giá ạ

 

[cantl]

dạ cũng vẫn không ra đơn giá ạ

Trên mình gửi file đính kèm, thử mở ra xem có được không? Bên máy mình được đấy.

 

[tt_kimbai]

Trên mình gửi file đính kèm, thử mở ra xem có được không? Bên máy mình được đấy.View attachment 283609

à dạ, công thức mảng phải bấm tổ hợp phím ctrl+shift+enter mình lại cứ thuận tay enter thôi ạ. Cảm ơn Anh/Chị/Bạn rất nhiều ạ

 

[Phan Thế Hiệp]

Chào cả nhà
Mình có bảng tính cần lấy đơn giá để tính chiết khấu cho khách
ở sheet NPK mình vlookup để lấy theo từng khách hàng được hưởng chiết khấu , đơn giá thì lại theo bảng CK có nhiều mức hưởng,
Giờ muốn lấy đơn giá qua để điền mà không biết kết hợp hàm cho đúng
Cả nhà giúp mình với ạ
Cảm ơn cả nhà rất nhiều ạ

1/ Nếu bảng "CK" đã sort trước rồi thì làm theo ý bài 3 là gọn gàng:

F16=IFERROR(LOOKUP($L$9,CK!$E$4:$E$54/(CK!$C$4:$C$54=$K$9),CK!$F$4:$F$54),)

Chỉ Enter, fill xuống.

2/ Nếu bảng "CK" chưa sort (hoặc đã sort rồi cũng được), thì có thể dùng:

F16=IFERROR(MOD(AGGREGATE(14,6,(CK!$E$4:$E$54*10^3+CK!$F$4:$F$54)/($L$9>=CK!$E$4:$E$54)/($K$9=CK!$C$4:$C$54),1),10^3),)

Enter, fill xuống.

Thân