Nhờ giúp đỡ công thưc tính điểm thực hiện theo kế hoạch

lad2000moet · 7/7/21

Chào các anh chị
Hiện tại em đang phải tính bảng điểm cho đơn vị với 1 số điểm cần dùng hàm excel, do em không thạo excel nên nhờ các anh chị giúp đỡ (file đính kèm)
điểm tính là thang 100 điểm xong nhận với trọng số sẽ ra số điểm của chỉ tiêu

ngocha1114 · 8/7/21

IF(F4>=100%,100,IF(100-(100%-F4)*500<0,0,100-(100%-F4)*500)*C4) bạn thử công thức này xem ạ

lad2000moet · 8/7/21

Cám ơn bạn nhé. Mình đã thử ok rồi. Ở bảng excel đính kèm mình còn 2 trường hợp nữa bạn giúp công thức hộ mình. Xin chân thành cảm ơn

ngocha1114 · 8/7/21

G4=IF(F4>=100%,100*C4,IF(100-(100%-F4)*500<0,0,100-(100%-F4)*500)*C4)
G5=IF(D5>=E5,100*C5,IF((100-(F5-100%))*1000<0,0,(100-(F5-100%)*1000)*C5))
G6=IF(IF(F6=100%,40*C6,IF(F6>100%,(40+(F6-100%)*100)*C6,IF(40-(100%-F6)*100<0,0,40-(100%-F6)*100)*C6))>=20,20,IF(F6=100%,40*C6,IF(F6>100%,(40+(F6-100%)*100)*C6,IF(40-(100%-F6)*100<0,0,40-(100%-F6)*100)*C6)))

lad2000moet · 8/7/21

ngocha1114 đã viết:
G4=IF(F4>=100%,100*C4,IF(100-(100%-F4)*500<0,0,100-(100%-F4)*500)*C4)
G5=IF(D5>=E5,100*C5,IF((100-(F5-100%))*1000<0,0,(100-(F5-100%)*1000)*C5))
G6=IF(IF(F6=100%,40*C6,IF(F6>100%,(40+(F6-100%)*100)*C6,IF(40-(100%-F6)*100<0,0,40-(100%-F6)*100)*C6))>=20,20,IF(F6=100%,40*C6,IF(F6>100%,(40+(F6-100%)*100)*C6,IF(40-(100%-F6)*100<0,0,40-(100%-F6)*100)*C6)))

Chào bạn, mình đã thử côngthức tạiô G5, G^ thấy chưa đúng bạn à. G5 nếu tính tăng hơn 50% thì cho ra số - (mà yêu cầu là trừ đến 0 điểm); G6 thì cứ vượt 1% thì cộng điểm, công thứuc lại là trừ điểm. Nhờ bạn xem lại giúp

Phan Thế Hiệp · 8/7/21

lad2000moet đã viết:
Chào các anh chị
Hiện tại em đang phải tính bảng điểm cho đơn vị với 1 số điểm cần dùng hàm excel, do em không thạo excel nên nhờ các anh chị giúp đỡ (file đính kèm)
điểm tính là thang 100 điểm xong nhận với trọng số sẽ ra số điểm của chỉ tiêu

Thử:

Mã:

G4=MAX(100-TEXT(1-F4,"0.00;\0")*500,)*C4
G5=MAX(100-TEXT((1-F5)*10^4,"\0;0.00"),)*C5
G6=MAX(40+MIN((F6-1)*100,10),)*C6

Thân

lad2000moet · 9/7/21

Phan Thế Hiệp đã viết:
Thử:

Mã:

G4=MAX(100-TEXT(1-F4,"0.00;\0")*500,)*C4 G5=MAX(100-TEXT((1-F5)*10^4,"\0;0.00"),)*C5 G6=MAX(40+MIN((F6-1)*100,10),)*C6

Thân

chào bạn, mình lắp công thức cảu bạn rồi nhưng thấy G5, G6 chưa đúng. VD G6 cho kế hoạch thực hiện bằng 100% thì được điểm tối đa, công thức cho ra 16; còn G5 mình thấy chưa hiểu ý công thức và thử tăng 1% là trừ hết điểm. Nhờ bạn xem giúp

Phan Thế Hiệp · 9/7/21

