Lọc duy nhất những số xuất hiện từ 2 lần trở lên (2 người xem)

[bimbim1412]

Bài toán này nếu dùng VBA (Dictionary) thì ra kết quả nhanh, em muốn thử xem nếu viết bằng công thức Excel thì Name điều kiện viết thế nào ah?

 

[dhn46]

Bài toán này nếu dùng VBA (Dictionary) thì ra kết quả nhanh, em muốn thử xem nếu viết bằng công thức Excel thì Name điều kiện viết thế nào ah?

Bạn dùng công thức mảng sau

=INDEX($A$3:$A$12,SMALL(IF(FREQUENCY($A$3:$A$12,$A$3:$A$12)>1,ROW(INDIRECT("1:"&ROWS($A$3:$A$12))),""),ROW(1:1)))

 

[leonguyenz]

Bài toán này nếu dùng VBA (Dictionary) thì ra kết quả nhanh, em muốn thử xem nếu viết bằng công thức Excel thì Name điều kiện viết thế nào ah?

Thêm công thức mảng này:

=INDEX($A$3:$A$12,MATCH(1,(COUNTIF($C$2:C2,$A$3:$A$12)=0)*(COUNTIF($A$3:$A$12,$A$3:$A$12)>1),0),)

 

[bimbim1412]

Thêm công thức mảng này:

=INDEX($A$3:$A$12,MATCH(1,(COUNTIF($C$2:C2,$A$3:$A$12)=0)*(COUNTIF($A$3:$A$12,$A$3:$A$12)>1),0),)

Ồ chưa bao giờ em sử dụng Countif dưới dạng như trên, nhờ bác hướng dẫn em nghĩ ra được Name điều kiện rồi

DL=Sheet1!$A$3:$A$12

DK=IF((MATCH(DL;DL;0)=ROW(INDIRECT("$1:"&ROWS(DL))))*(COUNTIF(DL;DL)>1);ROW(INDIRECT("$1:"&ROWS(DL)));"")

Kết quả tại ô C3:

=IF(COUNT(DK)>=ROWS($1:1);INDEX(DL;SMALL(DK;ROWS($1:1)));"")

Bài này em băn khoăn đi tìm cách viết điều kiện thôi chứ làm kiểu này dữ liệu lớn chắc treo máy mất

 

[bimbim1412]

Thêm công thức mảng này:

=INDEX($A$3:$A$12,MATCH(1,(COUNTIF($C$2:C2,$A$3:$A$12)=0)*(COUNTIF($A$3:$A$12,$A$3:$A$12)>1),0),)

Từ công thức mảng của anh, em thí nghiệm nhưng chưa rõ lắm, anh cho em hỏi công thức

=MATCH(1,(D9:D13)*(E9:E13),0)

là dạng mảng (Ctrl+Shift+Enter),
mà

=MATCH(2,{1;1;1;1;1;1;0;1;0;1}*{1;2;0;0;0;0;0;0;0;0},0)

lại có thể Enter bình thường nhỉ?

 

[mhung12005]

Từ công thức mảng của anh, em thí nghiệm nhưng chưa rõ lắm, anh cho em hỏi công thức

=MATCH(1,(D9:D13)*(E9:E13),0)

là dạng mảng (Ctrl+Shift+Enter),
mà

=MATCH(2,{1;1;1;1;1;1;0;1;0;1}*{1;2;0;0;0;0;0;0;0;0},0)

lại có thể Enter bình thường nhỉ?

Theo mình thì:
Trường hợp 1: Hàm Match vẫn phải lấy dữ liệu trên Range: (D913) và (E9:E13) để tính (tạo) ra mảng mới sau đó mới thực hiện dò tìm trên mảng mới này và hàm Match không phải là hàm mảng nên phải Ctrl + Shift + Enter.
Trường hợp 2: Hai mảng: {1;1;1;1;1;1;0;1;0;1}*{1;2;0;0;0;0;0;0;0;0}đã thật sự là mảng (không liên quan gì tới Range cả) nên nó vẫn tính toán ra mảng mới và thức hiện dò tìm --> Enter bình thường.

Mình hiểu vậy không biết đã đủ chưa mong các cao thủ khác chỉ giáo thêm.