Tách số tháng của năm 2023 và 2024

[duchg]

Chào anh, chị.
Em có bài toán dựa vào TỪ THÁNG cộng với SỐ THÁNG
Nhờ anh, chị viết công thức tách dùm em để được bao nhiêu tháng của năm 2023 và 2024 ạ

 

[Hoàng Tuấn 868]

Chào anh, chị.
Em có bài toán dựa vào TỪ THÁNG cộng với SỐ THÁNG
Nhờ anh, chị viết công thức tách dùm em để được bao nhiêu tháng của năm 2023 và 2024 ạ

View attachment 292931

Bạn thử tự viết trước đi xem thế nào.

 

[dangductuong2125]

Chào anh, chị.
Em có bài toán dựa vào TỪ THÁNG cộng với SỐ THÁNG
Nhờ anh, chị viết công thức tách dùm em để được bao nhiêu tháng của năm 2023 và 2024 ạ

View attachment 292931

Nếu cột A là chỉ là 2023 thì tại C2 có thể dùng công thức sau :

=IF((RIGHT(A2,2)-1+B2)<=12,B2,12-RIGHT(A2,2)+1)

 

[duchg]

Bạn thử tự viết trước đi xem thế nào.

Em viết dựa trên công thức bác dangductuong2125 gợi ý
Nhưng công thức dài quá và đọc khó hiểu
Anh, chị nào có công thức nào gọn hơn k nhỉ

 

[bigbabol89]

Em viết dựa trên công thức bác dangductuong2125 gợi ý
Nhưng công thức dài quá và đọc khó hiểu
Anh, chị nào có công thức nào gọn hơn k nhỉ

Với yêu cầu của bạn thì công thức trên là dễ hiểu và rút gọn lắm rồi ấy.

 

[ptm0412]

Với file ở bài #4:
D2 =MIN(12-RIGHT($A2,2)+1,$C2)*(LEFT($A2,4)=D$1)
copy xuống

E2 =MIN(12-RIGHT($A2,2)+1,$C2)*(LEFT($A2,4)=E$1)+MIN(12,$C2-SUM(D2:$D2))*(LEFT($A2,4)<>E$1)

Copy xuống và copy ngang vô tận



Công thức của bạn sai khi tổng số tháng vượt quá 2024 sang 2025

 

[Phuocam]

Copy xuống và copy ngang vô tận

.
Có chắc không anh? Thử sửa A2 bắt đầu từ năm 2024 xem sao?.

.

 

[ptm0412]

.
Có chắc không anh? Thử sửa A2 bắt đầu từ năm 2024 xem sao?.

.

Do dòng 1 là text nên tôi đã ghi <>,
Nghĩ lại thì số dạng text cũng so sánh được lớn nhỏ với nhau, vậy sửa <> thành < là được
E2 =MIN(12-RIGHT($A2,2)+1,$C2)*(LEFT($A2,4)=E$1)+MIN(12,$C2-SUM(D2:$D2))*(LEFT($A2,4)<E$1)

 

[bebo021999]

Hy vọng cái này không đến nỗi nào:

=SUMPRODUCT(--(YEAR(EDATE(DATE(LEFT($A2,4)+0,RIGHT($A2,2)+0,1),ROW(INDIRECT("1:" & $B2))-1))=C$1))

 

[ptm0412]

Hy vọng cái này không đến nỗi nào:

Suy luận phức tạp sinh ra công thức phức tạp Với lại yêu cầu bài #4 là công thức ngắn hơn, gọn hơn.
À mà dòng 1 của người ta là text đi sửa lại thành số!

 

[bebo021999]

Suy luận phức tạp sinh ra công thức phức tạp Với lại yêu cầu bài #4 là công thức ngắn hơn, gọn hơn.
À mà dòng 1 của người ta là text đi sửa lại thành số!

Nếu vậy thì chuyển vế thôi ạ:
SUMPRODUCT(--(xxx=C$1))
thành
SUMPRODUCT(--(xxx-C$1=0))

 

[LmoovoenX]

Em viết dựa trên công thức bác dangductuong2125 gợi ý
Nhưng công thức dài quá và đọc khó hiểu
Anh, chị nào có công thức nào gọn hơn k nhỉ

Thử công thức này ở D2, và kéo xuống các ô khác.

=IF(D$1<LEFT($A2,4),0,IFERROR(MIN(13-MID($A2,FIND(D$1,$A2)+4,2),$C2),MEDIAN(0,12,2*$C2-SUM($C2:C2))))

 

[LmoovoenX]

Thử công thức này ở D2, và kéo xuống các ô khác.

=IF(D$1<LEFT($A2,4),0,IFERROR(MIN(13-MID($A2,FIND(D$1,$A2)+4,2),$C2),MEDIAN(0,12,2*$C2-SUM($C2:C2))))

Vì không có trường hợp <0, nên thay hàm median bằng min nhé.

=IF(D$1<LEFT($A2,4),0,IFERROR(MIN(13-MID($A2,FIND(D$1,$A2)+4,2),$C2),MIN(12,2*$C2-SUM($C2:C2))))

 

[Phuocam]

=SUMPRODUCT(--(YEAR(EDATE(DATE(LEFT($A2,4)+0,RIGHT($A2,2)+0,1),ROW(INDIRECT("1:" & $B2))-1))=C$1))

.
Ngắn hơn một chút:

=SUMPRODUCT(--(YEAR(EDATE(TEXT($A2,"0000-00-1"),ROW(INDIRECT("1:" & $B2))-1))-C$1=0))

.

 

[HieuCD]

.
Ngắn hơn một chút:

=SUMPRODUCT(--(YEAR(EDATE(TEXT($A2,"0000-00-1"),ROW(INDIRECT("1:" & $B2))-1))-C$1=0))

.

Ngắn hơn tí xíu .

=SUMPRODUCT(N(YEAR(EDATE(TEXT($A2,"0000-00-1"),ROW(OFFSET($A$1,,,$B2))-1))=C$1))