lad2000moet đã viết:
chào bạn, mình lắp công thức cảu bạn rồi nhưng thấy G5, G6 chưa đúng. VD G6 cho kế hoạch thực hiện bằng 100% thì được điểm tối đa, công thức cho ra 16; còn G5 mình thấy chưa hiểu ý công thức và thử tăng 1% là trừ hết điểm. Nhờ bạn xem giúp

Điều kiện của bạn làm sao thì tôi làm đúng vậy.
Trích:
1/ Thực hiện (TH) ≥ Kế hoạch (KH): 100 điểm.
Thực hiện (TH) < Kế hoạch (KH): cứ thấp hơn 1% bị trừ 5 điểm, trừ tối đa đến 0 điểm.
2/ - TH ≤ KH: tối đa 100 điểm.
- TH > KH: tăng 0,1% so với KH trừ 10 điểm, trừ đến 0 điểm.
3/ '- Thực hiện = 100% KH: 40 điểm.
- Thực hiện> 100% KH: vượt 1% so KH được cộng 1 điểm. Cộng tối đa 10 điểm.
- Thực hiện <100% kế hoạch: giảm 1% so KH, trừ 1 điểm. Trừ đến 0 điểm.

G5: Tăng 0.1% trừ 10 điểm, vậy tăng 1% thì trừ 100 điểm=> nó trừ sạch nhách là đúng rồi chứ còn muốn gì bạn?

G6: Thực hiện =100% KH được 40 điểm, rồi nhân cho 'trọng số' 40% thì được 16, cũng là ý bạn mà!?

Thân

lad2000moet · 10/7/21

Phan Thế Hiệp đã viết:
Điều kiện của bạn làm sao thì tôi làm đúng vậy.
Trích:
1/ Thực hiện (TH) ≥ Kế hoạch (KH): 100 điểm.
Thực hiện (TH) < Kế hoạch (KH): cứ thấp hơn 1% bị trừ 5 điểm, trừ tối đa đến 0 điểm.
2/ - TH ≤ KH: tối đa 100 điểm.
- TH > KH: tăng 0,1% so với KH trừ 10 điểm, trừ đến 0 điểm.
3/ '- Thực hiện = 100% KH: 40 điểm.
- Thực hiện> 100% KH: vượt 1% so KH được cộng 1 điểm. Cộng tối đa 10 điểm.
- Thực hiện <100% kế hoạch: giảm 1% so KH, trừ 1 điểm. Trừ đến 0 điểm.

G5: Tăng 0.1% trừ 10 điểm, vậy tăng 1% thì trừ 100 điểm=> nó trừ sạch nhách là đúng rồi chứ còn muốn gì bạn?

G6: Thực hiện =100% KH được 40 điểm, rồi nhân cho 'trọng số' 40% thì được 16, cũng là ý bạn mà!?

Thân

mình đã xem lại rồi, mình bị sai ý là ở G6 =100% thì được 100 đ chứ không phải 40, mình đã sửa rồi, rất cám ơn bạn nhiều nhé.

Tomtep2010 · 14/11/23

Phan Thế Hiệp đã viết:
Điều kiện
'- Thực hiện = 99 đến100% KH: 40 điểm.
- Thực hiện> 100% KH: vượt 1% so KH được cộng 1 điểm. Cộng tối đa 10 điểm.
- Thực hiện <99% kế hoạch: giảm 1% so KH, trừ 1 điểm. Trừ đến 0 điểm.

Minh muốn làm điều kiện như thế này thì làm như thế nào ạ.

leonguyenz · 14/11/23

Tomtep2010 đã viết:
Minh muốn làm điều kiện như thế này thì làm như thế nào ạ.

Tải file ở bài #6, đọc kỹ lại bài #7 và #8.
Còn nếu muốn áp dụng vào file của bạn thì gửi file lên.

Tomtep2010 · 14/11/23

leonguyenz đã viết:
Tải file ở bài #6, đọc kỹ lại bài #7 và #8.
Còn nếu muốn áp dụng vào file của bạn thì gửi file lên.

bác hộ e với ạ. e cảm ơn

leonguyenz · 14/11/23

Bạn tham khảo công thức sau:

Mã:

=IF(E4<0.99,100*(ROUND(E4,2)-0.99),IF(E4<=1,50,MIN(20,3*100*(ROUND(E4,2)-1))))

