Không in nội dung của 1 Cell

[CATHY]

Em có vấn đề này nhờ các anh chị chỉ giúp!

Cell A1 có dữ liệu tham chiếu đến các Cell khác trong bảng tính, nhưng khi in bảng tính ra, em không muốn in nội dung của Cell A1. Vậy có cách nào làm được việc này không? (không tô màu trắng Cell A1)
Cảm ơn các anh chị
CATHY

 

[Mr Okebab]

Em có vấn đề này nhờ các anh chị chỉ giúp!

Cell A1 có dữ liệu tham chiếu đến các Cell khác trong bảng tính, nhưng khi in bảng tính ra, em không muốn in nội dung của Cell A1. Vậy có cách nào làm được việc này không? (không tô màu trắng Cell A1)
Cảm ơn các anh chị
CATHY

Bạn thân mến, có rất nhiều cách : Format Cell, Format Condition, Màu Pattems, Màu Fonts . . .
Đây là cách Format Cells/Number/Custom/Type

1. Nếu là số : ;;
2. Nếu là chuỗi ký tự : [White]@

Thân!

 

[CATHY]

Bạn thân mến, có rất nhiều cách : Format Cell, Format Condition, Màu Pattems, Màu Fonts . . .
Đây là cách Format Cells/Number/Custom/Type

1. Nếu là số : ;;
2. Nếu là chuỗi ký tự : [White]@

Thân!

Cảm ơn anh Bap, nhưng ý của em là trên bảng tính em vẫn nhìn thấy nội dung của Cell A1 nhưng khi in ra thì không thấy, cách của anh em làm thử thì không nhìn thấy nội dung của A1. Anh có cách nào khác nữa ko
CATHY

 

[dvu58]

Theo ý CATHY thì mình chỉ biết có cách:
1. Chọn (quét chuột chẳng hạn) vùng cần in trong trang bảng tính, trừ những ô (hoặc vùng) không muốn in.
2. Vào Print, vào mục Print what -> chọn option "Selection"

Bảo đảm chỉ in những vùng đã được chọn mà thôi.

 

[chibi]

Dùng cách của dvu58 hình như không ổn, tôi chưa thử với máy in nhưng đã thử với preview (Selection chỉ đúng với vùng liên tục).
Có thể dung VBA
Bắt đầu
Chuyển A1 thành chữ trắng
In
Đưa A1 trở lại như cũ
Kết thúc

 

[SoiBien]

Có thể dung VBA
Bắt đầu
Chuyển A1 thành chữ trắng
In
Đưa A1 trở lại như cũ
Kết thúc

Đây là một đoạn code tôi sưu tầm được, Cathy sử dụng xem nhé.
chọn các ô không muốn in (bằng phím Ctrl trong trường hợp các ô không liên tục) rồi đặt tên là Noprintrange , ý tưởng của code là thực hiện cho màu font chữ trùng với màu nền của ô, sau khi in xong thì trả lại như cũ.

Nhớ đặt code này trong ThisWorkbook code module nhé.

 '*********************************************************
    'Purpose:   Hide cell values when printing
    'Inputs:     None: A Sheet-level name of "NoPrintRange" must 
                    be defined for each sheet with a range to be hidden.
    'Returns:   None: Prints each selected sheet.
    '*********************************************************
    Private Sub Workbook_BeforePrint(Cancel As Boolean)
    	'J.E. McGimpsey  http://www.mcgimpsey.com/excel/noprintrange.html
        Dim vFontArr As Variant
        Dim oWkSht As Worksheet
        Dim rNoPrintRange As Range
        Dim rCell As Range
        Dim rArea As Range
        Dim i As Long
        Dim bOldScreenUpdating As Boolean
        
        Cancel = True
        With Application
            .EnableEvents = False
            bOldScreenUpdating = .ScreenUpdating
            .ScreenUpdating = False
        End With
        For Each oWkSht In ActiveWindow.SelectedSheets
            On Error Resume Next
            Set rNoPrintRange = oWkSht.Range("NoPrintRange")
            On Error GoTo 0
            If Not rNoPrintRange Is Nothing Then
                With rNoPrintRange
                    ReDim vFontArr(1 To .Count)
                    i = 1
                    For Each rArea In .Areas
                        For Each rCell In rArea
                            With rCell
                                vFontArr(i) = .Font.ColorIndex
                                If .Interior.ColorIndex = xlColorIndexNone Then
                                    .Font.Color = RGB(255, 255, 255) 'white
                                Else
                                    .Font.ColorIndex = .Interior.ColorIndex
                                End If
                            i = i + 1
                            End With
                        Next rCell
                    Next rArea
                    oWkSht.PrintOut
                    i = 1
                    For Each rArea In .Areas
                        For Each rCell In rArea
                            rCell.Font.ColorIndex = vFontArr(i)
                            i = i + 1
                        Next rCell
                    Next rArea
                End With
            Else
                oWkSht.PrintOut
            End If
            Set rNoPrintRange = Nothing
        Next oWkSht
        With Application
            .ScreenUpdating = bOldScreenUpdating
            .EnableEvents = True
        End With
    End Sub

Thân.