Tìm giá trị mới nhất (7 người xem)

[violetworld83]

Tại ô màu vàng, mình muốn tìm giá trị tại cột B mới nhất theo ngày.
Cả nhà mình giúp mình với nhé

 

[befaint]

Tại ô màu vàng, mình muốn tìm giá trị tại cột B mới nhất theo ngày.
Cả nhà mình giúp mình với nhé

CT1:

=LOOKUP(2,1/(A5:A51=MAX(A5:A51)),B5:B51)

CT2:

=SUMPRODUCT((A5:A51=MAX(A5:A51))*B5:B51)

 

[befaint]

CT3:

=MAX(B5:B51*(A5:A51=MAX(A5:A51)))
'Ctrl + Shift + Enter

 

[Phuocam]

CT4:

=INDEX(B5:B51,MATCH(TRUE,INDEX(A5:A51=MAX(A5:A51),0),0))

 

[Mộng Thường 2001]

Góp vui thêm với anh em: Nếu cột A đã sort theo ngày từ nhỏ đến lớn như dữ liệu, thì CT1 của anh @befaint sẽ thành:

CT5:

=LOOKUP(2,1/A5:A51,B5:B51)

hihi ^o^

 

[violetworld83]

CT3:

=MAX(B5:B51*(A5:A51=MAX(A5:A51)))
'Ctrl + Shift + Enter

Thanks bạn rất nhiều nhé
Tuy nhiên, mình vẫn chưa ra được kết quả như mong muốn.
Mình nói rõ thêm chút nhé, Mình có cột A: ngày xếp theo thứ tự tăng dần, cột B: giá trị sẽ được update theo ngày thực tế. Trong ví dụ của mình kết quả đang được update đến ngày mới nhất là ngày 2/5: 99.99%. Và mình muốn tại ô màu vàng sẽ hiển thị kết quả ở cột B theo điều kiện là ngày gần nhất so với today. Mình up lại file, bạn xem lại giúp mình nhé

 

[Phuocam]

Tuy nhiên, mình vẫn chưa ra được kết quả như mong muốn.

Chào bạn.
Kết quả mong muốn của bạn trong ô B52 và B53 là bao nhiêu?

 

[dazkangel]

Cảm ơn bạn rất nhiều nhé
Tuy nhiên, mình vẫn chưa ra được kết quả như mong muốn.
Mình nói rõ thêm chút nhé, Mình có cột A: ngày xếp theo thứ tự tăng dần, cột B: giá trị sẽ được update theo ngày thực tế. Trong ví dụ của mình kết quả đang được update đến ngày mới nhất là ngày 2/5: 99.99%. Và mình muốn tại ô màu vàng sẽ hiển thị kết quả ở cột B theo điều kiện là ngày gần nhất so với today. Mình up lại file, bạn xem lại giúp mình nhé

Thử công thức sau, fill qua ô C52:

B52=LOOKUP(2,1/(($A$5:$A$51<TODAY())*B$5:B$51>0),B$5:B$51)

 

[befaint]

Cảm ơn bạn rất nhiều nhé
Tuy nhiên, mình vẫn chưa ra được kết quả như mong muốn.
Mình nói rõ thêm chút nhé, Mình có cột A: ngày xếp theo thứ tự tăng dần, cột B: giá trị sẽ được update theo ngày thực tế. Trong ví dụ của mình kết quả đang được update đến ngày mới nhất là ngày 2/5: 99.99%. Và mình muốn tại ô màu vàng sẽ hiển thị kết quả ở cột B theo điều kiện là ngày gần nhất so với today. Mình up lại file, bạn xem lại giúp mình nhé

Vấn đề có 2 vấn đề:
- Thứ nhất, những ngày chưa có thông tin (giá trị) thì sao mình lại ghi 0% vào?
- Thứ hai, làm sao biết ngày gần nhất so với today (bởi vì cái thứ nhất nên không có căn cứ, trừ khi bạn ghi rõ điều kiện là giá trị cập nhật vào luôn >0).

 

[befaint]

B$5:B$51>0

Không có được nhé: 0% vẫn là một giá trị hoàn toàn xảy ra.

 

[dazkangel]

Không có được nhé: 0% vẫn là một giá trị hoàn toàn xảy ra.

Em không biết nữa anh à, đôi khi khó khăn quá thì đợi chủ bài lên tiếng.

 

[violetworld83]

Vấn đề có 2 vấn đề:
- Thứ nhất, những ngày chưa có thông tin (giá trị) thì sao mình lại ghi 0% vào?
- Thứ hai, làm sao biết ngày gần nhất so với today (bởi vì cái thứ nhất nên không có căn cứ, trừ khi bạn ghi rõ điều kiện là giá trị cập nhật vào luôn >0).

Mình trả lời bạn nhé
- Thứ nhất: vì ô này hiện tại mình có dùng công thức, nếu những ngày này số liệu chưa update thì sẽ hiện là 0
- Thứ hai: khi có số liệu thì chắc chắn giá trị sẽ >0, nếu ko có căn cứ được vào today thì mình có thể mình bằng cách lấy giá trị >0 gần nhất theo thứ tự từ trên xuống dưới thì được ko bạn.

 

[violetworld83]

Thử công thức sau, fill qua ô C52:

B52=LOOKUP(2,1/(($A$5:$A$51<TODAY())*B$5:B$51>0),B$5:B$51)

Mình dùng được công thức của bạn nhé, thanks bạn nhiều nha

 

[dazkangel]

Mình dùng được công thức của bạn nhé, Cảm ơn bạn nhiều nha

Nếu chỉ cần dữ liệu khác không thì như sau:

B52=LOOKUP(2,1/(B$5:B$51>0),B$5:B$51)

 

[befaint]

những ngày này số liệu chưa update thì sẽ hiện là 0

=If("chưa cập nhật","","giá trị mới")