Tuy nhiên, có vấn đề chưa rõ:
- Tại sao vượt kế hoạch > 100% thì đạt tối đa 20 điểm, còn từ 99%-100% đạt 50 điểm?
- Vế thứ 3, "Trừ đến 0 điểm", là lấy gì trừ? Nếu cho sẵn ô có điểm để trừ thì sửa lại công thức (với F1 là số điểm cho trước).

Mã:

=IF(E4<0.99,MAX(0,$F$1-100*(0.99-ROUND(E4,2))),IF(E4<=1,50,MIN(20,3*100*(ROUND(E4,2)-1))))

Tomtep2010 · 14/11/23

leonguyenz đã viết:
Bạn tham khảo công thức sau:

Mã:

=IF(E4<0.99,100*(ROUND(E4,2)-0.99),IF(E4<=1,50,MIN(20,3*100*(ROUND(E4,2)-1))))

Tuy nhiên, có vấn đề chưa rõ:
- Tại sao vượt kế hoạch > 100% thì đạt tối đa 20 điểm, còn từ 99%-100% đạt 50 điểm?
- Vế thứ 3, "Trừ đến 0 điểm", là lấy gì trừ? Nếu cho sẵn ô có điểm để trừ thì sửa lại công thức (với F1 là số điểm cho trước).

Mã:

=IF(E4<0.99,MAX(0,$F$1-100*(0.99-ROUND(E4,2))),IF(E4<=1,50,MIN(20,3*100*(ROUND(E4,2)-1))))

e ghi chi tiết ra đây ạ. bác xem qua hộ e

bebo021999 · 14/11/23

Nếu lấy 120đ làm chuẩn (99-100%) và cứ giảm 1% thì trừ 1đ, theo cách này thì nếu thực hiện =0, %=0, điểm vẫn còn và = 21đ
CT tại H4:

Mã:

=IF(G4>=1,MIN(120+(ROUND(G4,2)-1)*100*3,150),IF(ROUND(G4,2)>=0.99,120,120-(0.99-ROUND(G4,2))*100))

Tomtep2010 · 14/11/23

bebo021999 đã viết:
Nếu lấy 120đ làm chuẩn (99-100%) và cứ giảm 1% thì trừ 1đ, theo cách này thì nếu thực hiện =0, %=0, điểm vẫn còn và = 21đ
CT tại H4:

Mã:

=IF(G4>=1,MIN(120+(ROUND(G4,2)-1)*100*3,150),IF(ROUND(G4,2)>=0.99,120,120-(0.99-ROUND(G4,2))*100))

Trường hợp trừ 3đ thì sẽ bị âm. e phải làm thế nào vậy bác

Phan Thế Hiệp · 23/11/23

Tomtep2010 đã viết:
Minh muốn làm điều kiện như thế này thì làm như thế nào ạ.

Tomtep2010 đã viết:
Trường hợp trừ 3đ thì sẽ bị âm. e phải làm thế nào vậy bác

Công thức dưới đây được tạo theo điều kiện bạn ghi trong file bài #16:
"- Thực hiện = 99 đến 100% 120 điểm.
- Thực hiện > 100% KH: vượt 1% so KH được cộng 3 điểm. Cộng tối đa 30 điểm.
- Thực hiện < 99% kế hoạch: giảm 1% so KH, trừ 3 điểm. Trừ đến 0 điểm."

Và chỉ tính toán số phần trăm tăng, hoặc giảm tròn số là 1%. Tại ô H4, copy công thức sau:

Mã:

=IF(G4<0.99,MAX(120+300*ROUND(((G4-1)+0.01),2),),IF(G4>1,120+MIN(300*(ROUND(G4-1,2)),30),120))

Hoặc dùng:

Mã:

=MAX(120+MIN(IFERROR(LOOKUP(10^6,300*(TEXT(F4/E4*{1,-1},"[<"&{0.99,-1}&"]"&"0.00;")+{0.01,0}-1)),),30),)

Thân

Nhờ giúp đỡ công thưc tính điểm thực hiện theo kế hoạch

Thành viên chính thức

File đính kèm

Thành viên mới

Thành viên chính thức

Thành viên mới

Thành viên chính thức

-⍟-

File đính kèm

Thành viên chính thức

-⍟-

Thành viên chính thức

Thành viên mới

Thành viên gạo cội

Thành viên mới

File đính kèm

Thành viên gạo cội

File đính kèm

Thành viên mới

File đính kèm

Thành viên gạo cội

File đính kèm

Thành viên mới

File đính kèm

-⍟-

File đính kèm

Facebook

Group