Nhờ chỉ hướng lọc giá trị cột B không tồn tại trong cột A (1 người xem)

[trungvdb]

Bài này em dùng Dictionary và Advanced thì ra kết quả, tuy vậy riêng về công thức mảng nói chung Excel em mới học chưa vững lắm nghĩ mãi không ra, kính nhờ các thày chỉ giúp em cách này

 

[quangdiepctmbk]

Bạn xem file đính kèm nhé!
Mình dùng công thức mảng

 

[trungvdb]

Em nghĩ ra rồi, do chưa quen với công thức mảng lên ban đầu hơi khó hình dung

DL_1=OFFSET(Sheet1!$A$1;;;MATCH(10^15;Sheet1!$A:$A))

DL_1=OFFSET(Sheet1!$B$1;;;MATCH(10^15;Sheet1!$B:$B))

DK=IF(COUNTIF(DL_1;DL_2)>=1;"";MATCH(DL_2;DL_2;0))

Công thức tại ô E2:

=IF(ROWS($1:1)>COUNT(DK);"";INDEX(DL_2;SMALL(DK;ROWS($1:1))))

 

[concogia]

Em nghĩ ra rồi, do chưa quen với công thức mảng lên ban đầu hơi khó hình dung

DL_1=OFFSET(Sheet1!$A$1;;;MATCH(10^15;Sheet1!$A:$A))

DL_1=OFFSET(Sheet1!$B$1;;;MATCH(10^15;Sheet1!$B:$B))

DK=IF(COUNTIF(DL_1;DL_2)>=1;"";MATCH(DL_2;DL_2;0))

Công thức tại ô E2:

=IF(ROWS($1:1)>COUNT(DK);"";INDEX(DL_2;SMALL(DK;ROWS($1:1))))

Đó là một cách làm bằng name, một cách khác dùng mảng trực tiếp không qua name

=IF(ROW(A1)>SUM(IF(COUNTIF($A$1:$A$6,$B$1:$B$6)=0,1,0)),"",INDEX($B$1:$B$6,SMALL(IF(COUNTIF($A$1:$A$6,$B$1:$B$6)=0,ROW($A$1:$A$6),""),ROW(A1))))

Nhưng dùng namethì linh hoạt & nhìn công thức gọn ghẽ hơn
Thân

 

[Lê Duy Thương]

em nghĩ ra rồi, do chưa quen với công thức mảng lên ban đầu hơi khó hình dung

dl_1=offset(sheet1!$a$1;;;match(10^15;sheet1!$a:$a))

dl_1=offset(sheet1!$b$1;;;match(10^15;sheet1!$b:$b))

dk=if(countif(dl_1;dl_2)>=1;"";match(dl_2;dl_2;0))

công thức tại ô e2:

=if(rows($1:1)>count(dk);"";index(dl_2;small(dk;rows($1:1))))

không cần phức tạp thế đâu

=offset($b$1,small(if(countif($a$1:$a$18,$b$1:$b$18)>0,"",row($b$1:$b$18)),row(1:1))-1,,,)

 

[hoamattroicoi]

Bạn có thể dùng công thức này trong trường hợp cột B có dòng trống :
Công thức tại C2, kết thúc bằng Ctrl+Shift+Enter nhé :

=INDEX($B$1:$B$8,MATCH(1,($B$1:$B$8<>"")*(COUNTIF($A$1:$A$8,$B$1:$B$8)=0)*(COUNTIF($C$1:C1,$B$1:$B$8)=0),0))