Nhờ tách chiều dài, rộng, cao của các dầm (2 người xem)

[trungvdb]

Đầu bài của em là cột A diễn giải tích thể tích, em muốn tách riêng chiều dài, rộng, cao ra 3 cột B, C, D tương ứng như dưới hình.

(Quy luật: Các dầm luôn có thứ tự chiều dài/chiều rộng/chiều cao được ngăn cách bởi dấu * và được tính từ dấu : trở về sau)

Nếu giúp em bằng 2 cách càng tốt (nếu có thể ưu tiên làm giúp em dạng công thức excel), em đang nghiên cứu phần công thức.

 

[bebo021999]

Tại B3:

=--SUBSTITUTE(MID(A3,FIND(":",A3)+1,FIND("*",A3)-FIND(":",A3)-1),",",".")

C3:

=--SUBSTITUTE(MID(A3,FIND("*",A3)+1,FIND("*",A3,FIND("*",A3)+1)-FIND("*",A3)-1),",",".")

D3:

=--SUBSTITUTE(MID(A3,FIND("*",A3,FIND("*",A3)+1)+1,255),",",".")

Copy xuống

 

[ndu96081631]

Đầu bài của em là cột A diễn giải tích thể tích, em muốn tách riêng chiều dài, rộng, cao ra 3 cột B, C, D tương ứng như dưới hình.

(Quy luật: Các dầm luôn có thứ tự chiều dài/chiều rộng/chiều cao được ngăn cách bởi dấu * và được tính từ dấu : trở về sau)

Nếu giúp em bằng 2 cách càng tốt (nếu có thể ưu tiên làm giúp em dạng công thức excel), em đang nghiên cứu phần công thức.

Quá dễ:
- Dài:

=TRIM(MID(SUBSTITUTE(SUBSTITUTE($A3,":","*"),"*",REPT(" ",255)),[COLOR=#ff0000][B]255[/B][/COLOR],255))

- Rộng:

=TRIM(MID(SUBSTITUTE(SUBSTITUTE($A3,":","*"),"*",REPT(" ",255)),[B][COLOR=#ff0000]510[/COLOR][/B],255))

- Cao:

=TRIM(MID(SUBSTITUTE(SUBSTITUTE($A3,":","*"),"*",REPT(" ",255)),[COLOR=#ff0000][B]765[/B][/COLOR],255))

Chú ý mấy số màu đỏ nha
Ẹc... Ẹc...

 

[trungvdb]

Em hiểu rồi mình có thể thay 255 bằng 1 số nào đó đủ lớn để tạo ra khoảng trắng an toàn giữa các phần để khi cắt nó "không cắt" mất phần nội dung, thực chất nó chia ra làm 3 khúc mỗi khúc, ngăn cách giữa các phần có 255 kí tự trắng, như vậy (255*2=510; 255*3=765).

-------
Hôm nay em học được cách của thày rất hữu hiệu với nhiều bài, muốn cắt đến đoạn nào thì thêm vào khoảng trắng đủ lớn để có thể cắt thoải mái.

 

[concogia]

Em hiểu rồi mình có thể thay 255 bằng 1 số nào đó đủ lớn để tạo ra khoảng trắng an toàn giữa các phần để khi cắt nó "không cắt" mất phần nội dung, thực chất nó chia ra làm 3 khúc mỗi khúc, ngăn cách giữa các phần có 255 kí tự trắng, như vậy (255*2=510; 255*3=765).

-------
Hôm nay em học được cách của thày rất hữu hiệu với nhiều bài, muốn cắt đến đoạn nào thì thêm vào khoảng trắng đủ lớn để có thể cắt thoải mái.
Tuy vậy, Em có thắc mắc: Nhưng nhỡ may phần diễn giải đầu trước khi đến dấu hai chấm ) nó lớn hơn 255 kí tự thì "teo" ah?

Vậy, theo bạn, gặp trường hợp này (in đậm & nghiêng) thì ..........làm sao cho nó đừng "tèo" & theo bạn tại sao sử dụng số 255 mà không phải là số khác ???
Híc

 

[trungvdb]

Vậy, theo bạn, gặp trường hợp này (in đậm & nghiêng) thì ..........làm sao cho nó đừng "tèo" & theo bạn tại sao sử dụng số 255 mà không phải là số khác ???

Về nguyên tắc ta sẽ lấy một số đủ lớn (>255), nhưng tại sao nhiều bài trên diễn đàn rất hay sử dụng số này, phải chăng excel không cho đánh quá 255 ký tự --> 255 kí tự trắng đã là max rồi?

Em đoán vậy thôi

 

[ndu96081631]

Tuy vậy, Em có thắc mắc: Nhưng nhỡ may phần diễn giải đầu trước khi đến dấu hai chấm ) nó lớn hơn 255 kí tự thì "teo" ah?

Thông thường, để không phải suy nghĩ vụ này, ta sẽ thay số 255 = Len(Chuổi)
Ăn chắc không bao giờ sai ---> Chuổi dài bao nhiêu thì số khoảng trắng cũng dài bấy nhiêu

 

[concogia]

Về nguyên tắc ta sẽ lấy một số đủ lớn (>255), nhưng tại sao nhiều bài trên diễn đàn rất hay sử dụng số này, phải chăng excel không cho đánh quá 255 ký tự --> 255 kí tự trắng đã là max rồi?

Em đoán vậy thôi

Về nguyên tắc ta sẽ lấy một số đủ lớn (>255)

Bạn chỉ rõ là ........số nào đi ("Mắc mớ" gì mà lại phải >255 nhỉ ??? Híc)

....phải chăng excel không cho đánh quá 255 ký tự --> 255 kí tự trắng đã là max rồi?

Bạn thử vào bảng tính Ec chưa ??? Xem coi nó cho nhập bi nhiêu ký tự
Thân

 

[trungvdb]

Vâng, đúng là vụ này em nhầm; em chưa hiểu tại sao lại là 255 thày ah,

còn về cách thì như em vừa đọc phần trên của sư phụ Ndu (thay 255 bằng len($A1) là được).

 

[ndu96081631]

Vâng, đúng là vụ này em nhầm; em chưa hiểu tại sao lại là 255 thày ah,

còn về cách thì như em vừa đọc phần trên của sư phụ Ndu (thay 255 bằng len($A1) là được).

Ngày xưa còn dùng Excel 2003, khi bạn gõ 1 chuổi dài hơn 255 ký tự vào 1 cell nào đó, Excel cũng chẳng nói gì, nhưng khi bạn Move or copy sheet sang 1 workbook khác, nó tự cắt chuổi chỉ chừa lại 255 ký tự... Có lẽ vì thế mà người ta cho rằng 255 là giới hạn xử lý của Excel
Tuy nhiên bây giờ xài Excel 2010 thì... thoải mái
Ẹc... Ẹc...