Hỏi về nơi tải danh sách xã huyện tỉnh chuẩn (1 người xem)

[Trần Văn Bình]

Mình muốn đổi tên địa chỉ đã nhập sẳn trên file. Giờ mình muốn kết quả từ sheet danhmuc dựa vào sheets phuongxa

 

[DeTong]

dựa vào sheets phuongxa

Sheet phuongxa của bạn còn thiếu nhiều xã cũ nên nhiều trường hợp không thay thế được;
Điển hình: Xã Lương Ninh, Xã Lệ Thủy...

 

[minhminh27]

do sát nhập đơn vị hành chính mới. Nhờ Anh/Chị tạo file chuẩn với ạ.
em có tìm được trang web https://sapnhap.bando.com.vn/

 

[ongke0711]

Dữ liệu phân tách ra của bài #26 là chuẩn rồi đó bạn: 3.321 phường xã, chỉ còn thiếu mã định danh mới của từng xã thôi. Mã định danh này để tối tôi post lên.

 

[DeTong]

Nhờ Anh/Chị tạo file chuẩn với ạ.

Theo Danh Mục bài #26.
Áp dụng Tỉnh Quảng Trị bài #41
Dùng giải pháp QUERY...
Két quả chờ chủ thớt ý kiến...

let
    // Bước 1: Lấy dữ liệu từ bảng tên "tDiaChi" trong Excel hiện tại
    Nguon = Excel.CurrentWorkbook(){[Name="tDiaChi"]}[Content],

    // Bước 2: Chuyển đổi kiểu dữ liệu của cột ID và DiaChiCu
    DoiKieu = Table.TransformColumnTypes(Nguon, {{"ID", Int64.Type}, {"DiaChiCu", type text}}),

    // Bước 3: Tạo cột mới "ThayThe" bằng cách thay thế từng chuỗi trong DiaChiCu theo bảng tTim
    ThayChu = Table.AddColumn(DoiKieu, "ThayThe", each List.Accumulate(
        {0..Table.RowCount(tTim)-1},
        [DiaChiCu],
        (s,c)=> Text.Replace(s, tTim[Thay]{c}, tTim[Bang]{c})
    )),

    // Bước 4: Trích phần trước dấu phẩy đầu tiên trong "ThayThe"
    TruocPhay = Table.TransformColumns(ThayChu, {{"ThayThe", each Text.BeforeDelimiter(Text.Trim(_), ", "), type text}}),

    // Bước 5: Trích phần giữa 2 dấu phẩy trong "ThayThe" đã viết hoa chữ cái đầu
    GiuaPhay = Table.AddColumn(TruocPhay, "Giua", each Text.BetweenDelimiters(Text.Proper([DiaChiCu]), ", ", ", ")),

    // Bước 6: Thêm cột "Tinh" với giá trị cố định "Tỉnh Quảng Trị"
    ThemTinh = Table.AddColumn(GiuaPhay, "Tinh", each "Tỉnh Quảng Trị"),

    // Bước 7: Gộp ba cột lại thành chuỗi văn bản mới
    GopCot = Table.AddColumn(ThemTinh, "DiaChiMoi", each Text.Combine({[ThayThe], [Giua], [Tinh]}, ", "), type text),

    // Bước 8: Chỉ giữ lại cột ID và cột mới đã gộp
    KetQua = Table.SelectColumns(GopCot, {"ID", "DiaChiMoi"})
in
    KetQua