Hỏi về cách xếp loại học sinh

[aikhanh]

Chào các ACE trong gpec,
Mình có bài tập làm hoài ko ra ( mình mới tập tành excel ) mong các bạn chỉ giúp. Sợ post bên Công thức excel bị del bài nên qua đây.

Câu 3Hãy Xếp Loại cho học sinh dựa vào các yêu cầu sau:- Giỏi : ĐTB >=9 và không có môn nào điểm nhỏ hơn 8- Khá : ĐTB >=7 và không có môn nào điểm nhỏ hơn 6- TB : ĐTB >=5 và không có môn nào điểm nhỏ hơn 4
- Yếu : Các trường hợp còn lại
Cám ơn

​

 

[vumian]

Thử xem :
K5=IF(AND(I5>=9,MIN(C5:H5)>=8),"Giỏi",IF(AND(I5>=7,MIN(C5:H5)>=6),"Khá",IF(AND(I5>=5,MIN(C5:H5)>=4),"TB","Yếu")))

 

[Po_Pikachu]

Thêm 1 cách khác để bạn tham khảo đây. Mở file ra xem nha! Thân.

 

[letuongqt]

Hỏi về cách xếp loại học sinh Trả Lời Ðề Tài

Chào các ACE trong gpec,
Mình có bài tập làm hoài ko ra ( mình mới tập tành excel ) mong các bạn chỉ giúp. Sợ post bên Công thức excel bị del bài nên qua đây.

Câu 3Hãy Xếp Loại cho học sinh dựa vào các yêu cầu sau:- Giỏi : ĐTB >=9 và không có môn nào điểm nhỏ hơn 8- Khá : ĐTB >=7 và không có môn nào điểm nhỏ hơn 6- TB : ĐTB >=5 và không có môn nào điểm nhỏ hơn 4
- Yếu : Các trường hợp còn lại
Cám ơn

Bạn xem file này được chưa .

 

[aiquocxp]

Bạn xem nhe:
=IF(AND(I5>=9,MIN(C5:H5)>=8),"G",IF(AND(I5>=7,MIN(C5:H5)>=6),"K",
IF(AND(I5>=5,MIN(C5:H5)>=4),"TB","Y")))

 

[cadafi]

