Mong các AC xem giúp code ẩn cột, có lúc chạy nhanh lúc chậm rù!
- Thread starter win-sun
- Ngày gửi
win-sun
Thành viên hoạt động
- Tham gia
- 19/1/09
- Bài viết
- 151
- Được thích
- 15
ub Ancot()
Application.ScreenUpdating = False
Dim Col As Range
If Range("B4") = "ALL" Then
Columns("E:FC").EntireColumn.Hidden = False
Else
For Each Col In Range("E9:FC9")
If Col = Range("B4") Then
Col.EntireColumn.Hidden = False
Else
Col.EntireColumn.Hidden = True
End If
Next Col
End If
Application.ScreenUpdating = True
End Sub
có điều gì đó không ổn!
Application.ScreenUpdating = False
Dim Col As Range
If Range("B4") = "ALL" Then
Columns("E:FC").EntireColumn.Hidden = False
Else
For Each Col In Range("E9:FC9")
If Col = Range("B4") Then
Col.EntireColumn.Hidden = False
Else
Col.EntireColumn.Hidden = True
End If
Next Col
End If
Application.ScreenUpdating = True
End Sub
có điều gì đó không ổn!
Upvote
0
nguyenkhuyen106
Thành viên chính thức
- Tham gia
- 21/11/12
- Bài viết
- 56
- Được thích
- 81
Mình thấy Sub AnCot trong file không có vấn đề gì, tuy nhiên có thể sửa lại một chút, hy vọng nhanh hơn:
[GPECODE=vb]Sub AnCot()
Dim Col As Range
Application.ScreenUpdating = False
Range("E9:FC9").EntireColumn.Hidden = False
If Range("B4") <> "ALL" Then
For Each Col In Range("E9:FC9")
If Col <> Range("B4") Then Col.EntireColumn.Hidden = True
Next
End If
Application.ScreenUpdating = True
End Sub[/GPECODE]
Upvote
0
- Tham gia
- 17/8/08
- Bài viết
- 8,610
- Được thích
- 16,670
- Giới tính
- Nam
Bạn thử chạy với thủ tục này xem:
[GPECODE=vb]Sub Ancot()
With Application
.ScreenUpdating = False
.EnableEvents = False
.Calculation = xlCalculationManual
Dim Col As Range
With Sheet2
If .Range("B4") = "ALL" Then
.Columns("E:FC").EntireColumn.Hidden = False
Else
For Each Col In .Range("E9:FC9")
Col.EntireColumn.Hidden = (Col <> .Range("B4"))
Next Col
End If
End With
.Calculation = xlCalculationAutomatic
.EnableEvents = True
.ScreenUpdating = True
End With
End Sub
[/GPECODE]
Upvote
0
- Tham gia
- 5/6/08
- Bài viết
- 30,703
- Được thích
- 53,930
Bài này không dùng For.. Next và bỏ luôn dòng công thức phụ trên bảng tính cũng được
Dùng Find Method định vị vị trí ngày đầu và ngày cuối là được rồi
Thử nghiên cứu xem
Dùng Find Method định vị vị trí ngày đầu và ngày cuối là được rồi
Thử nghiên cứu xem
Upvote
0
nguyenkhuyen106
Thành viên chính thức
- Tham gia
- 21/11/12
- Bài viết
- 56
- Được thích
- 81
Thế này có được không anh?
[GPECODE=vb]Sub AnCot()
Dim i As Long
With Application
.ScreenUpdating = False
.Calculation = xlCalculationManual
.EnableEvents = False
With Sheet2
.[E9:FC9].EntireColumn.Hidden = (.[C4] < 6)
If .[C4] = 6 Then Exit Sub
For i = .[D9].Offset(, .[C4]).Column To 159 Step 5
.Cells(1, i).EntireColumn.Hidden = False
Next
End With
.EnableEvents = True
.Calculation = xlCalculationAutomatic
.ScreenUpdating = True
End With
End Sub[/GPECODE]
Upvote
0
nguyenkhuyen106
Thành viên chính thức
- Tham gia
- 21/11/12
- Bài viết
- 56
- Được thích
- 81
Mình thấy các cách trên đều chạy được mà.
Có lẽ ý của anh ndu như thế này:
[GPECODE=vb]Sub AnCot()
Dim Rng As Range
With Application
.ScreenUpdating = False
.Calculation = xlCalculationManual
.EnableEvents = False
With Sheet2
.[E9:FC9].EntireColumn.Hidden = (.[C4] < 6)
If .[C4] = 6 Then Exit Sub
Set Rng = .[E9:FC9].Find(.[FI1].Offset(.[C4] - 1), lookat:=xlWhole)
Do While Rng.Column < 160
Rng.EntireColumn.Hidden = False
Set Rng = Rng.Offset(, 5)
Loop
End With
.EnableEvents = True
.Calculation = xlCalculationAutomatic
.ScreenUpdating = True
End With
End Sub[/GPECODE]
Upvote
0
- Tham gia
- 5/6/08
- Bài viết
- 30,703
- Được thích
- 53,930
Đã nói là không For... Next có nghĩa là không vòng lập cơ mà
Do.. Loop cũng là vòng lập nha bạn
Tôi nghĩ bài này chẳng cần vòng lập cũng được tuốt
Làm thử chơi nhé:
PHP:
Sub dangky()
Dim rng1 As Range, rng2 As Range, rng As Range
Dim cbo As DropDown
Application.ScreenUpdating = False
On Error Resume Next
With Sheet3
Set cbo = .DropDowns(Application.Caller)
.Range("E:FC").EntireColumn.Hidden = (cbo.ListIndex = 1)
Set rng1 = .Range("E8").Offset(, (Day(.Range("D3")) - 1) * 5 - 4)
Set rng2 = .Range("E8").Offset(, (Day(.Range("D4")) - 1) * 5)
Set rng = .Range(rng1, rng2)
rng.EntireColumn.Hidden = False
End With
Application.ScreenUpdating = True
End Sub-------------------
Nhân đây đố mọi người biết cái ComboBox trên bảng tính đang liên kết với cái gì mà có được chữ "Hide" và "Unhide" trong list?
Ẹc... Ẹc...
Upvote
0
thanhlanh
Thành viên tích cực
- Tham gia
- 21/2/08
- Bài viết
- 857
- Được thích
- 1,203
Chắc là chữ "Hide" và "Unhide" trong list lấy từ các giá trị của .Range("E:FC").EntireColumn.Hidden. Đúng là nghệ thuật.
Nhưng có lẽ do máy mình chưa cảm nhận được nghệ thuật nên giống đàn gãi tai trâu:
- Trong List đó trống rỗng.
- Chạy code dangky, bỏ bẩy lỗi trì thấy lỗi tại dòng này Set cbo = .DropDowns(Application.Caller)
Nhờ Bác sỹ bốc thuốc!
Lần chỉnh sửa cuối:
Upvote
0
nguyenkhuyen106
Thành viên chính thức
- Tham gia
- 21/11/12
- Bài viết
- 56
- Được thích
- 81
Thử nghiệm một cái coi:
1. Mở 1 Workbook mới, vẽ lên sheet (Sheet1) 1 ComboBox (Form control)
2. Chạy code sau:
[GPECODE=vb]Sub Test()
Dim Cbo As DropDown
Set Cbo = Sheet1.DropDowns(1)
Cbo.AddItem "Giai phap Excel"
Cbo.AddItem "Cong cu tuyet voi cua ban"
End Sub[/GPECODE]
3. Xóa macro trên.
4. Hỏi câu hỏi tương tự như bác ndu96081631 ở trên.
5. Ẹc ẹc một cái nữa.
Upvote
0
nguyenkhuyen106
Thành viên chính thức
- Tham gia
- 21/11/12
- Bài viết
- 56
- Được thích
- 81
Anh nghiaphuc là mod của diễn đàn, thuộc hàng cao thủ, còn em chỉ là lính mới, thuộc dạng thấp thủ, đâu dám múa rìu qua mắt thợ?! Hihihi
Upvote
0
- Tham gia
- 5/6/08
- Bài viết
- 30,703
- Được thích
- 53,930
Thật ra tôi làm rất đơn giản:
- Đầu tiên xem thằng Dropdown ấy tên gì (bằng cách chọn nó rồi nhìn lên hộp Name box)
- Xong, Alt + F11 vào của sổ VBA
- Bấm Ctrl + G rồi gõ vào dòng lệnh
Mã:
ActiveSheet.Dropdowns("Tên của Dropdown").List = Array("Hide", "Unhide")-------------------
Mục đích của việc làm này là giúp chúng ta đở mất công tạo danh sách trên sheet ---> Tạo 1 lần, xài mãi mãi ---> Đã dùng đến code thì chẳng cần gì đến Input Range và Cell link (mọi thứ cứ dùng code mà viết)
--------------------
Đố tiếp: Tại sao tôi dùng Application.Caller? Mục đích?
Lần chỉnh sửa cuối:
Upvote
0
nguyenkhuyen106
Thành viên chính thức
- Tham gia
- 21/11/12
- Bài viết
- 56
- Được thích
- 81
Ái chà chà... Đơn giản có vậy thôi mà em phải copy cái dòng lệnh Dim Cbo As DropDown trong code của bác rồi "chế biến", thậm chí kiểu dữ liệu DropDown còn không có trong danh mục các kiểu dữ liệu có sẵn của VBA nữa. Và gõ Sheet1 rồi chấm 1 phát cũng chẳng thấy anh chàng DropDown đâu cả.
Vậy là lại biết thêm một điều hay nữa... Cảm ơn bác ndu96081631.
Upvote
0
- Tham gia
- 5/6/08
- Bài viết
- 30,703
- Được thích
- 53,930
Rất nhiều kiểu biến không có trong danh mục lắm bạn à
Muốn biết object thuộc "loại" gì, cứ chọn vào nó rồi chạy dòng lệnh: MsgBox TypeName(Selection)
Rất đơn giản
Ẹc... Ẹc...
Upvote
0
nguyenkhuyen106
Thành viên chính thức
- Tham gia
- 21/11/12
- Bài viết
- 56
- Được thích
- 81
Em lại thử nghiệm một lần nữa:
1. Tạo lại code như bài trên của em (ví dụ vậy), thay số 1 bởi Application.Caller
[GPECODE=vb]Sub Test()
Dim Cbo As DropDown
Set Cbo = Sheet1.DropDowns(Application.Caller)
Cbo.AddItem "Giai phap Excel"
Cbo.AddItem "Cong cu tuyet voi cua ban"
End Sub[/GPECODE]
2. Vẽ lên Sheet1 2 cái ComboBox, rồi Assign Macro cho cả 2 ComboBox này đều là Test.
3. Nhấn 1 trong 2 ComboBox vừa tạo, cứ chọn cái nào thì cái đó lại được thêm 2 dòng như trên.
--> Kết luận: Sử dụng Application.Caller để xác định rằng code đang chạy phụ thuộc vào chính ComboBox mà ta nhấn chuột vào.
Upvote
0
- Tham gia
- 5/6/08
- Bài viết
- 30,703
- Được thích
- 53,930
Mục đích của tôi là muốn khi bạn vẽ bất cứ thằng Drop down nào (tên gì mặc kệ), cứ Assign Macro với code là chạy được chứ không cần phải sửa tên Drop down trong code (dạng như tên động ấy) ---> Cứ "thằng" nào "đụng" vào tui thì tui "chỉ mặt thằng đó"
Ẹc... Ẹc...
Upvote
0
Bài viết mới nhất
- Question
