[Nhờ giúp] hàm đếm mặt hàng không có trong danh sách và liệt kê ngày trong 1 khoảng thời gian

[chickenexcel]

Nhờ anh/chị giúp đỡ:
1. Đếm số lượt mặt hàng không có trong danh sách cho trước (danh mục sản phẩm tại sheet "Tổng hợp" với sheet "Dữ liệu"), phụ thuộc vào khoảng thời gian tại D1 và D2, ở đây là mặt hàng "ổi" và "chôm chôm" không có, nhưng chỉ tính từ 1.6 đến 10.6 nên chỉ tính 1 lần
2. Liệt kê các ngày có trong sheet "dữ liệu" phụ thuộc vào ngày bắt đầu (D1) và kết thúc (D2)
Em có lập công thức ở cột H, cũng ra kết quả, nhưng để phụ thuộc vào khoảng thời gian theo D1 và D2 thì chưa biết làm thế nào (em có thử công thức để ghép địa chỉ vào nhưng không cho ra kết quả (D16), (I2)
mục đích là em có tạo 1 phiếu hàng, mỗi phiếu hàng là 1 ngày, sau khi dùng lệnh in sẽ in các ngày có bán hàng trong khoảng thời gian cho trước (D1 và D2)
Nhờ/anh chị chỉ giúp ạ!

 

[Phan Thế Hiệp]

Nhờ anh/chị giúp đỡ:

1. Sản phẩm không có trong danh mục:

D4=COUNT(1/(1-COUNTIF('Tổng hợp'!B5:B8,'Dữ liệu'!C2:C100)/('Dữ liệu'!B2:B100>=D1)/('Dữ liệu'!B2:B100<=D2)))

Kết thúc bằng Ctrl+Shift+Enter.

2. Liệt kê các ngày có trong sheet "dữ liệu" phụ thuộc vào ngày bắt đầu (D1) và kết thúc (D2):

H3=IFERROR(INDEX('Dữ liệu'!$B$2:$B$17,MATCH(,INDEX(COUNTIF($H$2:H2,'Dữ liệu'!$B$2:$B$17)+('Dữ liệu'!$B$2:$B$17<$D$1)+('Dữ liệu'!$B$2:$B$17>$D$2),),)),"")

Chỉ Enter. Fill xuống.

Thân

 

[chickenexcel]

dạ em cảm ơn a nhé, công thức của bác hay quá ạ!

 

[chickenexcel]

Làm phiền bác Phan Thế Hiệp, nếu tại cột (C) ngày trong sheet "Dữ liệu" có ngày, nhưng cột tên sản phẩm trống, muốn đếm khi thỏa mãn có ngày, tên sản phẩm <>"" thì công thức sửa thế nào ạ?
Em cảm ơn!

 

[Phan Thế Hiệp]

...nếu tại cột (C) ngày trong sheet "Dữ liệu" có ngày, nhưng cột tên sản phẩm trống, muốn đếm khi thỏa mãn có ngày, tên sản phẩm <>"" thì công thức sửa thế nào ạ?
Em cảm ơn!

Cứ thêm điều kiện vào đằng sau công thức, dạng: "Giá trị"/<đk1>/<đk2>/......../<đkn>

Cụ thể:
D4=COUNT(1/(1-COUNTIF('Tổng hợp'!B5:B10,'Dữ liệu'!C2:C102)/('Dữ liệu'!B2:B102>=D1)/('Dữ liệu'!B2:B102<=D2)/('Dữ liệu'!C2:C102<>"")))
Kết thúc bằng Ctrl+Shift+Enter.

Thân

 

[chickenexcel]

Cứ thêm điều kiện vào đằng sau công thức, dạng: "Giá trị"/<đk1>/<đk2>/......../<đkn>

Cụ thể:
D4=COUNT(1/(1-COUNTIF('Tổng hợp'!B5:B10,'Dữ liệu'!C2:C102)/('Dữ liệu'!B2:B102>=D1)/('Dữ liệu'!B2:B102<=D2)/('Dữ liệu'!C2:C102<>"")))
Kết thúc bằng Ctrl+Shift+Enter.

Thân

Cảm ơn anh ạ, vì em không hiểu cái 1/ với 1- nên chẳng hiểu được công thức của anh

 

[Phan Thế Hiệp]

Cảm ơn anh ạ, vì em không hiểu cái 1/ với 1- nên chẳng hiểu được công thức của anh

• Các điều kiện lọc: phải thỏa "Có ngày thuộc khoảng D1->D2", và "Tên hàng - Cột C không rỗng". Chính là đoạn:
  • /('Dữ liệu'!B2:B102>=D1)/('Dữ liệu'!B2:B102<=D2)/('Dữ liệu'!C2:C102<>"")
• Điều kiện xác định các "Tên hàng nào" không được điểm danh trong danh sách của B5: B10. Chính là đoạn:
  • COUNTIF('Tổng hợp'!B5: B10,'Dữ liệu'!C2: C102) -> dùng xác định tên hàng tồn tại trong Vùng C2: C102 có hay không, nếu có nó đếm 1, nếu không có nó đếm 0.
  • 1-COUNTIF('Tổng hợp'!B5: B10,'Dữ liệu'!C2: C102) -> tức "phủ định" lại việc trên, (tương đương sử dụng hàm NOT() ), tức nếu ở trên đếm nó có tồn tại thì bằng 1, vậy phủ định nó tức: 1-1=0; Ngươc lại, thì 1-0=1, tức đang từ 0 trở thành 1. Mục đích: ban đầu đếm thuận để xác định những tên hàng có tồn tại như bảng kê, rồi dùng phủ định để lòi ra những tên hàng không tồn tại theo như bảng.
• Ghép 2 điều kiện trên lại ta có 1 mảng kết quả lọc ra những tên hàng nằm trong khoảng ngày quy định, gồm các số 1 và 0 trong mảng.
• 1/{Mảng điều kiện, gồm các số 1 hoặc 0} -> hễ 1 chia cho 1 thì =1, 1 chia 0 sẽ báo lỗi #DIV/0!
• Dùng COUNT( 1/{Mảng điều kiện, gồm các số 1 hoặc 0} ) -> hàm Count() chỉ đếm các giá trị số (1), tức các tên hàng thỏa đủ các điều kiện quy định, và nó "phớt lờ" không tính các giá trị báo lỗi #DIV/0!

Thân

 

[keditimladieubong]

cảm ơn bác hiệp