Tôi nhận thấy cách của Po_pikachu là hay nhất (bài #3)! hay ở chỗ không phụ thuộc vào biểu thức IF, nếu có thêm điều kiện nữa thì cũng không thành vấn đề, trong khi nếu dùng IF thì tối đa được 8 lần IF!

Cảm ơn Po-Pikachu!

 

[aikhanh]

Cám ơn các ACE nhiều.
Mình là newbie với excel nên nhìn vô hàm IF còn hơi hỉu hỉu chút xíu, còn với hàm Choose nhìn hok hỉu gì hết hihi.
Chúc các ACE 1 ngày vui vẻ và tốt lành

 

[boyxin]

Thêm 1 cách khác để bạn tham khảo đây.
Mở file ra xem nha!
Thân.

Công thức tính ĐTB thế này sẽ gọn hơn

[I5] =AVERAGE(C5:H5,C5:E5)

Một cách khác của hàm CHOOSE như sau (dùng INDEX)

[K5] =INDEX({"Yếu","TB","Khá","Giỏi"},(I5>=5)*(MIN(C5:H5)>=4)+(I5>=7)*(MIN(C5:H5)>=6)+(I5>=9)*(MIN(C5:H5)>=8)+1)

 

[hatanluc]

Nhân tiện cho hỏi cách xếp loại học lực theo QĐ 40-BGD là sự khống chế bị hạ xuống bậc loại thấp hơn đấy.Như nếu đã đạt Giỏi nhưng có 1 môn đạt TB thì xuống Khá, nếu 1 môn đạt Yếu hoặc Kém thì từ G chỉ xuống TB thôi, tương tự cho loại Khá
Có bác nào chỉ giúp
Tôi có file đính kèm.Mong góp ý

 

[hanphong_2008]

To: Thầy hatanluc
nếu xếp loại học lực theo QĐ 40-BGD. Thì theo em cách hiểu của Thầy khác với mọi người rồi
chính vì thế mà công thức theo em là ngắn không chính xác, chưa xét đủ hết các khả năng.
Thầy thử với trường hợp 1 môn 4 còn lại là 9 xem kết quả là gì nhé. Các ví dụ Thầy đưa ra em mới xem qua thôi kết quả nói chung là tàm tạm. Tuy nhiên Thầy thử xem lại vơi bản Demo trường hợp của hs VINH xem nhé. trong diễn đàn bàn nhiều về vấn đề này lắm mong Thầy tìm hiểu và hoàn thiện hơn

 

[hientdz]

=IF(AND(I5>=9,COUNTIF(C5:H5,">=8")),"Giỏi",IF(AND(I5>=7,COUNTIF(C5:H5,">=6")),"Khá",IF(AND(I5>=5,COUNTIF(C5:H5,">=4")),"trung bình","yếu")))
cho em hỏi với em làm theo công thức countif ntn mà kết quả lại rađápán khác, không hiểu em cóáp dụng sai công thức không nữa. Mongmọi người chỉ giúp em với, em cámơnạ

 

[HieuCD]

=IF(AND(I5>=9,COUNTIF(C5:H5,">=8")),"Giỏi",IF(AND(I5>=7,COUNTIF(C5:H5,">=6")),"Khá",IF(AND(I5>=5,COUNTIF(C5:H5,">=4")),"trung bình","yếu")))
cho em hỏi với em làm theo công thức countif ntn mà kết quả lại rađápán khác, không hiểu em cóáp dụng sai công thức không nữa. Mongmọi người chỉ giúp em với, em cámơnạ

Mỗi người có đáp án khác nhau, bạn thích đáp án nào ?

 

[hientdz]

Mỗi người có đáp án khác nhau, bạn thích đáp án nào ?

mình biết có nhiều đáp án, hi nhưng mà sử dụng hàm countif thì nó có thể ra đáp án được không ạ

 

[HieuCD]

mình biết có nhiều đáp án, hi nhưng mà sử dụng hàm countif thì nó có thể ra đáp án được không ạ

Được

 

[hientdz]

Được

thế ạ!
bạn có thể check giúp mình đoạn công thức này sai ở đâu không ạ hay còn thiếu điều kiện nào khác nữa khi mình dùng hàm countif k a =IF(AND(I5>=9,COUNTIF(C5:H5,">=8")),"Giỏi",IF(AND(I5>=7,COUNTIF(C5:H5,">=6")),"Khá",IF(AND(I5>=5,COUNTIF(C5:H5,">=4")),"trung bình","yếu")))

 

[HieuCD]

thế ạ!
bạn có thể check giúp mình đoạn công thức này sai ở đâu không ạ hay còn thiếu điều kiện nào khác nữa khi mình dùng hàm countif k a =IF(AND(I5>=9,COUNTIF(C5:H5,">=8")),"Giỏi",IF(AND(I5>=7,COUNTIF(C5:H5,">=6")),"Khá",IF(AND(I5>=5,COUNTIF(C5:H5,">=4")),"trung bình","yếu")))

Công thức không sai, kết quả phù hợp với 1 số đáp án

 

[VetMini]

Bài này thì nếu làm đúng đắn thì lập một cái bảng lô gic ra trước. Rồi dùng Match/Index hoặc, VLookup/HLookup mà tra.
Công thức đại khái:
=INDEX($I$22:$L$25,MATCH($I5,$I$21:$L$21,1),MATCH(MIN($C5:$H5),$H$22:$H$25,1))

Bảng được lập trong vùng $H$21:$L$25
Bảng tra là vùng $I$22:$L$25, điểm trung bình là vùng $I$21:$L$21, số môn là vùng $H$22:$H$25


(*) khi tôi nói từ "đúng đắn" là tôi nói cho dân chuyên nghiệp, tức là chính người sử dụng bảng. Tôi không nói cho bài tập. Bài tập thì hỏi đến đâu làm đến đó. Chương trình dạy ở VN hình như không bao gồm bảng lô gic. Phân tích dữ liệu là dựa vào lô gic. Thiếu tư duy lập cái bảng lô gic là thiếu sót trầm trọng.

 

[hientdz]

Công thức không sai, kết quả phù hợp với 1 số đáp án

em loay hoay mãi mới nghĩ ra đc thêm điều kiện này thì khớp vs đúng đáp án và đúng theo logic của bài toán
=IF(AND(I5>=9,(COUNTIF(C5:H5,">=8")=6)),"giỏi",IF(AND(I5>=7,(COUNTIF(C5:H5,">=6")=6)),"Khá",IF(AND(I5>=5,(COUNTIF(C5:H5,">=4")=6)),"TB","yếu")))

 

[VetMini]

em loay hoay mãi mới nghĩ ra đc thêm điều kiện này thì khớp vs đúng đáp án và đúng theo logic của bài toán
=IF(AND(I5>=9,(COUNTIF(C5:H5,">=8")=6)),"giỏi",IF(AND(I5>=7,(COUNTIF(C5:H5,">=6")=6)),"Khá",IF(AND(I5>=5,(COUNTIF(C5:H5,">=4")=6)),"TB","yếu")))

Hỏi bài thì tránh viết tắt.
Những từ đc, vs chỉ dùng cho chít chát. Lúc chít chát thì hai bên đã có cái thông cảm rồi và bên này có thể đoán ý bên kia.
Trong công việc hỏi đáp, hai bên chưa có sự thông cảm, tất cả từ ngữ câu cú cần rõ rệt và tránh viết tắt, tiếng lóng gây rối rắm cho câu hỏi.

Ở bài #15, kết quả của hàm countif của bạn sử dụng không đúng cách.
=IF(AND(I5>=9,COUNTIF(C5:H5,">=8")),"Giỏi",...
Hàm IF chấp nhận rằng bất cứ trị số nào khác 0 là True. Vì vậy, trong cái biểu thức trên, chỉ cần countif trả về 1 là thoả rồi. Ở đây điều kiện đòi hỏi phải ít nhất là 6. Như vậy cách tính ở trên là sai.
Ở bài #18, bạn đã thấy cái sai đó và chỉnh lại:
=IF(AND(I5>=9,(COUNTIF(C5:H5,">=8")=6)),"giỏi",...
Biểu thức sau này bắt buộc kết quả của Countif phải ít nhất là 6, và đúng với điều kiện.

Tuy nhiên, nói về lô gic thì nó vẫn chưa đạt hết. Con số 6 ở đâu ra? Lỡ có tất cả 7 môn thì sao?
An toàn thì phải là COUNTIF(C5:H5, ">=8")=COUNTA(C5:H5) bảo đảm so sánh với số môn.
Nhưng muốn diễn tả cho thật đúng với đòi hỏi của đề bài "không có môn nào điểm nhỏ hơn 8" thì phải là:
=IF(AND(I5>=9, COUNTIF(C5:H5,"<8")=0),"giỏi",...

 

[hientdz]

Bài này thì nếu làm đúng đắn thì lập một cái bảng lô gic ra trước. Rồi dùng Match/Index hoặc, VLookup/HLookup mà tra.
Công thức đại khái:
=INDEX($I$22:$L$25,MATCH($I5,$I$21:$L$21,1),MATCH(MIN($C5:$H5),$H$22:$H$25,1))

Bảng được lập trong vùng $H$21:$L$25
Bảng tra là vùng $I$22:$L$25, điểm trung bình là vùng $I$21:$L$21, số môn là vùng $H$22:$H$25
View attachment 234620

em cám ơn nhé, cách này em sẽ tham khảo thêm a

Hỏi bài thì tránh viết tắt.
Những từ đc, vs chỉ dùng cho chít chát. Lúc chít chát thì hai bên đã có cái thông cảm rồi và bên này có thể đoán ý bên kia.
Trong công việc hỏi đáp, hai bên chưa có sự thông cảm, tất cả từ ngữ câu cú cần rõ rệt và tránh viết tắt, tiếng lóng gây rối rắm cho câu hỏi.

Ở bài #15, kết quả của hàm countif của bạn sử dụng không đúng cách.
=IF(AND(I5>=9,COUNTIF(C5:H5,">=8")),"Giỏi",...
Hàm IF chấp nhận rằng bất cứ trị số nào khác 0 là True. Vì vậy, trong cái biểu thức trên, chỉ cần countif trả về 1 là thoả rồi. Ở đây điều kiện đòi hỏi phải ít nhất là 6. Như vậy cách tính ở trên là sai.
Ở bài #18, bạn đã thấy cái sai đó và chỉnh lại:
=IF(AND(I5>=9,(COUNTIF(C5:H5,">=8")=6)),"giỏi",...
Biểu thức sau này bắt buộc kết quả của Countif phải ít nhất là 6, và đúng với điều kiện.

Tuy nhiên, nói về lô gic thì nó vẫn chưa đạt hết. Con số 6 ở đâu ra? Lỡ có tất cả 7 môn thì sao?
An toàn thì phải là COUNTIF(C5:H5, ">=8")=COUNTA(C5:H5) bảo đảm so sánh với số môn.
Nhưng muốn diễn tả cho thật đúng với đòi hỏi của đề bài "không có môn nào điểm nhỏ hơn 8" thì phải là:
=IF(AND(I5>=9, COUNTIF(C5:H5,"<8")=0),"giỏi",...

dạ vâng em cám ơn nhé, em mới vào GPE nên cần phải sửa nhiều ạ, Cám ơn anh đã góp ý cho em!!!